R4_RedFish.txt

//-----------------Sonic CD Red Fish Script-------------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0			:	Object.Timer
#alias Object.Value1			:	Object.Angle

// HUD alias
#alias Object[24].PropertyValue	:	HUD.CurrentTimePeriod

// States
#alias 0	:	REDFISH_SWIMRIGHT
#alias 1	:	REDFISH_SWIMLEFT

// Time Period Aliases
#alias 2	:	TIME_GOOD_FUTURE


sub ObjectMain
	switch Object.State
	case REDFISH_SWIMRIGHT
		if Object.Angle < 512
			Object.Angle += 2
			
			// Move a pixel right
			Object.XPos += 0x10000
		else
			// Apex reached, turn around
			Object.State	 = REDFISH_SWIMLEFT
			Object.Direction = FACING_LEFT
		end if
		break
		
	case REDFISH_SWIMLEFT
		if Object.Angle > 0
			Object.Angle -= 2
			
			// Just keep swimming, move a pixel left now
			Object.XPos -= 0x10000
		else
			// Other side's apex reached, turn right back around again
			Object.State	 = REDFISH_SWIMRIGHT
			Object.Direction = FACING_RIGHT
		end if
		break
		
	end switch
	
	// Animate the Fish
	Object.Timer++
	if Object.Timer > 19
		Object.Timer = 0
		Object.Frame++
		Object.Frame &= 1
	end if
	
end sub


sub ObjectDraw
	// With this current system set up, that does indeed mean the sprite gets drawn twice if
	// in the Good Future and the Metal Sonic Projector has been destroyed
	
	if MetalSonic_Destroyed == true
		Sin(TempValue1, Object.Angle)
		TempValue1 <<= 12
		TempValue1  += Object.YPos
		
		DrawSpriteFX(Object.Frame, FX_FLIP, Object.XPos, TempValue1)
	end if
	
	if HUD.CurrentTimePeriod == TIME_GOOD_FUTURE
		Sin(TempValue1, Object.Angle)
		TempValue1 <<= 12
		TempValue1  += Object.YPos
		
		DrawSpriteFX(Object.Frame, FX_FLIP, Object.XPos, TempValue1)
	end if
	
end sub


sub ObjectStartup
	
	LoadSpriteSheet("R4/Objects3.gif")
	
	// Fishy Frames
	
	SpriteFrame(-8, -12, 16, 24, 1, 67)
	SpriteFrame(-8, -12, 16, 24, 18, 67)
	
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R4/Objects3.gif")
	SpriteFrame(-8, -12, 16, 24, 1, 67)

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub