plot_tour_2D.ipynb

Kernel: SageMath 8.1

2-dimensional plots of functions with SageMath

%display latex

Plot of a symbolic function

A minimal plot:

plot(sin(x^2), (x, 0, 4))

Adding some options:

plot(sin(x^2), (x,0,4), color='red', thickness=2, axes_labels=[r"$\xi$", r"$y$"])

The list of options, along with some examples of use, is accessible via

plot?

It is also accessible online.

Storing the plot object in a Python variable:

g1 = plot(sin(x^2), (x,0,4), color='red', thickness=2, axes_labels=[r"$x$", r"$y$"])

type(g1)

print(g1)

Graphics object consisting of 1 graphics primitive

g1

Plot objects can be added:

g2 = plot(cos(x^2), (x,0,4), color='green', linestyle='--',
          thickness=2)

show(g1 + g2)

The command show can be used to display the object g1+g2 with extra options:

show(g1+g2, gridlines=True, aspect_ratio=1, title='A beautiful graphic')

The documentation for all possible options of show is returned by

g1.show?

It is also accessible online here.

Saving the plot in a pdf file (with the same options as in show):

(g1+g2).save("plot_sinx2_cosx2.pdf", 
             gridlines=True, aspect_ratio=1, title='A beautiful graphic')

Adding graphic objects in a Python loop:

chebyshev_T?

g = Graphics()  # an empty graphic object
for i in range(10):
    g += plot(chebyshev_T(i,x), (x,-1,1), color=hue(i/10),
              legend_label=r"$T_{}(x)$".format(i))
show(g, axes_labels=[r"$x$", r"$y$"], legend_loc='upper right')

Side remark: in the above code, we have implicitely redefined the Python variable i as an integer denoting the loop index, while i was predefined as the imaginary number $i$ such that $i^2=-1$. Consequently, we have now

i

e^(i*pi)

To restore the use of the Python name i for the imaginary number, it suffices to run

restore('i')

e^(i*pi)

Symbolic functions versus Python functions

Let us consider a symbolic function:

f(x) = sin(x^2)

f

f(x)

f(3)

We can plot f(x) as we did above for sin(x^2):

plot(f(x), (x,0,4))

It is also possible to pass the function f itself (not the symbolic expression f(x)), along with the lower and upper boundaries for the argument of f required in the plot, without having to specify any name for this argument:

plot(f, (0,4))

This second way of plotting function is actually the one that must be used for the plot of Python functions:

def f1(x):
    if x<2:
        return sin(x)
    return cos(x)

f1

f1(1)

plot(f1, (0,4))

f1(x)

# trace("f1(x)")

# diff(f1, x)

Actually, if we use the first method, we obtain a strange result:

plot(f1(x), (x,0,4))

This occurs because the argument f1(x) of the function plot is evaluated prior to any loop on the values of x within the specified interval. Since for the symbolic variable x one has

bool(x<2)

the function f1 always returns cos(x), hence the plot.

What about plotting Python functions with more than one argument? For instance suppose we want to plot the following function for some fixed value of the argument a:

def f2(x, a):
    if x<a:
        return a*sin(x)
    return a*cos(x)

plot(f2, (0,4))

verbose 0 (3749: plot.py, generate_plot_points) WARNING: When plotting, failed to evaluate function at 200 points.
verbose 0 (3749: plot.py, generate_plot_points) Last error message: 'f2() takes exactly 2 arguments (1 given)'

plot(f2, (0,4)) would return an error here. A first solution would be to wrap f2 into a single-argument Python function:

def f2_wrap(x):
    a = 1
    return f2(x,a)
plot(f2_wrap, (0,4))

A better solution is to use create an anonymous function with the Python keyword lambda:

plot(lambda x: f2(x, 1), (0,4))

In particular, it is very usefull in loops:

g = Graphics()
for i in range(10):
    a = 4/9*i
    g+=plot(lambda x: f2(x, a), (0,4), color=hue(i/10))
g

Plot from data

Let us consider a list of values, of the type $(x_i, y_i)$:

data = [(numerical_approx(i/10, digits=2), numerical_approx(sin((i/10)^2))) 
        for i in range(1, 40)]
data

We can plot it with list_plot:

g1 = list_plot(data)
g1

g1 = list_plot(data, marker='D', axes_labels=[r"$x$", r"$y$"])
g1

An alternative is to use line:

g2 = line(data, color='red')
g2

g1+g2

Plotting data from a file

fi = open("data.d", 'r')  # open file in read-only mode ('r') 
fi.readline()  # skip first line (comments)
data = []  # empty list
for line in fi:  # loop on the file lines
    xs, ys = line.split(' ')  # xs, ys = strings separated by ' '
    data.append((float(xs), float(ys)))  # conversion and add to the list
fi.close()
data

list_plot(data)