LoveHeart.txt

//-----------------Sonic CD Love Heart Script-----------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value0 : Object.Timer
#alias Object.Value1 : Object.Angle


sub ObjectDraw
	if Object.Timer > 144
		// Fade out the Heart
		
		TempValue0 = Object.Timer
		TempValue0 -= 144
		TempValue0 <<= 3
		if TempValue0 > 255
			TempValue0 = 255
		end if
		
		Object.Alpha = 255
		Object.Alpha -= TempValue0
		
		if Object.Alpha == 0
			Object.Type = TypeName[Blank Object]
		end if
	end if
	
	Sin(TempValue0, Object.Angle)
	TempValue0 <<= 9
	TempValue0 += Object.XPos
	
	if Object.Timer > 19
		// Fading heart
		
		DrawSpriteFX(1, FX_INK, TempValue0, Object.YPos)
	else
		// Normal heart
		
		DrawSpriteXY(0, TempValue0, Object.YPos)
	end if
	
	// Hover up at a rate of 0.375 pixels per frame
	Object.YPos -= 0x6000
	
	Object.Angle += 8
	Object.Angle &= 511
	
	Object.Timer++
	
end sub


sub ObjectStartup
	LoadSpriteSheet("R7/Objects2.gif")
	
	// Love Heart Frames
	SpriteFrame(-8, -8, 16, 16, 193, 134)
	SpriteFrame(-8, -8, 16, 16, 193, 150)
	
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R7/Objects2.gif")
	SpriteFrame(-8, -8, 16, 16, 193, 150)

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub