AboutHap

About HAP: Covers of Lie algebras

A short exact sequence of Lie algebras

0 → M → C → L → 0

(over a field k) is said to be a stem extension of L if M lies both in the centre Z(C) and in the derived subalgeba C². If, in addition, the rank of the vector space M is equal to the rank of the second Chevalley-Eilenberg homology H₂(L,k) then the Lie algebra C is said to be a cover of L.

Each finite dimensional Lie algebra L admits a cover C, and this cover can be shown to be unique up to Lie isomorphism.

The cover can be used to determine whether there exists a Lie algebra E whose central quotient E/Z(E) is isomorphic to L. The image in L of the centre of C is called the Lie Epicentre of L, and this image is trivial if and only if such an E exists.

The cover can also be used to determine the stem extensions of L. It can be shown that each stem extension is a quotient of the cover by an ideal in the Lie multiplier H₂(L,k).

The following commands compute the cover C of the solvable but non-nilpotent 13-dimensional Lie algebra L (over the rationals) that was introduced by M. Wuestner in [ "An example of a nonsolvable Lie algebra", Seminar Sophus Lie 2 (1992), 57-58 ]. They also show that:

the second Chevalley-Eilenberg homology of L has rank 2.
the second Leibniz homology of L has rank 6.
the second Chevalley-Eilenberg homology of C is trivial.
the second Leibniz homology of C has rank 6.
the Lie algebra L is not isomorphic to any central quotient E/Z(E).

gap> SCTL:=EmptySCTable(13,0,"antisymmetric");;
gap> SetEntrySCTable( SCTL, 1, 6, [ 1, 7 ] );;
gap> SetEntrySCTable( SCTL, 1, 8, [ 1, 9 ] );;
gap> SetEntrySCTable( SCTL, 1, 10, [ 1, 11 ] );;
gap> SetEntrySCTable( SCTL, 1, 12, [ 1, 13 ] );;
gap> SetEntrySCTable( SCTL, 1, 7, [ -1, 6 ] );;
gap> SetEntrySCTable( SCTL, 1, 9, [ -1, 8 ] );;
gap> SetEntrySCTable( SCTL, 1, 11, [ -1, 10 ] );;
gap> SetEntrySCTable( SCTL, 1, 13, [ -1, 12 ] );;
gap> SetEntrySCTable( SCTL, 6, 7, [ 1, 2 ] );;
gap> SetEntrySCTable( SCTL, 8, 9, [ 1, 3 ] );;
gap> SetEntrySCTable( SCTL, 6, 9, [ -1, 5 ] );;
gap> SetEntrySCTable( SCTL, 7, 8, [ 1, 5 ] );;
gap> SetEntrySCTable( SCTL, 2, 8, [ 1, 12 ] );;
gap> SetEntrySCTable( SCTL, 2, 9, [ 1, 13 ] );;
gap> SetEntrySCTable( SCTL, 3, 6, [ 1, 10 ] );;
gap> SetEntrySCTable( SCTL, 3, 7, [ 1, 11 ] );;
gap> SetEntrySCTable( SCTL, 2, 3, [ 1, 4 ] );;
gap> SetEntrySCTable( SCTL, 5, 6, [ -1, 12 ] );;
gap> SetEntrySCTable( SCTL, 5, 7, [ -1, 13 ] );;
gap> SetEntrySCTable( SCTL, 5, 8, [ -1, 10 ] );;
gap> SetEntrySCTable( SCTL, 5, 9, [ -1, 11 ] );;
gap> SetEntrySCTable( SCTL, 6, 11, [ -1/2, 4 ] );;
gap> SetEntrySCTable( SCTL, 7, 10, [ 1/2, 4 ] );;
gap> SetEntrySCTable( SCTL, 8, 13, [ 1/2, 4 ] );;
gap> SetEntrySCTable( SCTL, 9, 12, [ -1/2, 4 ] );;
gap> L:=LieAlgebraByStructureConstants(Rationals,SCTL);;

gap> LieAlgebraHomology(L,2);
2
gap> LeibnizAlgebraHomology(L,2);
6

gap> C:=Source(LieCoveringHomomorphism(L));;
gap> LieAlgebraHomology(C,2);
0
gap> LeibnizAlgebraHomology(C,2);
6
gap> Dimension(LieEpiCentre(L));
1

Contents