CountdownBubble.txt

//-------------Sonic CD Countdown Bubble Script---------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0	:	Object.Timer
#alias Object.Value1	:	Object.Angle
#alias Object.Value2	:	Object.XDrawPos
#alias Object.Value3	:	Object.YVelocity
#alias Object.Value4	:	Object.YDrawPos

// States
#alias 0	:	COUNTDOWNBUBBLE_SETUP
#alias 1	:	COUNTDOWNBUBBLE_FRAME_1
#alias 2	:	COUNTDOWNBUBBLE_FRAME_2
#alias 3	:	COUNTDOWNBUBBLE_FRAME_3
#alias 4	:	COUNTDOWNBUBBLE_FRAME_4
#alias 5	:	COUNTDOWNBUBBLE_FRAME_5
#alias 6	:	COUNTDOWNBUBBLE_FRAME_6
#alias 7	:	COUNTDOWNBUBBLE_FRAME_7
#alias 8	:	COUNTDOWNBUBBLE_FRAME_8


sub ObjectMain
	switch Object.State
	case COUNTDOWNBUBBLE_SETUP
		Object.YPos += Object.YVelocity
		
		Object.Timer++
		if Object.Timer > 6
			Object.Timer = 0
			Object.Frame++
		end if

		if Object.Frame < 4
			Sin(Object.XPos, Object.Angle)
			Object.XPos <<= 9
			Object.XPos  += Object.XDrawPos
			
			Object.Angle += 4
			Object.Angle &= 511
		else
			TempValue0    = Object.PropertyValue
			TempValue0   *= 3
			Object.Frame += TempValue0

			Object.XDrawPos  = Object.iXPos
			Object.XDrawPos -= Screen.XOffset

			Object.YDrawPos  = Object.iYPos
			Object.YDrawPos -= Screen.YOffset

			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_1
		Object.Timer++
		if Object.Timer == 6
			Object.Timer = 0
			Object.Frame++
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_2
		Object.Timer++
		if Object.Timer == 6
			Object.Timer = 0
			Object.Frame++
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_3
		Object.Timer++
		if Object.Timer == 8
			Object.Timer = 0
			Object.Frame--
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_4
		Object.Timer++
		if Object.Timer == 8
			Object.Timer = 0
			Object.Frame++
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_5
		Object.Timer++
		if Object.Timer == 8
			Object.Timer = 0
			Object.Frame--
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_6
		Object.Timer++
		if Object.Timer == 8
			Object.Timer = 0
			Object.Frame++
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_7
		Object.Timer++
		if Object.Timer == 8
			Object.Timer = 0
			Object.Frame--
			Object.State++
		end if
		break

	case COUNTDOWNBUBBLE_FRAME_8
		Object.Timer++
		if Object.Timer == 9
			Object.Type = TypeName[Blank Object]
		end if
		break

	end switch
end sub


sub ObjectDraw
#platform: Use_Origins
	if game.playMode == BOOT_PLAYMODE_MIRRORING
		Object.Direction = FACING_LEFT
		if Object.State == COUNTDOWNBUBBLE_SETUP
			DrawSpriteFX(Object.Frame, FX_FLIP, Object.XPos, Object.YPos)
		else
			DrawSpriteScreenFX(Object.Frame, FX_FLIP, Object.XDrawPos, Object.YDrawPos)
		end if
	else
		if Object.State == COUNTDOWNBUBBLE_SETUP
			DrawSprite(Object.Frame)
		else
			DrawSpriteScreenXY(Object.Frame, Object.XDrawPos, Object.YDrawPos)
		end if
	end if
#endplatform

#platform: Use_Standalone
	if Object.State == COUNTDOWNBUBBLE_SETUP
		DrawSprite(Object.Frame)
	else
		DrawSpriteScreenXY(Object.Frame, Object.XDrawPos, Object.YDrawPos)
	end if
#endplatform
end sub


sub ObjectStartup
	LoadSpriteSheet("R4/Objects2.gif")
	
	// Small Bubbles
	SpriteFrame(-4, -4, 8, 8, 35, 135)		// #0  - Small Bubble 1
	SpriteFrame(-4, -4, 8, 8, 44, 135)		// #1  - Small Bubble 2
	SpriteFrame(-4, -4, 8, 8, 53, 135)		// #2  - Small Bubble 3

	// Countdown Bubble
	SpriteFrame(-8, -8, 16, 16, 101, 210)	// #3  - Bubble make number

	SpriteFrame(-8, -12, 16, 24, 101, 185)	// #4  - Bubble make number 5
	SpriteFrame(-8, -12, 16, 24, 67, 135)	// #5  - Bubble 5
	SpriteFrame(-8, -12, 0, 0, 67, 135)		// #6  - Bubble 5 blink

	SpriteFrame(-8, -12, 16, 24, 84, 210)	// #7  - Bubble make number 4
	SpriteFrame(-8, -12, 16, 24, 84, 135)	// #8  - Bubble 4
	SpriteFrame(-8, -12, 0, 0, 67, 135)		// #9  - Bubble 4 blink

	SpriteFrame(-8, -12, 16, 24, 67, 210)	// #10 - Bubble make number 3
	SpriteFrame(-8, -12, 16, 24, 67, 160)	// #11 - Bubble 3
	SpriteFrame(-8, -12, 0, 0, 67, 135)		// #12 - Bubble 3 blink

	SpriteFrame(-8, -12, 16, 24, 84, 210)	// #13 - Bubble make number 2
	SpriteFrame(-8, -12, 16, 24, 84, 160)	// #14 - Bubble 2
	SpriteFrame(-8, -12, 0, 0, 67, 135)		// #15 - Bubble 2 blink

	SpriteFrame(-8, -12, 16, 24, 84, 210)	// #16 - Bubble make number 1
	SpriteFrame(-8, -12, 16, 24, 67, 185)	// #17 - Bubble 1
	SpriteFrame(-8, -12, 0, 0, 67, 135)		// #18 - Bubble 1 blink

	SpriteFrame(-8, -12, 16, 24, 101, 160)	// #19 - Bubble make number 0
	SpriteFrame(-8, -12, 16, 24, 84, 185)	// #20 - Bubble 0
	SpriteFrame(-8, -12, 0, 0, 67, 135)		// #21 - Bubble 0 blink
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("Global/Display.gif")
	SpriteFrame(-16, -16, 32, 32, 1, 143)		// #0 - "Script" Icon

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub