SM_Kerr_Newman.sagews

%auto
typeset_mode(True, display=False)

Kerr-Newman spacetime

This worksheet demonstrates a few capabilities of SageManifolds (version 0.8) in computations regarding Kerr-Newman spacetime, especially the check of Maxwell equations and Einstein equations.

It is released under the GNU General Public License version 3.

(c) Eric Gourgoulhon, Michal Bejger (2015)

The corresponding worksheet file can be downloaded from here.

 

Spacetime manifold

We start by declaring the Kerr-Newman spacetime as a 4-dimensional diffentiable manifold:

M = Manifold(4, 'M', r'\mathcal{M}')

Let us use the standard Boyer-Lindquist coordinates on it, by first introducing the part $\mathcal{M}_0$ covered by these coordinates

M0 = M.open_subset('M0', r'\mathcal{M}_0')
# BL = Boyer-Lindquist
BL.<t,r,th,ph> = M0.chart(r't r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\phi') 
print BL ; BL

chart (M0, (t, r, th, ph))

$\left(\mathcal{M}_0,(t, r, {\theta}, {\phi})\right)$

Metric tensor

The 3 parameters $m$, $a$ and $q$ of the Kerr-Newman spacetime are declared as symbolic variables:

var('m a q')

($m$, $a$, $q$)

Let us introduce the spacetime metric:

g = M.lorentz_metric('g')

The metric is defined by its components in the coordinate frame associated with Boyer-Lindquist coordinates, which is the current manifold's default frame:

rho2 = r^2 + (a*cos(th))^2
Delta = r^2 -2*m*r + a^2 + q^2
g[0,0] = -1 + (2*m*r-q^2)/rho2
g[0,3] = -a*sin(th)^2*(2*m*r-q^2)/rho2
g[1,1], g[2,2] = rho2/Delta, rho2
g[3,3] = (r^2 + a^2 + (2*m*r-q^2)*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

$g = \left( -\frac{a^{2} \cos\left({\theta}\right)^{2} + q^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{{\left(a q^{2} - 2 \, a m r\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} + q^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( a^{2} \cos\left({\theta}\right)^{2} + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{{\left(a q^{2} - 2 \, a m r\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{{\left(a^{2} q^{2} - 2 \, a^{2} m r\right)} \sin\left({\theta}\right)^{4} - {\left(a^{2} r^{2} + r^{4} + {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

g.display_comp()

$\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t } \phantom{\, t } } & = & -\frac{a^{2} \cos\left({\theta}\right)^{2} + q^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, t \, {\phi} }^{ \phantom{\, t } \phantom{\, {\phi} } } & = & \frac{{\left(a q^{2} - 2 \, a m r\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, r \, r }^{ \phantom{\, r } \phantom{\, r } } & = & \frac{a^{2} \cos\left({\theta}\right)^{2} + r^{2}}{a^{2} + q^{2} - 2 \, m r + r^{2}} \\ g_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & a^{2} \cos\left({\theta}\right)^{2} + r^{2} \\ g_{ \, {\phi} \, t }^{ \phantom{\, {\phi} } \phantom{\, t } } & = & \frac{{\left(a q^{2} - 2 \, a m r\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & -\frac{{\left(a^{2} q^{2} - 2 \, a^{2} m r\right)} \sin\left({\theta}\right)^{4} - {\left(a^{2} r^{2} + r^{4} + {\left(a^{4} + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \end{array}$

g.inverse()[0,0]

$\frac{a^{4} + 2 \, a^{2} r^{2} + r^{4} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \sin\left({\theta}\right)^{2}}{2 \, m r^{3} - r^{4} - {\left(a^{2} + q^{2}\right)} r^{2} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}$

The lapse function:

N = 1/sqrt(-(g.inverse()[[0,0]])) ; N

$\mbox{scalar field on the open subset 'M0' of the 4-dimensional manifold 'M'}$

N.display()

$\begin{array}{llcl} & \mathcal{M}_0 & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \frac{\sqrt{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \sqrt{a^{2} + q^{2} - 2 \, m r + r^{2}}}{\sqrt{a^{4} + 2 \, a^{2} r^{2} + r^{4} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \sin\left({\theta}\right)^{2}}} \end{array}$

Electromagnetic field tensor

Let us first introduce the 1-form basis associated with Boyer-Lindquist coordinates:

dBL = BL.coframe() ; dBL

$\left(\mathcal{M}_0 ,\left(\mathrm{d} t,\mathrm{d} r,\mathrm{d} {\theta},\mathrm{d} {\phi}\right)\right)$

The electromagnetic field tensor $F$ is formed as [cf. e.g. Eq. (33.5) of Misner, Thorne & Wheeler (1973)]

F = M.diff_form(2, name='F')
F.set_restriction( q/rho2^2 * (r^2-a^2*cos(th)^2)* dBL[1].wedge( dBL[0] - a*sin(th)^2* dBL[3] ) + \
    2*q/rho2^2 * a*r*cos(th)*sin(th)* dBL[2].wedge( (r^2+a^2)* dBL[3] - a* dBL[0] ) )
F.display()

$F = \left( \frac{a^{2} q \cos\left({\theta}\right)^{2} - q r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} r + \left( \frac{2 \, a^{2} q r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} {\theta} + \left( \frac{{\left(a^{3} q \cos\left({\theta}\right)^{2} - a q r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} r\wedge \mathrm{d} {\phi} + \left( \frac{2 \, {\left(a^{3} q r + a q r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$

F.display_comp()

$\begin{array}{lcl} F_{ \, t \, r }^{ \phantom{\, t } \phantom{\, r } } & = & \frac{a^{2} q \cos\left({\theta}\right)^{2} - q r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, t \, {\theta} }^{ \phantom{\, t } \phantom{\, {\theta} } } & = & \frac{2 \, a^{2} q r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, r \, t }^{ \phantom{\, r } \phantom{\, t } } & = & -\frac{a^{2} q \cos\left({\theta}\right)^{2} - q r^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, r \, {\phi} }^{ \phantom{\, r } \phantom{\, {\phi} } } & = & \frac{{\left(a^{3} q \cos\left({\theta}\right)^{2} - a q r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, {\theta} \, t }^{ \phantom{\, {\theta} } \phantom{\, t } } & = & -\frac{2 \, a^{2} q r \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, {\theta} \, {\phi} }^{ \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & \frac{2 \, {\left(a^{3} q r + a q r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, {\phi} \, r }^{ \phantom{\, {\phi} } \phantom{\, r } } & = & -\frac{{\left(a^{3} q \cos\left({\theta}\right)^{2} - a q r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ F_{ \, {\phi} \, {\theta} }^{ \phantom{\, {\phi} } \phantom{\, {\theta} } } & = & -\frac{2 \, {\left(a^{3} q r + a q r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \end{array}$

The Hodge dual of $F$:

star_F = F.hodge_star(g) ; star_F.display()

$\star F = \left( \frac{2 \, a q r \cos\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} r + \left( -\frac{{\left(a^{3} q \cos\left({\theta}\right)^{2} - a q r^{2}\right)} \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\wedge \mathrm{d} {\theta} + \left( -\frac{2 \, {\left(a^{4} q r \cos\left({\theta}\right) \sin\left({\theta}\right)^{4} - {\left(a^{4} q r + a^{2} q r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)^{2}\right)}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \right) \mathrm{d} r\wedge \mathrm{d} {\phi} + \left( \frac{{\left(a^{4} q + a^{2} q r^{2}\right)} \sin\left({\theta}\right)^{3} - {\left(a^{4} q - q r^{4}\right)} \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\wedge \mathrm{d} {\phi}$

Maxwell equations

Let us check that $F$ obeys the two (source-free) Maxwell equations:

xder(F).display()

$\mathrm{d}F = 0$

xder(star_F).display()

$\mathrm{d}\star F = 0$

Levi-Civita Connection

The Levi-Civita connection $\nabla$ associated with $g$:

nab = g.connection() ; print nab

Levi-Civita connection 'nabla_g' associated with the Lorentzian metric 'g' on the 4-dimensional manifold 'M'

Let us verify that the covariant derivative of $g$ with respect to $\nabla$ vanishes identically:

nab(g) == 0

$\mathrm{True}$

nab(g).display() # another view of the above property

$\nabla_{g} g = 0$

The nonzero Christoffel symbols (skipping those that can be deduced by symmetry of the last two indices):

g.christoffel_symbols_display()

$\begin{array}{lcl} \Gamma_{ \phantom{\, t } \, t \, r }^{ \, t \phantom{\, t } \phantom{\, r } } & = & \frac{a^{4} m + a^{2} q^{2} r + q^{2} r^{3} - m r^{4} - {\left(a^{4} m + a^{2} m r^{2}\right)} \sin\left({\theta}\right)^{2}}{2 \, m r^{5} - r^{6} - {\left(a^{2} + q^{2}\right)} r^{4} - {\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{2}} \\ \Gamma_{ \phantom{\, t } \, t \, {\theta} }^{ \, t \phantom{\, t } \phantom{\, {\theta} } } & = & \frac{{\left(a^{2} q^{2} - 2 \, a^{2} m r\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \\ \Gamma_{ \phantom{\, t } \, r \, {\phi} }^{ \, t \phantom{\, r } \phantom{\, {\phi} } } & = & \frac{{\left(a^{5} m + a^{3} q^{2} r - a^{3} m r^{2}\right)} \sin\left({\theta}\right)^{4} - {\left(a^{5} m + 2 \, a^{3} q^{2} r - 2 \, a^{3} m r^{2} + 2 \, a q^{2} r^{3} - 3 \, a m r^{4}\right)} \sin\left({\theta}\right)^{2}}{2 \, m r^{5} - r^{6} - {\left(a^{2} + q^{2}\right)} r^{4} - {\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{2}} \\ \Gamma_{ \phantom{\, t } \, {\theta} \, {\phi} }^{ \, t \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & \frac{{\left(a^{5} q^{2} - 2 \, a^{5} m r\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)^{5} - {\left(a^{5} q^{2} - 2 \, a^{5} m r + a^{3} q^{2} r^{2} - 2 \, a^{3} m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)^{3}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, t \, t }^{ \, r \phantom{\, t } \phantom{\, t } } & = & \frac{m r^{4} - {\left(2 \, m^{2} + q^{2}\right)} r^{3} + {\left(a^{2} m + 3 \, m q^{2}\right)} r^{2} - {\left(a^{4} m + a^{2} m q^{2} - 2 \, a^{2} m^{2} r + a^{2} m r^{2}\right)} \cos\left({\theta}\right)^{2} - {\left(a^{2} q^{2} + q^{4}\right)} r}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, t \, {\phi} }^{ \, r \phantom{\, t } \phantom{\, {\phi} } } & = & -\frac{{\left(a m r^{4} - {\left(2 \, a m^{2} + a q^{2}\right)} r^{3} + {\left(a^{3} m + 3 \, a m q^{2}\right)} r^{2} - {\left(a^{5} m + a^{3} m q^{2} - 2 \, a^{3} m^{2} r + a^{3} m r^{2}\right)} \cos\left({\theta}\right)^{2} - {\left(a^{3} q^{2} + a q^{4}\right)} r\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, r } \, r \, r }^{ \, r \phantom{\, r } \phantom{\, r } } & = & -\frac{a^{2} m + q^{2} r - m r^{2} - {\left(a^{2} m - a^{2} r\right)} \sin\left({\theta}\right)^{2}}{2 \, m r^{3} - r^{4} - {\left(a^{2} + q^{2}\right)} r^{2} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} \\ \Gamma_{ \phantom{\, r } \, r \, {\theta} }^{ \, r \phantom{\, r } \phantom{\, {\theta} } } & = & -\frac{a^{2} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, r } \, {\theta} \, {\theta} }^{ \, r \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & \frac{2 \, m r^{2} - r^{3} - {\left(a^{2} + q^{2}\right)} r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, r } \, {\phi} \, {\phi} }^{ \, r \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & \frac{{\left(a^{2} m r^{4} - {\left(2 \, a^{2} m^{2} + a^{2} q^{2}\right)} r^{3} + {\left(a^{4} m + 3 \, a^{2} m q^{2}\right)} r^{2} - {\left(a^{6} m + a^{4} m q^{2} - 2 \, a^{4} m^{2} r + a^{4} m r^{2}\right)} \cos\left({\theta}\right)^{2} - {\left(a^{4} q^{2} + a^{2} q^{4}\right)} r\right)} \sin\left({\theta}\right)^{4} + {\left(2 \, m r^{6} - r^{7} - {\left(a^{2} + q^{2}\right)} r^{5} + {\left(2 \, a^{4} m r^{2} - a^{4} r^{3} - {\left(a^{6} + a^{4} q^{2}\right)} r\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{4} - a^{2} r^{5} - {\left(a^{4} + a^{2} q^{2}\right)} r^{3}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, t \, t }^{ \, {\theta} \phantom{\, t } \phantom{\, t } } & = & \frac{{\left(a^{2} q^{2} - 2 \, a^{2} m r\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, t \, {\phi} }^{ \, {\theta} \phantom{\, t } \phantom{\, {\phi} } } & = & -\frac{{\left(a^{3} q^{2} - 2 \, a^{3} m r + a q^{2} r^{2} - 2 \, a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\theta} } \, r \, r }^{ \, {\theta} \phantom{\, r } \phantom{\, r } } & = & -\frac{a^{2} \cos\left({\theta}\right) \sin\left({\theta}\right)}{2 \, m r^{3} - r^{4} - {\left(a^{2} + q^{2}\right)} r^{2} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} \\ \Gamma_{ \phantom{\, {\theta} } \, r \, {\theta} }^{ \, {\theta} \phantom{\, r } \phantom{\, {\theta} } } & = & \frac{r}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, {\theta} } \, {\theta} \, {\theta} }^{ \, {\theta} \phantom{\, {\theta} } \phantom{\, {\theta} } } & = & -\frac{a^{2} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ \Gamma_{ \phantom{\, {\theta} } \, {\phi} \, {\phi} }^{ \, {\theta} \phantom{\, {\phi} } \phantom{\, {\phi} } } & = & -\frac{{\left({\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{5} - 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{3} - {\left(a^{4} q^{2} - 2 \, a^{4} m r + 2 \, a^{2} q^{2} r^{2} - 4 \, a^{2} m r^{3} - a^{2} r^{4} - r^{6}\right)} \cos\left({\theta}\right)\right)} \sin\left({\theta}\right)}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ \Gamma_{ \phantom{\, {\phi} } \, t \, r }^{ \, {\phi} \phantom{\, t } \phantom{\, r } } & = & \frac{a^{3} m \cos\left({\theta}\right)^{2} + a q^{2} r - a m r^{2}}{2 \, m r^{5} - r^{6} - {\left(a^{2} + q^{2}\right)} r^{4} - {\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{2}} \\ \Gamma_{ \phantom{\, {\phi} } \, t \, {\theta} }^{ \, {\phi} \phantom{\, t } \phantom{\, {\theta} } } & = & \frac{{\left(a q^{2} - 2 \, a m r\right)} \cos\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \\ \Gamma_{ \phantom{\, {\phi} } \, r \, {\phi} }^{ \, {\phi} \phantom{\, r } \phantom{\, {\phi} } } & = & -\frac{a^{2} q^{2} r - a^{2} m r^{2} + q^{2} r^{3} - 2 \, m r^{4} + r^{5} - {\left(a^{4} m - a^{4} r\right)} \cos\left({\theta}\right)^{4} + {\left(a^{4} m - a^{2} m r^{2} + 2 \, a^{2} r^{3}\right)} \cos\left({\theta}\right)^{2}}{2 \, m r^{5} - r^{6} - {\left(a^{2} + q^{2}\right)} r^{4} - {\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{2}} \\ \Gamma_{ \phantom{\, {\phi} } \, {\theta} \, {\phi} }^{ \, {\phi} \phantom{\, {\theta} } \phantom{\, {\phi} } } & = & \frac{a^{4} \cos\left({\theta}\right)^{5} + {\left(a^{2} q^{2} - 2 \, a^{2} m r + 2 \, a^{2} r^{2}\right)} \cos\left({\theta}\right)^{3} - {\left(a^{2} q^{2} - 2 \, a^{2} m r - r^{4}\right)} \cos\left({\theta}\right)}{{\left(a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}\right)} \sin\left({\theta}\right)} \end{array}$

Killing vectors

The default vector frame on the spacetime manifold is the coordinate basis associated with Boyer-Lindquist coordinates:

M.default_frame() is BL.frame()

$\mathrm{True}$

BL.frame()

$\left(\mathcal{M}_0 ,\left(\frac{\partial}{\partial t },\frac{\partial}{\partial r },\frac{\partial}{\partial {\theta} },\frac{\partial}{\partial {\phi} }\right)\right)$

Let us consider the first vector field of this frame:

xi = BL.frame()[0] ; xi

$\frac{\partial}{\partial t }$

print xi

vector field 'd/dt' on the open subset 'M0' of the 4-dimensional manifold 'M'

The 1-form associated to it by metric duality is

xi_form = xi.down(g) ; xi_form.display()

$\left( -\frac{a^{2} \cos\left({\theta}\right)^{2} + q^{2} - 2 \, m r + r^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t + \left( \frac{{\left(a q^{2} - 2 \, a m r\right)} \sin\left({\theta}\right)^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}$

Its covariant derivative is

nab_xi = nab(xi_form) ; print nab_xi ; nab_xi.display()

tensor field of type (0,2) on the open subset 'M0' of the 4-dimensional manifold 'M'

$\left( \frac{m r^{4} - {\left(2 \, m^{2} + q^{2}\right)} r^{3} + {\left(a^{2} m + 3 \, m q^{2}\right)} r^{2} - {\left(a^{4} m + a^{2} m q^{2} - 2 \, a^{2} m^{2} r + a^{2} m r^{2}\right)} \cos\left({\theta}\right)^{2} - {\left(a^{2} q^{2} + q^{4}\right)} r}{2 \, m r^{5} - r^{6} - {\left(a^{2} + q^{2}\right)} r^{4} - {\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{2}} \right) \mathrm{d} t\otimes \mathrm{d} r + \left( -\frac{{\left(a^{2} q^{2} - 2 \, a^{2} m r\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\otimes \mathrm{d} {\theta} + \left( -\frac{m r^{4} - {\left(2 \, m^{2} + q^{2}\right)} r^{3} + {\left(a^{2} m + 3 \, m q^{2}\right)} r^{2} - {\left(a^{4} m + a^{2} m q^{2} - 2 \, a^{2} m^{2} r + a^{2} m r^{2}\right)} \cos\left({\theta}\right)^{2} - {\left(a^{2} q^{2} + q^{4}\right)} r}{2 \, m r^{5} - r^{6} - {\left(a^{2} + q^{2}\right)} r^{4} - {\left(a^{6} + a^{4} q^{2} - 2 \, a^{4} m r + a^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(2 \, a^{2} m r^{3} - a^{2} r^{4} - {\left(a^{4} + a^{2} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{2}} \right) \mathrm{d} r\otimes \mathrm{d} t + \left( -\frac{a^{3} m \cos\left({\theta}\right)^{4} - a q^{2} r + a m r^{2} - {\left(a^{3} m - a q^{2} r + a m r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} {\phi} + \left( \frac{{\left(a^{2} q^{2} - 2 \, a^{2} m r\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} t + \left( -\frac{{\left(a^{3} q^{2} - 2 \, a^{3} m r + a q^{2} r^{2} - 2 \, a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\phi} + \left( \frac{a^{3} m \sin\left({\theta}\right)^{4} - {\left(a^{3} m + a q^{2} r - a m r^{2}\right)} \sin\left({\theta}\right)^{2}}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} r + \left( \frac{{\left(a^{3} q^{2} - 2 \, a^{3} m r + a q^{2} r^{2} - 2 \, a m r^{3}\right)} \cos\left({\theta}\right) \sin\left({\theta}\right)}{a^{4} \cos\left({\theta}\right)^{4} + 2 \, a^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\theta}$

Let us check that the vector field $\xi=\frac{\partial}{\partial t}$ obeys Killing equation:

nab_xi.symmetrize() == 0

$\mathrm{True}$

Similarly, let us check that $\chi := \frac{\partial}{\partial\phi}$ is a Killing vector:

chi = BL.frame()[3] ; chi

$\frac{\partial}{\partial {\phi} }$

nab(chi.down(g)).symmetrize() == 0

$\mathrm{True}$

Another way to check that $\xi$ and $\chi$ are Killing vectors is the vanishing of the Lie derivative of the metric tensor along them:

g.lie_der(xi) == 0

$\mathrm{True}$

g.lie_der(chi) == 0

$\mathrm{True}$

Curvature

The Ricci tensor associated with $g$:

Ric = g.ricci() ; print Ric

field of symmetric bilinear forms 'Ric(g)' on the 4-dimensional manifold 'M'

Ric.display()

$\mathrm{Ric}\left(g\right) = \left( -\frac{a^{2} q^{2} \cos\left({\theta}\right)^{2} - 2 \, a^{2} q^{2} - q^{4} + 2 \, m q^{2} r - q^{2} r^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2} - {\left(2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{q^{2}}{2 \, m r^{3} - r^{4} - {\left(a^{2} + q^{2}\right)} r^{2} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( \frac{q^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2} - {\left(2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{{\left(a^{6} q^{2} + a^{4} q^{4} - 2 \, a^{4} m q^{2} r + a^{4} q^{2} r^{2}\right)} \sin\left({\theta}\right)^{6} - {\left(a^{4} q^{4} - 2 \, a^{4} m q^{2} r + a^{2} q^{4} r^{2} - 2 \, a^{2} m q^{2} r^{3}\right)} \sin\left({\theta}\right)^{4} - {\left(a^{6} q^{2} + 3 \, a^{4} q^{2} r^{2} + 3 \, a^{2} q^{2} r^{4} + q^{2} r^{6}\right)} \sin\left({\theta}\right)^{2}}{a^{8} \cos\left({\theta}\right)^{8} + 4 \, a^{6} r^{2} \cos\left({\theta}\right)^{6} + 6 \, a^{4} r^{4} \cos\left({\theta}\right)^{4} + 4 \, a^{2} r^{6} \cos\left({\theta}\right)^{2} + r^{8}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Ric[:]

$\left(\begin{array}{rrrr} -\frac{a^{2} q^{2} \cos\left({\theta}\right)^{2} - 2 \, a^{2} q^{2} - q^{4} + 2 \, m q^{2} r - q^{2} r^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} & 0 & 0 & -\frac{2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2} - {\left(2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} \\ 0 & \frac{q^{2}}{2 \, m r^{3} - r^{4} - {\left(a^{2} + q^{2}\right)} r^{2} - {\left(a^{4} + a^{2} q^{2} - 2 \, a^{2} m r + a^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}} & 0 & 0 \\ 0 & 0 & \frac{q^{2}}{a^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 \\ -\frac{2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2} - {\left(2 \, a^{3} q^{2} + a q^{4} - 2 \, a m q^{2} r + 2 \, a q^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}{a^{6} \cos\left({\theta}\right)^{6} + 3 \, a^{4} r^{2} \cos\left({\theta}\right)^{4} + 3 \, a^{2} r^{4} \cos\left({\theta}\right)^{2} + r^{6}} & 0 & 0 & -\frac{{\left(a^{6} q^{2} + a^{4} q^{4} - 2 \, a^{4} m q^{2} r + a^{4} q^{2} r^{2}\right)} \sin\left({\theta}\right)^{6} - {\left(a^{4} q^{4} - 2 \, a^{4} m q^{2} r + a^{2} q^{4} r^{2} - 2 \, a^{2} m q^{2} r^{3}\right)} \sin\left({\theta}\right)^{4} - {\left(a^{6} q^{2} + 3 \, a^{4} q^{2} r^{2} + 3 \, a^{2} q^{2} r^{4} + q^{2} r^{6}\right)} \sin\left({\theta}\right)^{2}}{a^{8} \cos\left({\theta}\right)^{8} + 4 \, a^{6} r^{2} \cos\left({\theta}\right)^{6} + 6 \, a^{4} r^{4} \cos\left({\theta}\right)^{4} + 4 \, a^{2} r^{6} \cos\left({\theta}\right)^{2} + r^{8}} \end{array}\right)$

Let us check that in the Kerr case, i.e. when $q=0$, the Ricci tensor is zero:

Ric[:].subs(q=0)

$\left(\begin{array}{rrrr} 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 \end{array}\right)$

The Riemann curvature tensor associated with $g$:

R = g.riemann() ; print R

tensor field 'Riem(g)' of type (1,3) on the 4-dimensional manifold 'M'

The component $R^0_{\ \, 101}$ of the Riemann tensor is

R[0,1,0,1]

$\frac{4 \, a^{2} q^{2} r^{2} - 3 \, a^{2} m r^{3} + 3 \, q^{2} r^{4} - 2 \, m r^{5} + {\left(a^{4} q^{2} - 3 \, a^{4} m r\right)} \cos\left({\theta}\right)^{4} - {\left(2 \, a^{4} q^{2} - 9 \, a^{4} m r + 2 \, a^{2} q^{2} r^{2} - 7 \, a^{2} m r^{3}\right)} \cos\left({\theta}\right)^{2}}{2 \, m r^{7} - r^{8} - {\left(a^{2} + q^{2}\right)} r^{6} - {\left(a^{8} + a^{6} q^{2} - 2 \, a^{6} m r + a^{6} r^{2}\right)} \cos\left({\theta}\right)^{6} + 3 \, {\left(2 \, a^{4} m r^{3} - a^{4} r^{4} - {\left(a^{6} + a^{4} q^{2}\right)} r^{2}\right)} \cos\left({\theta}\right)^{4} + 3 \, {\left(2 \, a^{2} m r^{5} - a^{2} r^{6} - {\left(a^{4} + a^{2} q^{2}\right)} r^{4}\right)} \cos\left({\theta}\right)^{2}}$

The expression in the uncharged limit (Kerr spacetime) is

R[0,1,0,1].expr().subs(q=0).simplify_rational()

$\frac{3 \, a^{4} m r \cos\left({\theta}\right)^{4} + 3 \, a^{2} m r^{3} + 2 \, m r^{5} - {\left(9 \, a^{4} m r + 7 \, a^{2} m r^{3}\right)} \cos\left({\theta}\right)^{2}}{a^{2} r^{6} - 2 \, m r^{7} + r^{8} + {\left(a^{8} - 2 \, a^{6} m r + a^{6} r^{2}\right)} \cos\left({\theta}\right)^{6} + 3 \, {\left(a^{6} r^{2} - 2 \, a^{4} m r^{3} + a^{4} r^{4}\right)} \cos\left({\theta}\right)^{4} + 3 \, {\left(a^{4} r^{4} - 2 \, a^{2} m r^{5} + a^{2} r^{6}\right)} \cos\left({\theta}\right)^{2}}$

while in the non-rotating limit (Reissner-Nordström spacetime), it is

R[0,1,0,1].expr().subs(a=0).simplify_rational()

$-\frac{3 \, q^{2} - 2 \, m r}{q^{2} r^{2} - 2 \, m r^{3} + r^{4}}$

In the Schwarzschild limit, it reduces to

R[0,1,0,1].expr().subs(a=0, q=0).simplify_rational()

$-\frac{2 \, m}{2 \, m r^{2} - r^{3}}$

Obviously, it vanishes in the flat space limit:

R[0,1,0,1].expr().subs(m=0, a=0, q=0)

$0$

Bianchi identity

Let us check the Bianchi identity $\nabla_p R^i_{\ \, j kl} + \nabla_k R^i_{\ \, jlp} + \nabla_l R^i_{\ \, jpk} = 0$:

DR = nab(R) ; print DR  #long (takes a while)

for i in M.irange():
    for j in M.irange():
        for k in M.irange():
            for l in M.irange():
                for p in M.irange():
                    print DR[i,j,k,l,p] + DR[i,j,l,p,k] + DR[i,j,p,k,l] ,

If the last sign in the Bianchi identity is changed to minus, the identity does no longer hold:

DR[0,1,2,3,1] + DR[0,1,3,1,2] + DR[0,1,1,2,3] # should be zero (Bianchi identity)

DR[0,1,2,3,1] + DR[0,1,3,1,2] - DR[0,1,1,2,3] # note the change of the second + to -

Ricci scalar

The Ricci scalar $R = g^{\mu\nu} R_{\mu\nu}$ of the Kerr-Newman spacetime vanishes identically:

g.ricci_scalar().display()

Einstein equation

The Einstein tensor is

G = Ric - 1/2*g.ricci_scalar()*g ; print G

Since the Ricci scalar is zero, the Einstein tensor reduces to the Ricci tensor:

G == Ric

The invariant $F_{\mu\nu} F^{\mu\nu}$ of the electromagnetic field:

Fuu = F.up(g)
F2 = F['_ab']*Fuu['^ab'] ; print F2

F2.display()

The energy-momentum tensor of the electromagnetic field:

Fud = F.up(g,0)
T = 1/(4*pi)*( F['_k.']*Fud['^k_.'] - 1/4*F2 * g ); print T

T[:]

Check of the Einstein equation:

G == 8*pi*T

Kretschmann scalar

The tensor $R^\flat$, of components $R_{ijkl} = g_{ip} R^p_{\ \, jkl}$:

dR = R.down(g) ; print dR

The tensor $R^\sharp$, of components $R^{ijkl} = g^{jp} g^{kq} g^{lr} R^i_{\ \, pqr}$:

uR = R.up(g) ; print uR

The Kretschmann scalar $K := R^{ijkl} R_{ijkl}$:

Kr_scalar = uR['^ijkl']*dR['_ijkl']
Kr_scalar.display()

A variant of this expression can be obtained by invoking the factor() method:

Kr = Kr_scalar.function_chart() # coordinate function representing the scalar field in the default chart
Kr.factor()

As a check, we can compare Kr to the formula given by R. Conn Henry, Astrophys. J. 535, 350 (2000):

Kr == 8/(r^2+(a*cos(th))^2)^6 *( \
          6*m^2*(r^6 - 15*r^4*(a*cos(th))^2 + 15*r^2*(a*cos(th))^4 - (a*cos(th))^6) \
        - 12*m*q^2*r*(r^4 - 10*(a*r*cos(th))^2 + 5*(a*cos(th))^4) \
        + q^4*(7*r^4 - 34*(a*r*cos(th))^2 + 7*(a*cos(th))^4) )

The Schwarzschild value of the Kretschmann scalar is recovered by setting $a=0$ and $q=0$:

Kr.expr().subs(a=0, q=0)

K1 = Kr.expr().subs(m=1, a=0.9, q=0.5)

plot3d(K1, (r,1,3), (th, 0, pi))