BossSpike.txt

//-----------------Sonic CD Boss Spike Script-----------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0	:	Object.Timer

// States
#alias 0	:	BOSSSPIKE_FALLING
#alias 1	:	BOSSSPIKE_DESPAWN

// Collision Sides
#alias 0	:	CSIDE_FLOOR


sub ObjectMain
	if Object.State == BOSSSPIKE_FALLING
		Object.YPos += 0x38000
		ObjectTileCollision(CSIDE_FLOOR, 0, 12, 0)
		if CheckResult == true
			Object.State = BOSSSPIKE_DESPAWN
		end if
	else
		Object.Timer++
		if Object.Timer == 64
			Object.Type = TypeName[Blank Object]
		end if
	end if
end sub


sub ObjectPlayerInteraction
	if Object.State == BOSSSPIKE_FALLING
		PlayerObjectCollision(C_TOUCH, -4, -12, 4, 12)
		if CheckResult == true
			CallFunction(Player_Hit)
		end if
	end if
end sub


sub ObjectDraw
	TempValue0  = Object.Timer
	TempValue0 &= 7
	
	if TempValue0 < 4
		DrawSprite(0)
	end if
end sub


sub ObjectStartup
	LoadSpriteSheet("R6/Objects2.gif")

	SpriteFrame(-4, -12, 8, 24, 228, 1)	// #0 - Boss Spike
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R6/Objects2.gif")

	SpriteFrame(-4, -12, 8, 24, 228, 1)	// #0 - Boss Spike

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub