Bomb.txt

//---------------Sonic CD Semi Bomb Script--------------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0	:	Object.Timer
#alias Object.Value1	:	Object.YVelocity

// States
#alias 0	:	BOMB_FALLING
#alias 1	:	BOMB_TICKING

// Collision Sides
#alias 0	:	CSIDE_FLOOR

// Global SFX
#alias 22	:	SFX_G_EXPLOSION


sub ObjectMain
	if Object.State == BOMB_FALLING
		Object.YPos += Object.YVelocity
		Object.YVelocity += 0x2000
		
		ObjectTileCollision(CSIDE_FLOOR, 0, 8, 0)
		if CheckResult == true
			Object.State = BOMB_TICKING
		end if
	else
		if Object.Timer < 240
			Object.Timer++
		else
			Object.Type = TypeName[Blank Object]
			CreateTempObject(TypeName[Explosion], 0, Object.XPos, Object.YPos)
			PlaySfx(SFX_G_EXPLOSION, false)
		end if

		if Object.Timer > 120
			Object.Frame   = Object.Timer
			Object.Frame  &= 3
			Object.Frame >>= 1
		end if
	end if

	if Object.OutOfBounds == true
		Object.Type = TypeName[Blank Object]
	end if
end sub


sub ObjectPlayerInteraction
	PlayerObjectCollision(C_TOUCH, -8, -8, 8, 8)
	if CheckResult == true
		CallFunction(Player_Hit)
	end if
end sub


sub ObjectDraw
	DrawSprite(Object.Frame)
end sub


sub ObjectStartup
	LoadSpriteSheet("R6/Objects.gif")

	SpriteFrame(-8, -8, 16, 16, 43, 67)	// #0 - Bomb
	SpriteFrame(-8, -8, 16, 16, 60, 67)	// #1 - Flashing Bomb
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R6/Objects.gif")

	SpriteFrame(-8, -8, 16, 16, 43, 67)	// #0 - Bomb

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub