BBFireball.txt

//-------------Sonic CD Big Bomb Fireball Script--------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases
#alias Object.Value1	:	Object.XVelocity
#alias Object.Value2	:	Object.YVelocity

// Collision Plane
#alias 0	:	COLLISION_PLANE_A


sub ObjectMain
	Object.XPos += Object.XVelocity
	Object.YPos += Object.YVelocity
	Object.YVelocity += 0x2000

	if Object.OutOfBounds == true
		Object.Type = TypeName[Blank Object]
	end if
end sub


sub ObjectPlayerInteraction
	if Player.CollisionPlane == COLLISION_PLANE_A
		if Player.State != Player_State_Static
			PlayerObjectCollision(C_TOUCH, -8, -8, 8, 8)
			if CheckResult == true
				CallFunction(Player_Hit)
			end if
		end if
	end if
end sub


sub ObjectDraw
	TempValue0   = Object.AnimationTimer
	TempValue0 >>= 1
	DrawSprite(TempValue0)

	Object.AnimationTimer++
	Object.AnimationTimer &= 3
end sub


sub ObjectStartup
	LoadSpriteSheet("R8/Objects2.gif")

	SpriteFrame(-8, -8, 16, 16, 109, 110) // #0 - Big Bomb Fireball yellow frame
	SpriteFrame(-8, -8, 16, 16, 126, 110) // #1 - Big Bomb Fireball red frame
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("R8/Objects2.gif")
	SpriteFrame(-8, -8, 16, 16, 109, 110) // #0 - Big Bomb Fireball yellow

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub