meson.build

# Copyright © 2020-2021 Collabora, Ltd.
# Author: Antonio Caggiano <[email protected]>
#
# SPDX-License-Identifier: MIT

pps_sources = [
  'pps.cc',
  'pps_device.cc',
  'pps_driver.cc',
  'pps_counter.cc',
]

include_pps = include_directories('../')

dep_drm = dependency('libdrm')
pps_deps = [dep_drm, dep_perfetto]
pps_deps += pps_datasources

lib_pps = static_library(
  'pps',
  sources: pps_sources,
  include_directories: [include_pps, inc_src, pps_includes],
  dependencies: pps_deps,
  cpp_args: '-std=c++17'
)

dep_pps = declare_dependency(
  link_with: lib_pps,
  include_directories: [include_pps, inc_src]
)

producer_sources = [
  'pps_datasource.cc',
  'pps_producer.cc'
]

executable(
  'pps-producer',
  sources: producer_sources,
  include_directories: [include_pps, inc_src],
  dependencies: [dep_pps, dep_perfetto],
  cpp_args: '-std=c++17',
  install: true
)

config_sources = [
  'pps_config.cc'
]

dep_docopt = dependency('docopt', required: false)

if dep_docopt.found()
  executable(
    'pps-config',
    sources: config_sources,
    include_directories: [include_pps, inc_src],
    dependencies: [dep_pps, dep_docopt],
    cpp_args: '-std=c++17',
    install: true
  )
endif