WaterSplash.txt

//----------------Sonic CD WaterSplash Script-----------------//
//--------Scripted by Christian Whitehead 'The Taxman'--------//
//-------Unpacked By Rubberduckycooly's Script Unpacker-------//

// Aliases

// HUD Alias
#alias Object.Value7 : HUD.WaterTimer

// Player Alises
#alias Player.XPos : SSSonic.XPos
#alias Player.YPos : SSSonic.YPos
#alias Object.Value0 : SSSonic.ZPos

// Stage SFX
#alias 1 : SFX_S_WATERSPLASH

// Tile Info
#alias 6 : TILEINFO_ANGLEA


sub ObjectDraw
	if SSSonic.YPos > 0
		// If Sonic's in the air, he certainly isn't splashing around anymore so unload
		ResetObjectEntity(3, TypeName[Blank Object], 0, 0, 0)
	else
		
		// Find the player's truncated X and Z pos
		
		TempValue0 = SSSonic.XPos
		TempValue0 >>= 16
		
		TempValue1 = SSSonic[-1].ZPos
		TempValue1 >>= 16
		
		// Get the tile type Sonic's currently standing on
		Get16x16TileInfo(CheckResult, TempValue0, TempValue1, TILEINFO_ANGLEA)
		
		// Is it a water tile?
		if CheckResult == 2
			
			if Object.Frame == 0
				PlayStageSfx(SFX_S_WATERSPLASH, false)
				
				if Stage.TimeEnabled == true
					HUD[4].WaterTimer = 40
				end if
			end if
			
			// Animate the object
			Object.Frame++
			if Object.Frame == 40
				Object.Frame = 28
			end if
			
			// Get the frame it should draw
			TempValue0 = Object.Frame
			TempValue0 >>= 2
			
			// Draw the sprite around the center of the screen
			DrawSpriteScreenXY(TempValue0, Screen.CenterX, 224)
			
		else
			// Sonic's not on a water tile, erase the Water Splash object
			ResetObjectEntity(3, TypeName[Blank Object], 0, 0, 0)
			HUD[4].WaterTimer = 0
		end if
	end if
	
end sub


sub ObjectStartup
	
	LoadSpriteSheet("Special/Objects.gif")
	
	// Water Splash Frames
	SpriteFrame(-20, -32, 40, 32, 1, 84)
	SpriteFrame(-20, -32, 40, 32, 42, 84)
	SpriteFrame(-20, -32, 40, 32, 83, 84)
	SpriteFrame(-20, -48, 40, 48, 124, 58)
	SpriteFrame(-20, -64, 40, 64, 165, 58)
	SpriteFrame(-20, -8, 40, 8, 124, 107)
	SpriteFrame(-20, -8, 40, 8, 124, 116)
	SpriteFrame(-20, -32, 40, 32, 42, 84)
	SpriteFrame(-20, -32, 40, 32, 83, 84)
	SpriteFrame(-20, -32, 40, 32, 1, 84)
	
end sub


// ========================
// Editor Subs
// ========================

sub RSDKDraw
	DrawSprite(0)
end sub


sub RSDKLoad
	LoadSpriteSheet("Special/Objects.gif")
	SpriteFrame(-20, -32, 40, 32, 42, 84)

	SetVariableAlias(ALIAS_VAR_PROPVAL, "unused")
end sub