CoCalc -- fade.asm

GitHub Repository: pret/pokered
Path: blob/master/home/fade.asm
¹²⁷⁰ views
1
; These routines manage gradual fading
2
; (e.g., entering a doorway)
3
LoadGBPal::
4
	ld a, [wMapPalOffset] ; tells if wCurMap is dark (requires HM5_FLASH?)
5
	ld b, a
6
	ld hl, FadePal4
7
	ld a, l
8
	sub b
9
	ld l, a
10
	jr nc, .ok
11
	dec h
12
.ok
13
	ld a, [hli]
14
	ldh [rBGP], a
15
	ld a, [hli]
16
	ldh [rOBP0], a
17
	ld a, [hli]
18
	ldh [rOBP1], a
19
	ret
20

21
GBFadeInFromBlack::
22
	ld hl, FadePal1
23
	ld b, 4
24
	jr GBFadeIncCommon
25

26
GBFadeOutToWhite::
27
	ld hl, FadePal6
28
	ld b, 3
29

30
GBFadeIncCommon:
31
	ld a, [hli]
32
	ldh [rBGP], a
33
	ld a, [hli]
34
	ldh [rOBP0], a
35
	ld a, [hli]
36
	ldh [rOBP1], a
37
	ld c, 8
38
	call DelayFrames
39
	dec b
40
	jr nz, GBFadeIncCommon
41
	ret
42

43
GBFadeOutToBlack::
44
	ld hl, FadePal4 + 2
45
	ld b, 4
46
	jr GBFadeDecCommon
47

48
GBFadeInFromWhite::
49
	ld hl, FadePal7 + 2
50
	ld b, 3
51

52
GBFadeDecCommon:
53
	ld a, [hld]
54
	ldh [rOBP1], a
55
	ld a, [hld]
56
	ldh [rOBP0], a
57
	ld a, [hld]
58
	ldh [rBGP], a
59
	ld c, 8
60
	call DelayFrames
61
	dec b
62
	jr nz, GBFadeDecCommon
63
	ret
64

65
FadePal1:: dc 3,3,3,3, 3,3,3,3, 3,3,3,3
66
FadePal2:: dc 3,3,3,2, 3,3,3,2, 3,3,2,0
67
FadePal3:: dc 3,3,2,1, 3,2,1,0, 3,2,1,0
68
FadePal4:: dc 3,2,1,0, 3,1,0,0, 3,2,0,0
69
;              rBGP     rOBP0    rOBP1
70
FadePal5:: dc 3,2,1,0, 3,1,0,0, 3,2,0,0
71
FadePal6:: dc 2,1,0,0, 2,0,0,0, 2,1,0,0
72
FadePal7:: dc 1,0,0,0, 1,0,0,0, 1,0,0,0
73
FadePal8:: dc 0,0,0,0, 0,0,0,0, 0,0,0,0
74

75
Product

Resources

Company
