HPlatform.txt

//------------Sonic CD Horizontal Platform Script-------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value1	:	Object.OffSetXPos
#alias Object.Value2	:	Object.XVelocity
#alias Object.Value3	:	Object.Angle

// Property Values
// This property values only cover the starting position
#alias 0	:	START_MOVING_LEFT
#alias 1	:	START_MOVING_RIGHT


sub ObjectMain
	Object.Angle   = Oscillation
	Object.Angle <<= 1

	if Object.PropertyValue == START_MOVING_RIGHT
		Object.Angle += 256
	end if
	
	Sin(Object.XVelocity, Object.Angle)
	Object.XVelocity <<= 13
	Object.XVelocity  += Object.XPos
	Object.XVelocity  &= 0xFFFF0000 // Truncate the value
	Object.XVelocity  -= Object.OffSetXPos
end sub


sub ObjectPlayerInteraction
	TempValue0  = Object.XPos
	Object.XPos = Object.OffSetXPos

	PlayerObjectCollision(C_PLATFORM, -24, -12, 24, 8)
	if CheckResult == true
		Player.XPos += Object.XVelocity
		if Player.State == Player_State_SpinningTop
			Player.State = Player_State_Ground
		end if
	end if
	Object.XPos = TempValue0
end sub


sub ObjectDraw
	Sin(Object.OffSetXPos, Object.Angle)
	Object.OffSetXPos <<= 13
	Object.OffSetXPos  += Object.XPos
	Object.OffSetXPos  &= 0xFFFF0000 // Truncate the value

	DrawSpriteXY(0, Object.OffSetXPos, Object.YPos)
	DrawSpriteXY(1, Object.OffSetXPos, Object.YPos)
end sub


sub ObjectStartup
	LoadSpriteSheet("R6/Objects.gif")

	SpriteFrame(-24, -16, 48, 32, 1, 84)	// #0 - Horizontal Platform
	SpriteFrame(-8, 16, 16, 16, 35, 117)	// #1 - Platform Light

	ArrayPos0 = 32
	while ArrayPos0 < 1056
		if Object[ArrayPos0].Type == TypeName[H Platform]
			Object[ArrayPos0].DrawOrder = 4
		end if
		ArrayPos0++
	loop
end sub


// ========================
// Editor Subs
// ========================

sub RSDKEdit
	if Editor.ReturnVariable == true
		switch Editor.VariableID
		case EDIT_VAR_PROPVAL // Property Value
			CheckResult  = Object.PropertyValue
			CheckResult &= 1
			break
		case 0 // startDir
			CheckResult  = Object.PropertyValue
			CheckResult &= 1
			break
		end switch
	else
		switch Editor.VariableID
		case EDIT_VAR_PROPVAL // Property Value
			Object.PropertyValue  = Editor.VariableValue
			Object.PropertyValue &= 1
			break
		case 0 // startDir
			Object.PropertyValue  = Editor.VariableValue
			Object.PropertyValue &= 1
			break
		end switch
	end if
end sub


sub RSDKDraw
	DrawSprite(0)
	DrawSprite(1)
	switch Object.PropertyValue
	case START_MOVING_LEFT
		TempValue1 = 255
		TempValue2 = 255
		TempValue3 = 128
		TempValue4 = 0
		break
	case START_MOVING_RIGHT
		TempValue1 = 128
		TempValue2 = 0
		TempValue3 = 255
		TempValue4 = 255
		break
	end switch
	TempValue0   = Object.XPos
	TempValue0  -= 0x490000
	TempValue5   = Object.YPos
	TempValue5  -= 0x100000
	if object.PropertyValue == START_MOVING_LEFT
		DrawArrow(Object.XPos, Object.YPos, TempValue0, Object.YPos, 255, TempValue3, TempValue4, 0)
		if Editor.ShowGizmos == true
			Editor.DrawingOverlay = true
			DrawRectOutline(TempValue0, TempValue5, 0x90, 0x30, 255, 255, 255, 255)
			TempValue0   = Object.XPos
			TempValue0  += 0x490000
			DrawArrow(Object.XPos, Object.YPos, TempValue0, Object.YPos, 255, TempValue1, TempValue2, 0)
			Editor.DrawingOverlay = false
		end if
	else
		TempValue0   = Object.XPos
		TempValue0  += 0x490000
		DrawArrow(Object.XPos, Object.YPos, TempValue0, Object.YPos, 255, TempValue1, TempValue2, 0)
		if Editor.ShowGizmos == true
			Editor.DrawingOverlay = true
			TempValue0   = Object.XPos
			TempValue0  -= 0x490000
			DrawRectOutline(TempValue0, TempValue5, 0x90, 0x30, 255, 255, 255, 255)
			DrawArrow(Object.XPos, Object.YPos, TempValue0, Object.YPos, 255, TempValue3, TempValue4, 0)
			Editor.DrawingOverlay = false
		end if
	end if
	
end sub


sub RSDKLoad
	LoadSpriteSheet("R6/Objects.gif")
	SpriteFrame(-24, -16, 48, 32, 1, 84)	// #0 - Horizontal Spin Platform frame 0
	SpriteFrame(-8, 16, 16, 16, 35, 117)	// #1 - Spin Platform Light

	AddEditorVariable("startDir")
	SetActiveVariable("startDir")
	AddEnumVariable("Left", START_MOVING_LEFT)
	AddEnumVariable("Right", START_MOVING_RIGHT)
end sub