BossSpark.txt

//-----------------Sonic CD Boss Spark Script-----------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0	:	Object.Timer
#alias Object.Value1	:	Object.XVelocity
#alias Object.Value2	:	Object.YVelocity

#alias 0	:	BOSSSPARK_GRIND
#alias 1	:	BOSSSPARK_LAND


sub ObjectMain
	
	// Have a horizontal deceleration value of 0.125 pixels per frame
	Object.XVelocity -= 0x2000
	
	// Enforce a maximum left velocity of 3 pixels per frame
	if Object.XVelocity < -0x30000
		Object.XVelocity = -0x30000
	end if
	
	// Update X movement
	Object.XPos += Object.XVelocity
	
	if Object.PropertyValue == BOSSSPARK_LAND
		
		// Move the Spark down by 0.125 pixels
		Object.YVelocity += 0x2000
		
		// Update the Spark's Y Position
		Object.YPos += Object.YVelocity
		
		// Unload when no longer needed
		if Object.OutOfBounds == true
			Object.Type = TypeName[Blank Object]
		end if
		
	else
		// For a grinding-generated Spark, just show for around half a second and disappear after that
		
		if Object.Timer < 36
			Object.Timer++
		else
			Object.Type = TypeName[Blank Object]
		end if
		
	end if
	
end sub


sub ObjectDraw
	
	TempValue0   = Object.Frame
	TempValue0 >>= 2
	
	DrawSprite(TempValue0)
	
	// Object animation is progressed here
	Object.Frame++
	Object.Frame %= 20
	
end sub


sub ObjectStartup
	LoadSpriteSheet("R5/Objects2.gif")
	
	// Boss Spark Frames
	// Their offset isn't in the center, these sprites are actually offset to the left a bit
	SpriteFrame(-2, -4, 16, 8, 131, 155)
	SpriteFrame(-2, -4, 16, 8, 131, 164)
	SpriteFrame(-2, -4, 16, 8, 131, 173)
	SpriteFrame(-2, -4, 16, 8, 131, 182)
	SpriteFrame(-2, -4, 16, 8, 148, 182)
	
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R5/Objects2.gif")
	SpriteFrame(-2, -4, 16, 8, 131, 155)

	// Although used by the object, it shouldn't be set from the editor
	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub