Extension of the metric - black hole.ipynb

Kernel: SageMath 8.0

%display latex

Spacetime: black hole extension

M = Manifold(4, 'M', r'\mathcal{M}')
print M

4-dimensional differentiable manifold M

X.<v,t,th,ph> = M.chart(R' v:(-oo,+oo) t:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi')
X

We introduce the new coordinate $v$ such that $dv=dr+\frac{dt}{F}$. The metric thus takes the following form:

F=function('F')(t)
g = M.lorentzian_metric('g')
g[0,0] = F
g[1,1] = 0
g[1,0] = -1
g[2,2] = t^2
g[3,3] = (t*sin(th))^2
g.display()

gm1=g.inverse();
gm1.display()

No coordinate singularity appears for $F(t)=0$ in the metric and inverse metric. It allows to cross both the outer and inner horizons, if they exist.

Radial null vectors

Outgoing null vector

k = M.vector_field(name='k')
k[0] = 1
k[1] = F/2 # outgoing since F/2>0 at infinity
k.display()

Ingoing null vector

l = M.vector_field(name='l')
l[1] = -2
l.display()

kd=k.down(g)
ld=l.down(g)

Check that $k$ is a null vector

kk=kd['_a']*k['^a']
kk.display()

Check that $l$ is a null vector

ll=ld['_a']*l['^a']
ll.display()

Normalization

lk=ld['_a']*k['^a']
lk.display()

Induced metric

h=g-1/2*(kd*ld+ld*kd)

hu=h.up(g)

h.display()

Expansion of a congruence of null geodesics

nab = g.connection() ; print nab

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 4-dimensional differentiable manifold M

Check that the covariant derivative does not act on the metric:

nab(g).display()

theta_outgoing=hu['^{ab}']*nab(kd)['_{ab}']
print theta_outgoing

Scalar field on the 4-dimensional differentiable manifold M

theta_outgoing.display()

The zeros of $\theta_{outgoing}$, hence of $F$, correspond to the presence of horizons. The region with $F(t)<0$, where the expansion of outgoing null rays becomes negative, is a (future) trapped region.

theta_ingoing=theta=hu['^{ab}']*nab(ld)['_{ab}']
print theta_ingoing

Scalar field on the 4-dimensional differentiable manifold M

theta_ingoing.display()

The expansion of ingoing radial null rays is strictly negative, which is expected in the presence of a $\textbf{black hole}$.

Ricci's scalar

Rscal = g.ricci_scalar().expr()
Rscal.factor()

Kretschmann's scalar

R = g.riemann() ; print(R)

Tensor field Riem(g) of type (1,3) on the 4-dimensional differentiable manifold M

uR=R.up(g)
dR=R.down(g)

Kr_scalar = uR['^{abcd}']*dR['_{abcd}']
K=Kr_scalar.expr().factor()
K