HPlatform.txt

// ----------------------------------
// RSDK Project: Sonic 1
// Script Description: H Platform Object
// Script Author: Christian Whitehead/Simon Thomley
// Unpacked by Rubberduckycooly's script unpacker
// ----------------------------------

// ========================
// Aliases
// ========================

private alias object.value0 : object.stood
private alias object.value1 : object.centerPos.x
private alias object.value2 : object.centerPos.y
private alias object.value3 : object.stoodAngle

// Player Aliases
private alias object.xpos : player.xpos
private alias object.ypos : player.ypos


// ========================
// Function Declarations
// ========================

reserve function HPlatform_DebugDraw
reserve function HPlatform_DebugSpawn


// ========================
// Tables
// ========================

private function HPlatform_DebugDraw
	DrawSprite(0)
end function


private function HPlatform_DebugSpawn
	CreateTempObject(TypeName[H Platform], object.direction, object.xpos, object.ypos)
	object[tempObjectPos].centerPos.x = object.xpos
	object[tempObjectPos].centerPos.y = object.ypos
end function


// ========================
// Events
// ========================

event ObjectUpdate
	temp6 = object.xpos
	temp7 = object.ypos
	GetTableValue(temp0, 12, StageSetup_oscillationTable)
	GetBit(temp1, object.propertyValue, 0)
	if temp1 == 1
		FlipSign(temp0)
		temp0 += 0x4000
	else
		temp0 -= 0x4000
	end if
	temp0 <<= 8

	object.xpos = object.centerPos.x
	object.xpos -= temp0

	if object.stood == true
		if object.stoodAngle < 64
			object.stoodAngle += 4
		end if
	else
		if object.stoodAngle > 0
			object.stoodAngle -= 4
		end if
	end if

	temp0 = object.stoodAngle
	temp0 <<= 1
	Sin(temp1, temp0)
	temp1 <<= 9
	object.ypos = object.centerPos.y
	object.ypos += temp1

	object.stood = false

	temp0 = object.xpos
	temp1 = object.ypos
	temp6 &= 0xFFFF0000
	temp7 &= 0xFFFF0000
	temp4 = object.xpos
	temp4 &= 0xFFFF0000
	temp4 -= temp6
	temp5 = object.ypos
	temp5 &= 0xFFFF0000
	temp5 -= temp7

	object.xpos = temp6
	object.ypos = temp7
	foreach (GROUP_PLAYERS, currentPlayer, ACTIVE_ENTITIES)
		BoxCollisionTest(C_PLATFORM, object.entityPos, -32, -8, 32, 12, currentPlayer, C_BOX, C_BOX, C_BOX, C_BOX)
		if checkResult == true
			object.stood = true
			player[currentPlayer].xpos += temp4
			player[currentPlayer].ypos += temp5
		end if
	next

	object.xpos = temp0
	object.ypos = temp1
end event


event ObjectDraw
	DrawSprite(0)
end event


event ObjectStartup
	LoadSpriteSheet("SYZ/Objects.gif")
	SpriteFrame(-32, -10, 64, 32, 119, 1)

	foreach (TypeName[H Platform], arrayPos0, ALL_ENTITIES)
		object[arrayPos0].centerPos.x = object[arrayPos0].xpos
		object[arrayPos0].centerPos.y = object[arrayPos0].ypos
	next

	SetTableValue(TypeName[H Platform], DebugMode_ObjCount, DebugMode_TypesTable)
	SetTableValue(HPlatform_DebugDraw, DebugMode_ObjCount, DebugMode_DrawTable)
	SetTableValue(HPlatform_DebugSpawn, DebugMode_ObjCount, DebugMode_SpawnTable)
	DebugMode_ObjCount++
end event


// ========================
// Editor Events
// ========================

event RSDKEdit
	if editor.returnVariable == true
		switch editor.variableID
		case EDIT_VAR_PROPVAL // property value
			checkResult = object.propertyValue
			break
			
		case 0 // startDir
			GetBit(checkResult, object.propertyValue, 0)
			break
			
		end switch
	else
		switch editor.variableID
		case EDIT_VAR_PROPVAL // property value
			object.propertyValue = editor.variableValue
			break
			
		case 0 // startDir
			CheckNotEqual(editor.variableValue, false)
			SetBit(object.propertyValue, 0, checkResult)
			break
			
		end switch
	end if
end event


event RSDKDraw
	DrawSprite(0)
	
		if editor.showGizmos == true
		editor.drawingOverlay = true

		// Draw some lines to indicate where this platform is gonna go and that it's a horizontal type
		// (Otherwise it's just the generic platform sprite, which is shared between two other objects)
		
//		object.inkEffect = INK_BLEND

		temp0 = 0x3f8000
		temp0 += object.xpos
//		DrawSpriteFX(0, FX_INK, temp0, object.ypos)
		
		temp1 = -0x408000
		temp1 += object.xpos
//		DrawSpriteFX(0, FX_INK, temp1, object.ypos)

		DrawLine(temp0, object.ypos, temp1, object.ypos, 255, 255, 255)
		
//		object.inkEffect = INK_NONE

		editor.drawingOverlay = false
	end if
end event


event RSDKLoad
	LoadSpriteSheet("SYZ/Objects.gif")
	SpriteFrame(-32, -10, 64, 32, 119, 1)

	AddEditorVariable("startDir")
	SetActiveVariable("startDir")
	AddEnumVariable("Left", 0)
	AddEnumVariable("Right", 1)

	// there is apparently another variable (uses bit 1, while startDir uses bit 0), though its not used and thus idk what it is
	// TODO: I may have an inkling as to what it may be, investigate some more
end event