MovingBlock.txt

//----------------Sonic CD Moving Block Script----------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0	:	Object.Oscillation
#alias Object.Value1	:	Object.XOriginPos

// Spring Aliases
#alias Object[+1].XPos	:	Spring.XPos


sub ObjectMain
	Object.Oscillation += 2
	Object.Oscillation &= 511
	Sin(Object.XPos, Object.Oscillation)

	Object.XPos <<= 13
	Object.XPos  += Object.XOriginPos
	Spring.XPos   = Object.XPos
end sub


sub ObjectPlayerInteraction
	PlayerObjectCollision(C_BOX, -16, -16, 16, 16)
end sub


sub ObjectDraw
	DrawSprite(0)
end sub


sub ObjectStartup
	LoadSpriteSheet("R3/Objects.gif")

	SpriteFrame(-16, -16, 32, 32, 1, 1)	// #0 - Moving Block

	ArrayPos0 = 32
	while ArrayPos0 < 1056
		if Object[ArrayPos0].Type == TypeName[Moving Block]
			Object[ArrayPos0].XOriginPos = Object[ArrayPos0].XPos
		end if
		ArrayPos0++
	loop
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R3/Objects.gif")

	SpriteFrame(-16, -16, 32, 32, 1, 1)	// #0 - Moving Block

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub