# TableRing(G, L, C, verbose=False)
#
# Returns the ring R = Z_C[G].
#
#           G is a group (defined using GAP)
#           L is a list of labels for the elements of G; the
#             label order should match the output of G.Elements()
#           C is a positive integer
#
#     verbose should be set to true if you want to print
#             the operation table to check your labels

def TableRing(G, L, C, verbose=False):
    OrdG = int(G.Order())
    T = gap.EmptySCTable(OrdG,0)
    GE = G.Elements()
    GD = {g: i for i, g in enumerate(GE)}

    if verbose:
        print("Group multiplication:")
        print("---------------------")
    for i in [1..OrdG]:
        for j in [1..OrdG]:
            if verbose:
                print(L[i-1], "*", L[j-1], "=", L[GD[GE[i]*GE[j]]])
            gap.SetEntrySCTable(T,i,j,[1, GD[GE[i]*GE[j]]+1])

    O = [C]*OrdG
    return gap.RingByStructureConstants(O, T, L)

# SL(2,3) is not realizable in characteristic 2.

G = gap.SmallGroup(24,3)

# To check that L is correct, change "False" to "True" in R = TableRing(...) below and inspect the result.
#
# The element c below has order 3.

L = libgap(["1", "c", "i", "j", "-e", "c^2", "ci", "cj", "-c", "k", "-i", "-j", "c^2i", "c^2j", "-c^2", "ck", "-ci", "-cj", "-k", "c^2k", "-c^2i", "-c^2j", "-ck", "-c^2k"])
C = 2

R = TableRing(G, L, C, True)
Gens = gap.GeneratorsOfRing(R)

# t = 1 + cj + (-c) has order 8 in the group ring, so it must map to an element of Q8
# in the quotient. So our ring must be a quotient of a ring S below.
#
# The only ring whose unit group is large enough is
#     F_2[G]/(1 + cj + (-c) + k)
# which has unit group
#     C2 x SL(2,3)

t = Gens[1] + Gens[8] + Gens[9]
print("t =", t)
print("t^8 =", t^8)
print()

Q = [Gens[1], Gens[3], Gens[4], Gens[5], Gens[10], Gens[11], Gens[12], Gens[19]]

print("Checking R/(t + q) for q in", Q)
print()

for q in Q:
    I = gap.Ideal(R, [t + q])
    S = R/I
    U = S.Units()
    print("R/(t+", q, ") has unit group", U.StructureDescription())
    

# b is another element of order 8. Combining it with the case above where the
# ring realizes C2 x SL(2,3), our ring must be a quotient of one of these:

b = Gens[2] + Gens[4] + Gens[7]
print("b =", b)
print("b^8 =", b^8)
print()

Q = [Gens[1], Gens[3], Gens[4], Gens[5], Gens[10], Gens[11], Gens[12], Gens[19]]

print("Checking R/(t + k, b + q) for q in ", Q)
print()

for q in Q:
    I = gap.Ideal(R, [t + Gens[10], b + q])
    S = R/I
    U = S.Units()
    print("R/(t +", Gens[10], ", b +", q, ") has unit group", U.StructureDescription())