3643.sagews

Definición de variables

t = var('t')
y = function('y', t)

Boyce & DiPrima 7th edition. Sec. 3.1, 

4)  $2y''-3y'+y=0$

desolve(2*diff(y,t,2)-3*diff(y,t)+y == 0,y)

\newcommand{\Bold}[1]{\mathbf{#1}}k_{1} e^{t} + k_{2} e^{\left(\frac{1}{2} \, t\right)}

12) $y''+3y'$, $y(0)=-2$, $y'(0)=3$

desolve(diff(y,t,2)+3*diff(y,t)== 0,y,[0,-2,3])

\newcommand{\Bold}[1]{\mathbf{#1}}-e^{\left(-3 \, t\right)} - 1

plot(-e^(-3*t) -1,(-1,2))

19) $y''-y=0$, $y(0)=\frac{5}{4}$, $y'(0)=-\frac{3}{4}$

desolve(diff(y,t,2)-y== 0,y,[0,5/4,-3/4])

\newcommand{\Bold}[1]{\mathbf{#1}}e^{\left(-t\right)} + \frac{1}{4} \, e^{t}

El mínimo se encuentra tomando $\frac{dy}{dt}=0$

diff(e^(-t) + 1/4*e^t,t)

\newcommand{\Bold}[1]{\mathbf{#1}}-e^{\left(-t\right)} + \frac{1}{4} \, e^{t}

y eligiendo la raíz real de

solve(-e^(-t) + 1/4*e^t==0, t)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[t = i \, \pi + \log\left(2\right), t = \log\left(2\right)\right]

Equivalentemente, podemos usar el comando numérico correspondiente:

find_root(-e^(-t) + 1/4*e^t==0, 0,2)

\newcommand{\Bold}[1]{\mathbf{#1}}0.69314718056

plot(e^(-t) + 1/4*e^t,(0,2))

Sec. 3.2, 

2)  $y_1=\cos t$, $y_2=\sin t$

Para calcular el Wronskiano, definimos la siguiente matriz:

A = Matrix([[cos(t),sin(t)],[diff(cos(t),t),diff(sin(t),t)]])
A

\newcommand{\Bold}[1]{\mathbf{#1}}\left($$\begin{array}{rr} \cos\left(t\right) & \sin\left(t\right) \\ -\sin\left(t\right) & \cos\left(t\right) \end{array}$$\right)

Así, el Wronskiano correspondiente a las soluciones es:

(A.determinant()).full_simplify()

\newcommand{\Bold}[1]{\mathbf{#1}}1

4)  $y_1=x$, $y_2=x e^x$

B = Matrix([[x,x*e^(x)],[diff(x,x),diff(x*e^(x),x)]])
B

\newcommand{\Bold}[1]{\mathbf{#1}}\left($$\begin{array}{rr} x & x e^{x} \\ 1 & x e^{x} + e^{x} \end{array}$$\right)

(B.determinant()).full_simplify()

\newcommand{\Bold}[1]{\mathbf{#1}}x^{2} e^{x}

6)  $y_1=\cos^2 \theta$, $y_2=1+\cos 2\theta$

C = Matrix([[(cos(t))^2,1+cos(2*t)],[diff((cos(t))^2,t),diff(1+cos(2*t),t)]])
C

\newcommand{\Bold}[1]{\mathbf{#1}}\left($$\begin{array}{rr} \cos\left(t\right)^{2} & \cos\left(2 \, t\right) + 1 \\ -2 \, \sin\left(t\right) \cos\left(t\right) & -2 \, \sin\left(2 \, t\right) \end{array}$$\right)

(C.determinant()).full_simplify()

\newcommand{\Bold}[1]{\mathbf{#1}}0

24) $y''-2y'+y=0$, $y_1=e^t$, $y_2=te^t$

var('c1,c2') # definición de las constantes de integración c1 y c2
ed= lambda u: diff(u, t,2) -2*diff(u,t)+u # definición del operador de la EDO 
ed(c1*e^(t)+c2*t*e^t).expand()

\newcommand{\Bold}[1]{\mathbf{#1}}0

D = Matrix([[e^(t),t*e^t],[diff(e^t,t),diff(t*e^t,t)]])
D

\newcommand{\Bold}[1]{\mathbf{#1}}\left($$\begin{array}{rr} e^{t} & t e^{t} \\ e^{t} & t e^{t} + e^{t} \end{array}$$\right)

(D.determinant()).full_simplify()

\newcommand{\Bold}[1]{\mathbf{#1}}e^{\left(2 \, t\right)}

26) $(1-x\cot x)y''-xy'+y=0$, $y_1=x$, $y_2=\sin x$

ed2= lambda u: (1-x*cot(x))*diff(u, x,2) -x*diff(u,x)+u # definición del operador de la EDO 
(ed2(c1*x+c2*sin(x)).expand()).simplify_full()

\newcommand{\Bold}[1]{\mathbf{#1}}0

E = Matrix([[x,sin(x)],[diff(x,x),diff(sin(x),x)]])
E

\newcommand{\Bold}[1]{\mathbf{#1}}\left($$\begin{array}{rr} x & \sin\left(x\right) \\ 1 & \cos\left(x\right) \end{array}$$\right)

(E.determinant()).full_simplify()

\newcommand{\Bold}[1]{\mathbf{#1}}x \cos\left(x\right) - \sin\left(x\right)

Sec. 3.4, 

14)  $9y''+9y'-4y=0$

desolve(9*diff(y,t,2)+9*diff(y,t)-4*y == 0,y)

\newcommand{\Bold}[1]{\mathbf{#1}}k_{1} e^{\left(\frac{1}{3} \, t\right)} + k_{2} e^{\left(-\frac{4}{3} \, t\right)}

20) $y''+y=0$, $y(\frac{\pi}{3})=2$, $y'(\frac{\pi}{3})=-4$

desolve(diff(y,t,2)+y== 0,y,[pi/3,2,-4])

\newcommand{\Bold}[1]{\mathbf{#1}}{\left(\sqrt{3} - 2\right)} \sin\left(t\right) + {\left(2 \, \sqrt{3} + 1\right)} \cos\left(t\right)

plot((sqrt(3) - 2)*sin(t) + (2*sqrt(3) + 1)*cos(t),(-2,10))

23) $3u''-u'+2u=0$, $u(0)=2$, $u'(0)=0$

desolve(3*diff(y,t,2)-diff(y,t)+2*y== 0,y,[0,2,0]).expand()

\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{2}{23} \, \sqrt{23} e^{\left(\frac{1}{6} \, t\right)} \sin\left(\frac{1}{6} \, \sqrt{23} t\right) + 2 \, e^{\left(\frac{1}{6} \, t\right)} \cos\left(\frac{1}{6} \, \sqrt{23} t\right)

plot(-2/23*(sqrt(23)*sin(1/6*sqrt(23)*t) - 23*cos(1/6*sqrt(23)*t))*e^(1/6*t),(-2,15))

Para encontrar el primer punto en que $|u|=10$, recurrimos a los métodos numéricos:

find_root((-2/23*(sqrt(23)*sin(1/6*sqrt(23)*t) - 23*cos(1/6*sqrt(23)*t))*e^(1/6*t))^2-100, 0,12)

\newcommand{\Bold}[1]{\mathbf{#1}}10.7597705544

Sec. 3.5

4) $4y''+12y'+9y=0$

desolve(4*diff(y,t,2)+12*diff(y,t)+9*y == 0,y)

\newcommand{\Bold}[1]{\mathbf{#1}}{\left(k_{2} t + k_{1}\right)} e^{\left(-\frac{3}{2} \, t\right)}

12) $y''-6y'+9y=0$, $y(0)=0$, $y'(0)=2$

desolve(diff(y,t,2)-6*diff(y,t)+9*y== 0,y,[0,0,2])

\newcommand{\Bold}[1]{\mathbf{#1}}2 \, t e^{\left(3 \, t\right)}

plot(2*t*e^(3*t),(t,-2,.35))

18) $9y''+12y'+4y=0$, $y(0)=a>0$, $y'(0)=-1$

a=var('a')
desolve(9*diff(y,t,2)+12*diff(y,t)+4*y== 0,y,[0,a,-1])

\newcommand{\Bold}[1]{\mathbf{#1}}\frac{1}{3} \, {\left({\left(2 \, a - 3\right)} t + 3 \, a\right)} e^{\left(-\frac{2}{3} \, t\right)}

Esta función simepre es positiva a menos que  el factor $(2a-3)$ sea negativo. Así, $a=\frac{3}{2}$ es el valor crítico.

Zill 7th Ed. Sec. 4.3

51) $y'''+6y''+y'-34y=0$

El polinomio característico es $r^3+6r^2+r-34=0$, cuyas raíces son

var('r')
solve(r^3+6*r^2+r-34==0, r)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[r = \left(-i - 4\right), r = \left(i - 4\right), r = 2\right]

De modo que la solución general es $y(t)=c_1 e^{2t}+c_2 e^{-4t}\cos t+c_3 e^{-4t}\sin t$

52) $y''''+y=0$

El polinomio característico es $r^4+1=(r^2+1)^2-2r^2=(r^2-\sqrt{2}r+1)(r^2+\sqrt{2}r+1)=0$, cuyas raíces son

solve(r^2-sqrt(2)*r+1==0, r)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[r = -\left(\frac{1}{2} i - \frac{1}{2}\right) \, \sqrt{2}, r = \left(\frac{1}{2} i + \frac{1}{2}\right) \, \sqrt{2}\right]

solve(r^2+sqrt(2)*r+1==0, r)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[r = -\left(\frac{1}{2} i + \frac{1}{2}\right) \, \sqrt{2}, r = \left(\frac{1}{2} i - \frac{1}{2}\right) \, \sqrt{2}\right]

De modo que la solución general es $y(t)=c_1 e^{t/\sqrt{2}}\cos{\frac{t}{\sqrt{2}}}+c_2 e^{t/\sqrt{2}}\sin{\frac{t}{\sqrt{2}}}+c_3 e^{-t/\sqrt{2}}\cos{\frac{t}{\sqrt{2}}}+c_4 e^{-t/\sqrt{2}}\sin{\frac{t}{\sqrt{2}}}$

Puntos Extra:

Zill 7th Ed. Sec. 4.3

18) $y'''+3y''-4y'-12y=0$

El polinomio característico es $r^3+3r^2-4r-12=0$, cuyas raíces son

solve(r^3+3*r^2-4*r-12==0, r)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[r = \left(-2\right), r = 2, r = \left(-3\right)\right]

De modo que la solución general es $y(t)=c_1 e^{2t}+c_2 e^{-2t}+c_3 e^{-3t}$

28) $2\frac{d^5x}{ds^5}-7\frac{d^4x}{ds^4}+12\frac{d^3x}{ds^3}+8\frac{d^2x}{ds^2}=0$

El polinomio característico es $2r^5-7r^4+12r^3+8r^2=0$, cuyas raíces son

solve(2*r^5-7*r^4+12*r^3+8*r^2,r)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[r = \left(-2 i + 2\right), r = \left(2 i + 2\right), r = \left(-\frac{1}{2}\right), r = 0\right]

Aquí la raíz $r=0$ está degenerada (aparece dos veces), de modo que la solución general es: $x(s)=c_1+c_2 s+c_3 e^{-s/2}+c_4 e^{2s}\cos{2s}+c_5 e^{2s}\sin{2s}$.

28) $y'''+12y''+36y'=0$

El polinomio característico es $r^3+12r^2+36r=0$, cuyas raíces son

solve(r^3+12*r^2+36*r,r)

\newcommand{\Bold}[1]{\mathbf{#1}}\left[r = \left(-6\right), r = 0\right]

con raíz doble r=-6, de modo que $y(t)=c_1+c_2e^{-6t}+c_3 t e^{-6t}$ . Aplicando las condiciones iniciales $y(0)=0$, $y'(0)=1$ y $y''(0)=7$ en la solución general y sus derivadas

var('c1,c2,c3')
f1(t)= c1+c2*e^(-6*t)+c3*t*e^(-6*t)
f1p=diff(f1,t)
f1pp=diff(f1,t,2)

arroja el siguiente sistema de ecuaciones:

f1(0)==0,f1p(0)==1,f1pp(0)==-7

\newcommand{\Bold}[1]{\mathbf{#1}}\left(c_{1} + c_{2} = 0, -6 \, c_{2} + c_{3} = 1, 36 \, c_{2} - 12 \, c_{3} = \left(-7\right)\right)

solve((f1(0)==0,f1p(0)==1,f1pp(0)==-7),(c1,c2,c3))

\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[c_{1} = \left(\frac{5}{36}\right), c_{2} = \left(-\frac{5}{36}\right), c_{3} = \left(\frac{1}{6}\right)\right]\right]

Así, $y(t)=y(t)=\frac{5}{36}-\frac{5}{36}e^{-6t}+\frac{1}{6}t e^{-6t}$ es la solución al problema.

50) si $m_1=-\frac{1}{2}$ y $m_2=3+i$ son raíces de un polinomio característico con coeficientes reales, necesariamente, la raíz restante debe ser el complejo conjugado de la raíz compleja $m_2$. Así $m_3=3-i$ y por lo tanto, dicho polinomio es

var('m')
((m+1/2)*(m-3-i)*(m-3+i)).expand()

\newcommand{\Bold}[1]{\mathbf{#1}}m^{3} - \frac{11}{2} \, m^{2} + 7 \, m + 5

de modo que la EDO lineal homogénea correspondiente es $y'''-\frac{11}{2}y''+7y'+5y=0$