PlatformBlock.txt

//---------------Sonic CD Platform Block Script---------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.PropertyValue	:	Object.BlocksNo


sub ObjectPlayerInteraction
	
	if Object.BlocksNo <= 1
		
		// This is a singular Block Platform, so only check Platform Collision as such
		PlayerObjectCollision(C_PLATFORM,-16,-16,16,16)
		
	else
		
		// This Object is here in the place of several Blocks
		
		// Base width is 32
		TempValue0 = 32
		
		TempValue0 *= Object.BlocksNo
		
		// Since a left collision of -16's already gonna be tested, we can cut off 16 from the right total
		TempValue0 -= 16
		
		PlayerObjectCollision(C_PLATFORM, -16, -16, TempValue0, 16)
	end if
	
end sub


sub ObjectDraw
	
	if Object.BlocksNo <= 1
		
		// Just draw a single Block sprite
		DrawSprite(0)
		
	else
		
		// Draw all the Blocks in a loop
		
		// TempValue1 really has no reason to exist here...
		// It's always the same value anyway
		
		TempValue0 = Object.XPos
		TempValue1 = Object.YPos
		TempValue2 = 0
		
		while TempValue2 < Object.BlocksNo
			DrawSpriteXY(0, TempValue0, TempValue1)
			
			// Add 32 pixels to the current Block Position
			TempValue0 += 0x200000
			
			TempValue2++
		loop
	end if
	
end sub


sub ObjectStartup
	
	LoadSpriteSheet("Mission/Objects.gif")
	
	// Block Frame
	SpriteFrame(-16, -16, 32, 32, 1, 1)
	
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	if Object.BlocksNo < 2
		DrawSprite(0)
	else
		TempValue0 = Object.XPos
		TempValue1 = 0
		while TempValue2 < Object.BlocksNo
			DrawSpriteXY(0, TempValue0, Object.YPos)
			TempValue0 += 0x200000
			TempValue1++
		loop
	end if
end sub


sub RSDKLoad
	LoadSpriteSheet("Mission/Objects.gif")
	SpriteFrame(-16, -16, 32, 32, 1, 1)
	
	SetVariableAlias(ALIAS_VAR_PROPVAL, "BlocksNo")
end sub