FallSignPost.txt

//---------------Sonic CD Fall Sign Post Script---------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0	:	Object.Timer
#alias Object.Value1	:	Object.FrameTimer
#alias Object.Value2	:	Object.IdleTimer
#alias Object.Value4	:	Object.YVelocity
#alias Object.Value5	:	Object.OnFloor

// States
#alias 0	:	FALLSIGNPOST_SETUP
#alias 1	:	FALLSIGNPOST_AIR_FLIP
#alias 2	:	FALLSIGNPOST_FLIP
#alias 3	:	FALLSIGNPOST_STOP_PLAYER

// Camera
#alias 4	:	CAMERASTYLE_HLOCKED

// Control Mode
#alias -1	:	CONTROLMODE_NONE

// Collision Sides
#alias 0	:	CSIDE_FLOOR

// Global SFX
#alias 15	:	SFX_G_SIGNPOST

// Priority
#alias 1	:	PRIORITY_ACTIVE


sub ObjectMain
	switch Object.State
	case FALLSIGNPOST_SETUP
		CheckEqual(game.missionCondition, MISSION_CONDITION_CLEAR)
		TempValue0  = CheckResult
		CheckNotEqual(Screen.YOffset, 0)
		TempValue0 &= CheckResult
		if TempValue0 == true
			game.missionCondition = false
			Object.XPos   = Player.XPos
			Object.XPos  -= 0x80000

			Object.YPos   = Screen.YOffset
			Object.YPos  += 24
			Object.YPos <<= 16

			Screen.CameraStyle = CAMERASTYLE_HLOCKED
			ObjectTileCollision(CSIDE_FLOOR, 0, 8, 0)
			if CheckResult == true
				Object.OnFloor = true
			end if
			Object.State = FALLSIGNPOST_AIR_FLIP
			PlaySfx(SFX_G_SIGNPOST, false)
		end if
		break

	case FALLSIGNPOST_AIR_FLIP
		Object.IdleTimer++

		Object.YPos		 += Object.YVelocity
		Object.YVelocity += 0xC00
		ObjectTileCollision(CSIDE_FLOOR, 0, 8, 0)
		if CheckResult == true
			if Object.OnFloor == false
				Object.Timer = 4
				Object.State = FALLSIGNPOST_FLIP
			end if
		else
			Object.OnFloor = false
		end if

		TempValue0  = Screen.YOffset
		TempValue0 += Screen.YSize
		TempValue0 += 44
		if Object.iYPos >= TempValue0
			Object.Timer = 4
			Object.State = FALLSIGNPOST_FLIP
		end if

		Object.FrameTimer++
		if Object.FrameTimer == 2
			Object.FrameTimer = 0
			Object.Frame++
			if Object.Frame == 5
				Rand(TempValue0,48)
				TempValue0 <<= 16
				TempValue0  += Object.XPos
				TempValue0  -= 0x180000

				Rand(TempValue1,32)
				TempValue1 <<= 16
				TempValue1  += Object.YPos
				TempValue1  -= 0x140000
				CreateTempObject(TypeName[Ring Sparkle], 0, TempValue0, TempValue1)
			end if

			if Object.Frame == 9
				Object.Frame = 1
				Rand(TempValue0, 48)
				TempValue0 <<= 16
				TempValue0  += Object.XPos
				TempValue0  -= 0x180000

				Rand(TempValue1, 32)
				TempValue1 <<= 16
				TempValue1  += Object.YPos
				TempValue1  -= 0x140000
				CreateTempObject(TypeName[Ring Sparkle], 0, TempValue0, TempValue1)
			end if
		end if
		break

	case FALLSIGNPOST_FLIP
		Object.IdleTimer++
		if Stage.TimeEnabled == true
			Music.Volume -= 2
		end if

		Object.FrameTimer++
		if Object.FrameTimer == 2
			Object.FrameTimer = 0
			Object.Frame++
			if Object.Frame == 5
				Rand(TempValue0, 48)
				TempValue0 <<= 16
				TempValue0  += Object.XPos
				TempValue0  -= 0x180000

				Rand(TempValue1, 32)
				TempValue1 <<= 16
				TempValue1  += Object.YPos
				TempValue1  -= 0x140000
				CreateTempObject(TypeName[Ring Sparkle], 0, TempValue0, TempValue1)
			end if
			
			if Object.Frame == 9
				Rand(TempValue0, 48)
				TempValue0 <<= 16
				TempValue0  += Object.XPos
				TempValue0  -= 0x180000

				Rand(TempValue1, 32)
				TempValue1 <<= 16
				TempValue1  += Object.YPos
				TempValue1  -= 0x140000
				CreateTempObject(TypeName[Ring Sparkle], 0, TempValue0, TempValue1)
				Object.Timer--
				if Object.Timer == 0
					Object.Frame = 5
					Object.State = FALLSIGNPOST_STOP_PLAYER
				else
					Object.Frame = 1
				end if
			end if
		end if
		break

	case FALLSIGNPOST_STOP_PLAYER
		CheckEqual(Player.State, Player_State_Ground)
		TempValue0  = CheckResult
		CheckEqual(Player.OutOfBounds, true)
		TempValue0 |= CheckResult

		TempValue1  = Screen.XOffset
		TempValue1 += Screen.XSize
		TempValue1 += 32
		CheckGreater(Player.iXPos, TempValue1)
		TempValue0 |= CheckResult
		if TempValue0 == true
			Player.ControlMode	= CONTROLMODE_NONE
			Player.JumpHold		= false
			Player.Right		= false
			Player.Left			= false
			Player.Up			= false
			Player.Down			= false

			if Player.State == Player_State_Ground
				Player.XVelocity = 0
				Player.YVelocity = 0
			end if
			Player.Speed		= 0
			
			Screen.CameraEnabled = false
		end if
		break
	end switch

	CheckGreater(Object.IdleTimer, 60)
	TempValue0  = CheckResult
	CheckEqual(Object[30].Type, TypeName[Blank Object])
	TempValue0 &= CheckResult
	if TempValue0 == true
		EngineCallback(NOTIFY_TOUCH_SIGNPOST)
		Stage.TimeEnabled = false
		PlayMusic(1)

		Object[30].Type		 = TypeName[ActFinish]
		Object[30].DrawOrder = 6
		Object[30].Priority	 = PRIORITY_ACTIVE
	end if

	if Stage.TimeEnabled == false
		Player.AirTimer = 0
	end if
end sub


sub ObjectDraw
	if Object.State > FALLSIGNPOST_SETUP
		DrawSprite(0)
		DrawSprite(Object.Frame)
	end if
end sub


sub ObjectStartup
	LoadSpriteSheet("Global/Items2.gif")

	SpriteFrame(-12, -12, 24, 24, 0, 150)		// #0 - Sign Post
	SpriteFrame(-24, -44, 48, 32, 34, 99)		// #1 - Sign Post Head (Eggman)
	SpriteFrame(-16, -44, 32, 32, 1, 183)		// #2 - Sign Post Head (Flip 1)
	SpriteFrame(-4, -44, 8, 32, 25, 150)		// #3 - Sign Post Head (Flip 2)
	SpriteFrame(-16, -44, 32, 32, 1, 216)		// #4 - Sign Post Head (Flip 3)
	SpriteFrame(-24, -44, 48, 32, 34, 132)		// #5 - Sign Post Head (Player)
	SpriteFrame(-16, -44, 32, 32, 1, 183)		// #6 - Sign Post Head (Flip 1)
	SpriteFrame(-4, -44, 8, 32, 25, 150)		// #7 - Sign Post Head (Flip 2)
	SpriteFrame(-16, -44, 32, 32, 1, 216)		// #8 - Sign Post Head (Flip 3)

	ArrayPos0 = 32
	while ArrayPos0 < 1056
		if Object[ArrayPos0].Type == TypeName[FallSignPost]
			Object[ArrayPos0].Frame		= 1
			Object[ArrayPos0].Timer		= 16
			Object[ArrayPos0].Priority	= PRIORITY_ACTIVE
		end if
		ArrayPos0++
	loop
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
	DrawSprite(1)
end sub


sub RSDKLoad
	LoadSpriteSheet("Global/Items2.gif")

	SpriteFrame(-12, -12, 24, 24, 0, 150)		// #0 - Sign Post
	SpriteFrame(-24, -44, 48, 32, 34, 99)		// #1 - Sign Post Head (Eggman)
	
	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub