MissionAreaBL.txt

//----------Sonic CD Mission Area Bottom Left Script----------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.State	:	Object.SetBounds

// Priority
#alias 1	:	PRIORITY_ACTIVE
#alias 5	:	PRIORITY_INACTIVE


sub ObjectMain
	
	// If it hasn't been done already, set the Stage's Bottom Left boundaries
	if Object.SetBounds == false
		
		// Move the X Bounds to 16 pixels to the left of this Object
		Stage.NewXBoundary1   = Object.XPos
		Stage.NewXBoundary1 >>= 16
		Stage.NewXBoundary1  -= 16
		
		// And then move the Y Bounds to be right at this Object's position
		Stage.NewYBoundary2   = Object.YPos
		Stage.NewYBoundary2 >>= 16
		
		// Set the flag, as the bounds have been set now
		Object.SetBounds = true
	end if
	
	if Stage.State == STAGE_RUNNING
		if Player.YPos > Object.YPos
			CheckEqual(Player.State, Player_State_Death)
			TempValue0   = CheckResult
			CheckEqual(Player.State, Player_State_Drown)
			CheckResult |= TempValue0
			if CheckResult == false
				Player.YVelocity = 0
				Player.Speed	 = 0
				Player.YPos		 = Object.YPos
				game.forceKillPlayer = true
			end if
			
			// Stop the object from running any further
			Object.Priority = PRIORITY_INACTIVE
		end if
		
		if Player.XPos < Object.XPos
			Player.XVelocity = 0
			Player.Speed	 = 0
			Player.XPos		 = Object.XPos
		end if
	end if
	
end sub


sub ObjectStartup
	
	// Cycle through all objects in the scene, and make all Mission Area markers active
	ArrayPos0 = 32
	while ArrayPos0 < 1056
		if Object[ArrayPos0].Type == TypeName[MissionAreaBL]
			Object[ArrayPos0].Priority = PRIORITY_ACTIVE
		end if
		
		ArrayPos0++
	loop
	
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("Mission/Objects.gif")
	SpriteFrame(-16, -16, 32, 32, 1, 34)		// #0 - "Bottom Left" Editor Icon
	
	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub