AngelRing.txt

//-----------------Sonic CD Angel Ring Script-----------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value3	:	Object.Timer
#alias Object.Value2	:	Object.RingTimer

// Lose Ring Aliases
#alias Object.Value0	:	Object.XVelocity
#alias Object.Value1	:	Object.YVelocity

// States
#alias 0	:	ANGELRING_INACTIVE
#alias 1	:	ANGELRING_RING_SHOWER

// Players
#alias 0	:	PLAYER_SONIC_A

// Priority
#alias 0	:	PRIORITY_BOUNDS
#alias 1	:	PRIORITY_ACTIVE


sub ObjectMain
	if Object.OutOfBounds == true
		Object.State	 = ANGELRING_INACTIVE
		Object.Timer	 = 0
		Object.RingTimer = 0
		Object.Priority  = PRIORITY_BOUNDS
	end if

	if Object.Timer > 0
		if Object.RingTimer < 12
			Object.RingTimer++
		else
			Object.RingTimer = 0
			CreateTempObject(TypeName[Lose Ring], 0, Object.XPos, Object.YPos)
			Rand(Object[TempObjectPos].XVelocity, 8)
			Object[TempObjectPos].XVelocity <<=  15
			Object[TempObjectPos].XVelocity  -=  0x14000

			Object[TempObjectPos].YVelocity   = -0x20000
			
			Object[TempObjectPos].AnimationSpeed = 256
			Object.Timer--
		end if
	end if
end sub


sub ObjectPlayerInteraction
	if Object.State == ANGELRING_INACTIVE
		PlayerObjectCollision(C_TOUCH, -64, -64, -12, 96)
		if CheckResult == true
			Object.State	 = ANGELRING_RING_SHOWER
			Object.Timer	 = 60
			Object.Priority  = PRIORITY_ACTIVE
			Object.RingTimer = 0

			// Statue Saviour
			if Stage.PlayerListPos == PLAYER_SONIC_A // PLAYER_SONIC in origins
				if Stage.DebugMode == false
					SetAchievement(5, 100)
				end if
			end if
		end if
	end if
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("Global/Display.gif")
	SpriteFrame(-16, -16, 32, 32, 1, 143)		// #0 - "Script" Icon

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub