4149.sagews

Parameterize the paraboloid $2z=x^2+y^2$ and then find its surface area for $1 \le z \le 2$.

---

---

Because we just want to calculate the surface area, we set our function $f=1$ and we calculate $SA=\iint_SdS$

---

We found the parameterization and ran the SOLVER first (below) and then used that information to get the graphs here.

var('u v'); var ('x y z')

(u, v) (x, y, z)

---

Graph 1a and 1b: We use the parameterization of S that we get below to graph the surface (the intervals are numbers so no problems). 

Sf=vector((sqrt(2*v)*cos(u),sqrt(2*v)*sin(u),v))
P1=parametric_plot(Sf,(v,1,2),(u,0,2*pi),color='red', opacity=.7)
show(P1)

Or we can do an implicit plot (we could easily add the top and bottom parts above too :))

S0=implicit_plot3d(x^2+y^2==2*z,(x,-2.3,2.3),(y,-2.3,2.3),(z,0,1),color='blue', opacity=.2)
S1=implicit_plot3d(x^2+y^2==2*z,(x,-2.3,2.3),(y,-2.3,2.3),(z,1,2),color='red', opacity=.7)
S2=implicit_plot3d(x^2+y^2==2*z,(x,-2.3,2.3),(y,-2.3,2.3),(z,2,2.2),color='blue', opacity=.2)
tx=text3d("x",(0,-2,0))
ty=text3d("y",(2,0,0))
show(S0+S1+S2+tx+ty, figsize=4)

Graph 2: We graph the parameterized region and the value of integrand as a vertical arrow at each point of this region.

Notice that the value of the surface integral ~12.53 is the "volume" (divided by vs=vector_scale).

Spar=parametric_plot3d(vector((u,v,0)),(u,0,2*pi),(v,1,2))
vs=1
vf=sum([sum([arrow3d((c,d,0),(c+0,d+0,0+sqrt(2*d+1)/vs), color=hue((d+8)/8), width=2) for d in [1..2,step=0.25]]) for c in [0..2*pi,step=pi/4]])
show(Spar+vf, aspect_ratio=(1,1,1))

Preparation for the SOLVER: We need to parametrize the surface and find the intervals.

Parameterize:  Remember, we need 2 variables to parameterize a surface. A paraboloid is "almost" a cylinder; it is a "cylinder" whose radius varies with z. 

We see $x^2+y^2=(\sqrt{2z})^2$ So we will parameterize this "circle" using $\sqrt{2z}$ as the radius. We need an angle variable for the circle and we will let z=v be our 2nd variable.

ParseError: KaTeX parse error: Unknown column alignment: * at position 24: …{\begin{array}{*̲{20}{l}}{x = \s…

To get the whole paraboloid, we have $u \in [0,2\pi]$ and $v \in[0,\inf]$ .  To get our red strip, we have $u \in [0,2\pi]$ and $v \in[1,2]$.

Hand Solution or just go directly to the SOLVER:

We could calculate using either the explicit formula or the parameterized form. We will use the parameterized form so we need the formula:

$\iint_S\,{f(x,y,z)}\,dS=\iint_{D_{xy}}\,{f(x,y,z(x,y))}$ $\left\| {d{{\vec S}_u} \times d{{\vec S}_v}} \right\| \,du\,dv$ where  $d{{\vec S}_u}=\,<\frac{\partial x}{\partial u},\frac{\partial y}{\partial u},\frac{\partial z}{\partial u }>$ and $d{{\vec S}_v}=\,<\frac{\partial x}{\partial v},\frac{\partial y}{\partial v},\frac{\partial z}{\partial v}>$

We have 

$d{{\vec S}_u}=\,<\frac{\partial x}{\partial u},\frac{\partial y}{\partial u},\frac{\partial z}{\partial u} >\,=\,<-\sqrt{2v}\sin (u),\sqrt{2v}\cos (u),0>\,$ and $d{{\vec S}_v}=\,<\frac{\partial x}{\partial v},\frac{\partial y}{\partial v},\frac{\partial z}{\partial v}>\,=\,<\frac{1}{\sqrt{2v}}\cos (u),\frac{1}{\sqrt{2v}}\sin (u),1>$

So ParseError: KaTeX parse error: Unknown column alignment: * at position 62: …{\begin{array}{*̲{20}{c}} {\vec …  and $\left\| {d{{\vec S}_u} \times d{{\vec S}_v}} \right\| =\sqrt{2v+1}$.

Finally $SA=\iint_SdS=\int_1^2 \int_0^{2 \pi}\sqrt{2v+1}du \, dv = 2 \pi\int_1^2 \sqrt{2v+1} \,dv=2 \pi \frac{(2v+1)^{\frac{3}{2}}}{2 \cdot \frac{3}{2}}\bigg|_1^2=\frac{2 \pi}{3}(5 \sqrt{5}-3 \sqrt{3}) \approx \boxed{12.53}$

---

SOLVER: Our program follows the hand solution method. Everything in red requires something particular to your problem!

1. Parameterize S and input as vector function. Requires parametrization - done above.
2. Input f(x,y,z).
3. Find the partials of S. 
4. Find the vector product of the partials. Find the magnitude (intensity) of this vector.
5. Substitute parameterization in f.
6. Find the integrand.
7. Find intervals of integration and integrate. Requires intervals of parametrization - done above.

---

Step 0: The program declares our variables. We are given variables (x,y,z). We need (u,v) as parameters.

var ('u v'); var('x y z')

(u, v) (x, y, z)

---

Step 1: We define $\vec S$, and $f(x,y,z)$. Changes with problem; you must input your parametrization in Sf and your function of f.

Sf=vector((sqrt(2*v)*cos(u),sqrt(2*v)*sin(u),v))
f=1

---

Step 2: The program finds the partial derivatives.

Sprime_u=diff(Sf,u)
view(Sprime_u)

\newcommand{\Bold}[1]{\mathbf{#1}}\left(-\sqrt{2} \sqrt{v} \sin\left(u\right),\,\sqrt{2} \sqrt{v} \cos\left(u\right),\,0\right)

Sprime_v=diff(Sf,v)
view(Sprime_v)

\newcommand{\Bold}[1]{\mathbf{#1}}\left(\frac{\sqrt{2} \cos\left(u\right)}{2 \, \sqrt{v}},\,\frac{\sqrt{2} \sin\left(u\right)}{2 \, \sqrt{v}},\,1\right)

---

Step 3: The program calculates $\left\| {d{{\vec S}_u} \times d{{\vec S}_v}} \right\|$

npar=Sprime_u.cross_product(Sprime_v)
np=norm(npar)
view(np)

\newcommand{\Bold}[1]{\mathbf{#1}}\sqrt{{\left| -\sin\left(u\right)^{2} - \cos\left(u\right)^{2} \right|}^{2} + {\left| \sqrt{2} \sqrt{v} \sin\left(u\right) \right|}^{2} + {\left| \sqrt{2} \sqrt{v} \cos\left(u\right) \right|}^{2}}

---

Step 4: The program defines a standard sage function for "change of variables" for a 2-variable parametrization (surface).

The program changes the variables of $f$.

def changevar(h, eqn, newvar1,newvar2):
    return h.substitute(eqn)

f=changevar(f,x==Sf[0],u,v)
f=changevar(f,y==Sf[1],u,v)
f=changevar(f,z==Sf[2],u,v)
view(f)

\newcommand{\Bold}[1]{\mathbf{#1}}1

---

Step 5: Then program finds the dot product of f and dS (the magnitude from step 3).

integrand=np*f
view(integrand)

\newcommand{\Bold}[1]{\mathbf{#1}}\sqrt{{\left| -\sin\left(u\right)^{2} - \cos\left(u\right)^{2} \right|}^{2} + {\left| \sqrt{2} \sqrt{v} \sin\left(u\right) \right|}^{2} + {\left| \sqrt{2} \sqrt{v} \cos\left(u\right) \right|}^{2}}

---

Step 6: The program computes the integral (flux). Changes with problem - we must put in our intervals of integration.

integrand2=integral(integrand,(v,1,2))
view(integrand2)

\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{1}{3} \, {\left(\sin\left(u\right)^{2} + \cos\left(u\right)^{2} + 2\right)} \sqrt{\sin\left(u\right)^{4} + \cos\left(u\right)^{4} + 2 \, {\left(\cos\left(u\right)^{2} + 1\right)} \sin\left(u\right)^{2} + 2 \, \cos\left(u\right)^{2}} + \frac{1}{3} \, {\left(\sin\left(u\right)^{2} + \cos\left(u\right)^{2} + 4\right)} \sqrt{\sin\left(u\right)^{4} + \cos\left(u\right)^{4} + 2 \, {\left(\cos\left(u\right)^{2} + 2\right)} \sin\left(u\right)^{2} + 4 \, \cos\left(u\right)^{2}}

result=integral(integrand2,(u,0,2*pi))
view(result)

\newcommand{\Bold}[1]{\mathbf{#1}}-2 \, \pi \sqrt{3} + \frac{10}{3} \, \pi \sqrt{5}

n(result)

12.5332529180638

Answer:  Given the paraboloid $2z=x^2+y^2$ 

The parametrization is: ParseError: KaTeX parse error: Unknown column alignment: * at position 24: …{\begin{array}{*̲{20}{l}}{x = \s…, ;$u \in [0,2\pi]$ and $v \in [0,\infty ]$.

The surface area for $1 \le z \le 2$ is: $\approx 12.53$.