Contact
CoCalc Logo Icon
StoreFeaturesDocsShareSupport News AboutSign UpSign In
| Download

Espaces-temps anti-de Sitter et cylindres d'Einstein en dimension arbitraire.

Path: AdS.ipynb
Views: 48
Visibility: Unlisted (only visible to those who know the link)
Image: ubuntu2204
Kernel: SageMath 10.1
%display latex
Parallelism().set(nproc=8)

This notebook was written under the supervision of Éric Gourgoulhon (LUTH) as part of my physics internship in July 2023.

Author : Nicolas Seroux

Espace-temps anti-de Sitter et cylindre d'Einstein

Nous donnons ici quelques propriétés géométriques des espaces-temps anti-de Sitter AdSn+1\mathrm{AdS}_{n+1} et des espaces-temps d'Einstein Einn+1\mathrm{Ein}_{n+1}. On essaiera d'énoncer la théorie dans le cas général n≥2n\geq2, et on illustrera cette théorie par les calculs explicites dans les cas n=2n=2 et n=3n=3.

Cylindre d'Einstein

Pour, pour n≥2n\geq2, on appelle espace-temps d'Einstein universel en dimension n+1n+1 la variété Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} définie comme un produit R×Sn\mathbb{R}\times\mathbb{S}_n muni de la métrique :

gEin~n+1=−dτ+dΩn2,g_{\widetilde{\mathrm{Ein}}_{n+1}} = -\mathrm{d}\tau+\mathrm{d}\Omega_n^2,

où dΩn2\mathrm{d}\Omega_n^2 est la métrique usuelle sur Sn\mathbb{S}_n.

L'exemple classique dans le cas n=3n=3 est le cylindre d'Einstein Ein~3+1≈R×S3\widetilde{\mathrm{Ein}}_{3+1}\approx\mathbb{R}\times\mathbb{S}_3, dont la métrique est donnée dans des coordonnées naturelles (τ,χ,θ,φ)(\tau,\chi,\theta,\varphi) par :

gEin~3+1=−dτ2+dχ2+sin⁡2χ(dθ2+sin⁡2θ dφ2).g_{\widetilde{\mathrm{Ein}}_{3+1}} = -\mathrm{d}\tau^2+\mathrm{d}\chi^2 + \sin^2\chi\left(\mathrm{d}\theta^2+\sin^2\theta\, \mathrm{d}\varphi^2\right).

Pour n=2n=2, on choisit de manière analogue des coordonnées (τ,θ,φ)(\tau, \theta,\varphi) pour lesquelles :

gEin~2+1=−dτ2+dθ2+sin⁡2θ dφ2.g_{\widetilde{\mathrm{Ein}}_{2+1}} = -\mathrm{d}\tau^2+\mathrm{d}\theta^2+\sin^2\theta \,\mathrm{d}\varphi^2.

Définition de la variété d'espace-temps et des coordonnées adaptées :

Ein_U_3 = Manifold(3, 'Ein_U_3', latex_name=r'\widetilde{\mathrm{Ein}}_{2+1}',
                   structure='Lorentzian', metric_latex_name=r'g_{\widetilde{\mathrm{Ein}}_{2+1}}')
X_Ein_U_3.<tau,th,ph> = Ein_U_3.chart(r'tau:\tau th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')

Ein_U_4 = Manifold(4, 'Ein_U_4', latex_name=r'\widetilde{\mathrm{Ein}}_{3+1}',
                   structure='Lorentzian', metric_latex_name=r'g_{\widetilde{\mathrm{Ein}}_{3+1}}')
X_Ein_U_4.<tau,chi,th,ph> = Ein_U_4.chart(r'tau:\tau chi:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')

Définition de la métrique :

g_Ein_U_3 = Ein_U_3.metric()

g_Ein_U_3[0,0] = -1
g_Ein_U_3[1,1] = 1
g_Ein_U_3[2,2] = sin(th)^2

g_Ein_U_3.display()

gEin~2+1=−dτ⊗dτ+dθ⊗dθ+sin⁡(θ)2dφ⊗dφ\displaystyle g_{\widetilde{\mathrm{Ein}}_{2+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

g_Ein_U_4 = Ein_U_4.metric()

g_Ein_U_4[0,0] = -1
g_Ein_U_4[1,1] = 1
g_Ein_U_4[2,2] = sin(chi)^2
g_Ein_U_4[3,3] = sin(chi)^2*sin(th)^2

g_Ein_U_4.display()

gEin~3+1=−dτ⊗dτ+dχ⊗dχ+sin⁡(χ)2dθ⊗dθ+sin⁡(χ)2sin⁡(θ)2dφ⊗dφ\displaystyle g_{\widetilde{\mathrm{Ein}}_{3+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

On peut désormais calculer les tenseurs d'Einstein associés aux métriques gEin~2+1g_{\widetilde{\mathrm{Ein}}_{2+1}} et gEin~3+1g_{\widetilde{\mathrm{Ein}}_{3+1}}. Pour n=2n=2 :

Ric_Ein_U_3 = g_Ein_U_3.ricci()
R_Ein_U_3 = g_Ein_U_3.ricci_scalar()

G_Ein_U_3 = Ric_Ein_U_3 - 1/2*R_Ein_U_3*g_Ein_U_3
G_Ein_U_3.set_name('G', latex_name=r'G_{\mathrm{Ein}_{2+1}}')
G_Ein_U_3.display()

GEin2+1=dτ⊗dτ\displaystyle G_{\mathrm{Ein}_{2+1}} = \mathrm{d} {\tau}\otimes \mathrm{d} {\tau}

On voit donc que le cylindre d'Einstein en dimension 2+12+1 est une solution des équations d'Einstein en présence d'un fluide parfait sans pression de densité 18π\frac{1}{8\pi} suivant des orbites de ∂τ\partial_\tau, dont le tenseur énergie-impulsion est donné par :

T=18π dτ⊗dτ.T=\frac{1}{8\pi}\,\mathrm{d}\tau\otimes\mathrm{d}\tau.

Pour n=3n=3 :

Ric_Ein_U_4 = g_Ein_U_4.ricci()
R_Ein_U_4 = g_Ein_U_4.ricci_scalar()

G_Ein_U_4 = Ric_Ein_U_4-1/2*R_Ein_U_4*g_Ein_U_4
G_Ein_U_4.set_name('G', latex_name=r'G_{\mathrm{Ein}_{3+1}}')
G_Ein_U_4.display()

GEin3+1=3dτ⊗dτ−dχ⊗dχ−sin⁡(χ)2dθ⊗dθ−sin⁡(χ)2sin⁡(θ)2dφ⊗dφ\displaystyle G_{\mathrm{Ein}_{3+1}} = 3 \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} -\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} -\sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} -\sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

On voit donc que :

GEin3+1=2 dτ⊗dτ−gEin3+1G_{\mathrm{Ein}_{3+1}}=2\,\mathrm{d}\tau\otimes\mathrm{d}\tau-g_{\mathrm{Ein}_{3+1}}

ce qui montre que le cylindre d'Einstein en dimension 3+13+1 est une solution des équations d'Einstein avec constante cosmologique Λ=1\Lambda=1 en présence d'un fluide parfait sans pression de densité ρ=14π\rho=\frac{1}{4\pi} suivant des orbites de ∂τ\partial_\tau, dont le tenseur énergie-impulsion est donné par :

T=14π dτ⊗dτ.T=\frac{1}{4\pi}\,\mathrm{d}\tau\otimes\mathrm{d}\tau.

On peut également voir le cylindre d'Einstein en dimension 3+13+1 comme une solution des équations d'Einstein avec une constante cosmologique Λ\Lambda quelconque et un fluide parfait de densité ρ=3−Λ8π\rho=\frac{3-\Lambda}{8\pi} et de pression p=Λ−18πp=\frac{\Lambda-1}{8\pi} sont le tenseur énergie impulsion est donné par :

T=(ρ+p) dτ⊗dτ+p gEin~3+1=14πdτ⊗dτ+Λ−18πgEin~3+1.T=(\rho+p)\,\mathrm{d}\tau\otimes\mathrm{d}\tau+p\,g_{\widetilde{\mathrm{Ein}}_{3+1}}=\frac{1}{4\pi}\mathrm{d\tau}\otimes\mathrm{d}\tau+\frac{\Lambda-1}{8\pi}g_{\widetilde{\mathrm{Ein}}_{3+1}}.

En particulier, l'espace-temps d'Einstein en dimension 3+13+1 a une courbure scalaire constante :

R_Ein_U_4.display()

r(gEin~3+1):Ein~3+1⟶R(τ,χ,θ,φ)⟼6\displaystyle \begin{array}{llcl} \mathrm{r}\left(g_{\widetilde{\mathrm{Ein}}_{3+1}}\right):& \widetilde{\mathrm{Ein}}_{3+1} & \longrightarrow & \mathbb{R} \\ & \left({\tau}, {\chi}, {\theta}, {\varphi}\right) & \longmapsto & 6 \end{array}

En général, pour n≥2n\geq2, on a :

RicEinn+1=(n−1)gEinn+1+(n−1) dτ⊗dτ,\mathrm{Ric}_{\mathrm{Ein}_{n+1}}=(n-1)g_{\mathrm{Ein}_{n+1}}+(n-1)\,\mathrm{d}\tau\otimes\mathrm{d}\tau,

ce qui implique que la courbure scalaire est donnée par REinn+1=(n−1)(n+1)−(n−1)=n(n−1)R_{\mathrm{Ein}_{n+1}}=(n-1)(n+1)-(n-1)=n(n-1), et donc : GEinn+1=−(n−1)n−22gEinn+1+(n−1) dτ⊗dτ, G_{\mathrm{Ein}_{n+1}}=-(n-1)\frac{n-2}{2}g_{\mathrm{Ein}_{n+1}}+(n-1)\,\mathrm{d}\tau\otimes\mathrm{d}\tau, ce qui signifie que le cylindre d'Einstein de dimension n+1n+1 est une solution des équations d'Einstein avec constante cosmologique Λ\Lambda et un fluide parfait de densité ρ\rho et de pression pp avec : p=18π(Λ−(n−1)(n−2)2),p=\frac{1}{8\pi}\left(\Lambda-\frac{(n-1)(n-2)}{2}\right), ρ=18π(n(n−1)2−Λ).\rho=\frac{1}{8\pi}\left(\frac{n(n-1)}{2}-\Lambda\right). En particulier, si l'on impose une condition d'énergie forte, qui se traduit par ρ≥0\rho\geq0, p+ρ≥0p+\rho\geq0, on obtient une borne sur la constante cosmologique : Λ≤n(n−1)2.\Lambda\leq\frac{n(n-1)}{2}.

Alternativement, on peut supposer que l'espace-temps d'Einstein est solution des équations d'Einstein pour une matière sans pression - hypothèse raisonnable pour une situation cosmologique - ce qui fixe alors la valeur de la constante cosmologique Λ\Lambda et de la densité ρ\rho :

Λ=(n−1)(n−2)2,\Lambda=\frac{(n-1)(n-2)}{2},ρ=n−18π.\rho=\frac{n-1}{8\pi}.

Pour tout n≥2n\geq2, Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} est simplement connexe. L'espace-temps d'Einstein universel est en fait le recouvrement universel de l'espace-temps d'EinsteinEinn+1≈S1×Sn\mathrm{Ein}_{n+1}\approx\mathbb{S}_1\times\mathbb{S}_n. La forme de la métrique de Einn+1\mathrm{Ein}_{n+1} est similaire à celle de Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} :

Ein_3 = Manifold(3, 'Ein_3', latex_name=r'\mathrm{Ein}_{2+1}', structure='Lorentzian',
                 metric_latex_name=r'g_{\mathrm{Ein}_{2+1}}')
X_Ein_3.<tau,th,ph> = Ein_3.chart(r'tau:(0,2*pi):\tau:periodic th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')

g_Ein_3 = Ein_3.metric()

g_Ein_3[0,0] = -1
g_Ein_3[1,1] = 1
g_Ein_3[2,2] = sin(th)^2

g_Ein_3.display()

gEin2+1=−dτ⊗dτ+dθ⊗dθ+sin⁡(θ)2dφ⊗dφ\displaystyle g_{\mathrm{Ein}_{2+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

Ein_4 = Manifold(4, 'Ein_4', latex_name=r'\mathrm{Ein}_{3+1}', structure='Lorentzian',
                 metric_latex_name=r'g_{\mathrm{Ein}_{3+1}}')
X_Ein_4.<tau,chi,th,ph> = Ein_4.chart(r'tau:(0,2*pi):\tau:periodic chi:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')

g_Ein_4 = Ein_4.metric()

g_Ein_4[0,0] = -1
g_Ein_4[1,1] = 1
g_Ein_4[2,2] = sin(chi)^2
g_Ein_4[3,3] = sin(chi)^2*sin(th)^2

g_Ein_4.display()

gEin3+1=−dτ⊗dτ+dχ⊗dχ+sin⁡(χ)2dθ⊗dθ+sin⁡(χ)2sin⁡(θ)2dφ⊗dφ\displaystyle g_{\mathrm{Ein}_{3+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

On dispose d'une projection naturelle πEinn+1:Ein~n+1⟶Einn+1\pi_{\mathrm{Ein}_{n+1}}:\widetilde{\mathrm{Ein}}_{n+1}\longrightarrow\mathrm{Ein}_{n+1}, qui est de plus une isométrie. On aurait également pu partir de Einn+1\mathrm{Ein}_{n+1} et définir la métrique sur le recouvrement universel Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} comme un tiré-en-arrière par πEinn+1\pi_{\mathrm{Ein}_{n+1}}. 

pi_Ein_3 = Ein_U_3.diff_map(Ein_3, [tau, th, ph], name='pi_Ein_3', latex_name=r'\pi_{\mathrm{Ein}_{2+1}}')
pi_Ein_3.display()

πEin2+1:Ein~2+1⟶Ein2+1(τ,θ,φ)⟼(τ,θ,φ)=(τ,θ,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{Ein}_{2+1}}:& \widetilde{\mathrm{Ein}}_{2+1} & \longrightarrow & \mathrm{Ein}_{2+1} \\ & \left({\tau}, {\theta}, {\varphi}\right) & \longmapsto & \left({\tau}, {\theta}, {\varphi}\right) = \left({\tau}, {\theta}, {\varphi}\right) \end{array}

pi_Ein_4 = Ein_U_4.diff_map(Ein_4, [tau, chi, th, ph], name='pi_Ein_4', latex_name=r'\pi_{\mathrm{Ein}_{3+1}}')
pi_Ein_4.display()

πEin3+1:Ein~3+1⟶Ein3+1(τ,χ,θ,φ)⟼(τ,χ,θ,φ)=(τ,χ,θ,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{Ein}_{3+1}}:& \widetilde{\mathrm{Ein}}_{3+1} & \longrightarrow & \mathrm{Ein}_{3+1} \\ & \left({\tau}, {\chi}, {\theta}, {\varphi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\varphi}\right) = \left({\tau}, {\chi}, {\theta}, {\varphi}\right) \end{array}

Espace-temps anti-de Sitter

Espace pseudo-minkowskien R2+n\mathbb{R}^{2+n}

On définit l'espace-temps pseudo-minkowskien R2+n\mathbb{R}^{2+n} en munissant Rn+2\mathbb{R}^{n+2} de coordonnées globales (u,v,x1,⋯ ,xn)(u,v,x^1, \cdots,x^n) et d'une métrique pseudo-riemannienne plate.

R22 = Manifold(4, 'R22', r'\mathbb{R}^{2+2}', structure='pseudo-Riemannian', signature=0,
               metric_name='eta_22', metric_latex_name=r'\eta_{2+2}')

X_R22_Cart.<u,v,x,y> = R22.chart()

X_R22_Sph.<u,v,r,ph> = R22.chart(r'u v r:(0,+oo) ph:(0,2*pi):\varphi:periodic')

trans_R22_Sph_to_Cart = X_R22_Sph.transition_map(X_R22_Cart, [u, v, r*cos(ph), r*sin(ph)], restrictions2=(x^2+y^2!=0))

R23 = Manifold(5, 'R23', r'\mathbb{R}^{2+3}', structure='pseudo-Riemannian', signature=1,
               metric_name='eta_23', metric_latex_name=r'\eta_{2+3}')

X_R23_Cart.<u,v,x,y,z> = R23.chart()

X_R23_Sph.<u,v,r,th,ph> = R23.chart(r'u v r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')

trans_R23_Sph_to_Cart = X_R23_Sph.transition_map(X_R23_Cart, [u, v, r*cos(ph)*sin(th), r*sin(ph)*sin(th), r*cos(th)],
                                                 restrictions2=(x^2+y^2+z^2!=0))

La forme de la métrique mime la métrique de Minkowski, à ceci près qu'on ajoute une seconde direction temporelle :

η2+n=−du⊗du−dv⊗dv+dx1⊗dx1+⋯+dxn⊗dxn.\eta_{2+n}=-\mathrm{d}u\otimes\mathrm{d}u-\mathrm{d}v\otimes\mathrm{d}v+\mathrm{d}x^1\otimes\mathrm{d}x^1+\cdots+\mathrm{d}x^n\otimes\mathrm{d}x^n.
eta_22 = R22.metric()

eta_22[0,0], eta_22[1,1], eta_22[2,2], eta_22[3,3] = -1, -1, 1, 1

eta_22.display()

η2+2=−du⊗du−dv⊗dv+dx⊗dx+dy⊗dy\displaystyle \eta_{2+2} = -\mathrm{d} u\otimes \mathrm{d} u-\mathrm{d} v\otimes \mathrm{d} v+\mathrm{d} x\otimes \mathrm{d} x+\mathrm{d} y\otimes \mathrm{d} y

eta_23 = R23.metric()

eta_23[0,0], eta_23[1,1], eta_23[2,2], eta_23[3,3], eta_23[4,4] = -1, -1, 1, 1, 1

eta_23.display()

η2+3=−du⊗du−dv⊗dv+dx⊗dx+dy⊗dy+dz⊗dz\displaystyle \eta_{2+3} = -\mathrm{d} u\otimes \mathrm{d} u-\mathrm{d} v\otimes \mathrm{d} v+\mathrm{d} x\otimes \mathrm{d} x+\mathrm{d} y\otimes \mathrm{d} y+\mathrm{d} z\otimes \mathrm{d} z

Cette métrique permet de définir une forme quadratique Q2+nQ_{2+n} sur R2+n\mathbb{R}^{2+n} dont l'expression est naturellement :

Q2+n(u,v,x1,⋯ ,xn)=−u2−v2+∑i=1n(xi)2Q_{2+n}(u,v,x^1, \cdots,x^n)=-u^2-v^2+\sum\limits_{i=1}^n(x^i)^2
Q_22 = R22.diff_map(manifolds.RealLine(), [x^2+y^2-u^2-v^2], name='Q_22', latex_name=r'Q_{2+2}')
Q_22.display()

Q2+2:R2+2⟶R(u,v,x,y)⟼t=−u2−v2+x2+y2(u,v,r,φ)⟼t=r2−u2−v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{2+2}:& \mathbb{R}^{2+2} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y\right) & \longmapsto & t = -u^{2} - v^{2} + x^{2} + y^{2} \\ & \left(u, v, r, {\varphi}\right) & \longmapsto & t = r^{2} - u^{2} - v^{2} \end{array}

Q_23 = R23.diff_map(manifolds.RealLine(), [x^2+y^2+z^2-u^2-v^2], name='Q_23', latex_name=r'Q_{2+3}')
Q_23.display()

Q2+3:R2+3⟶R(u,v,x,y,z)⟼t=−u2−v2+x2+y2+z2(u,v,r,θ,φ)⟼t=r2−u2−v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{2+3}:& \mathbb{R}^{2+3} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y, z\right) & \longmapsto & t = -u^{2} - v^{2} + x^{2} + y^{2} + z^{2} \\ & \left(u, v, r, {\theta}, {\varphi}\right) & \longmapsto & t = r^{2} - u^{2} - v^{2} \end{array}

On introduit aussi des formes quadratiques pour la norme usuelle de Rn+2\mathbb{R}^{n+2} :

Q_4 = R22.diff_map(manifolds.RealLine(), [x^2+y^2+u^2+v^2], name='Q_4', latex_name=r'Q_{4}')
Q_4.display()

Q4:R2+2⟶R(u,v,x,y)⟼t=u2+v2+x2+y2(u,v,r,φ)⟼t=r2+u2+v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{4}:& \mathbb{R}^{2+2} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y\right) & \longmapsto & t = u^{2} + v^{2} + x^{2} + y^{2} \\ & \left(u, v, r, {\varphi}\right) & \longmapsto & t = r^{2} + u^{2} + v^{2} \end{array}

Q_5 = R23.diff_map(manifolds.RealLine(), [x^2+y^2+z^2+u^2+v^2], name='Q_5', latex_name=r'Q_{5}')
Q_5.display()

Q5:R2+3⟶R(u,v,x,y,z)⟼t=u2+v2+x2+y2+z2(u,v,r,θ,φ)⟼t=r2+u2+v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{5}:& \mathbb{R}^{2+3} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y, z\right) & \longmapsto & t = u^{2} + v^{2} + x^{2} + y^{2} + z^{2} \\ & \left(u, v, r, {\theta}, {\varphi}\right) & \longmapsto & t = r^{2} + u^{2} + v^{2} \end{array}

Espace-temps anti-de Sitter

L'espace-temps anti-de Sitter AdSn+1\mathrm{AdS}_{n+1} est usuellement défini comme une sous-variété de R2+n\mathbb{R}^{2+n}. Plus précisément, AdSn+1\mathrm{AdS}_{n+1} est l'ensemble des points x∈R2+nx\in\mathbb{R}^{2+n} tels que Q2+n(x)=−ℓ2Q_{2+n}(x)=-\ell^2, où ℓ\ell est un paramètre qu'on peut supposer positif :

l = var('l', latex_name=r'\ell')
assume(l>0)

Dans tout les calculs et illustrations, on prendra ℓ=1\ell=1.

On choisit plutôt de définir AdSn+1\mathrm{AdS}_{n+1} comme une variété lorentzienne abstraite difféomorphe à S1×Rn\mathbb{S}_1\times\mathbb{R}^n que l'on munit de coordonnées sphériques sur le facteur Rn\mathbb{R}^n. On a donc des coordonnées (t,r,⋯ ,θ,φ)(t,r,\cdots,\theta,\varphi). On voit donc que AdSn+1≈S1×Rn\mathrm{AdS}_{n+1}\approx\mathbb{S}_1\times\mathbb{R}^n n'est pas simplement connexe, et on introduit aussi son revêtement universel AdS~n+1≈Rn+1\widetilde{\mathrm{AdS}}_{n+1}\approx\mathbb{R}^{n+1}.

AdS_3 = Manifold(3, 'AdS_3', latex_name=r'\mathrm{AdS}_{2+1}', structure='Lorentzian',
                 metric_latex_name=r'g_{\mathrm{AdS}_{2+1}}')
AdS_U_3 = Manifold(3, 'AdS_U_3', latex_name=r'\widetilde{\mathrm{AdS}}_{2+1}', structure='Lorentzian')

AdS_4 = Manifold(4, 'AdS_4', latex_name=r'\mathrm{AdS}_{3+1}', structure='Lorentzian',
                 metric_latex_name=r'g_{\mathrm{AdS}_{3+1}}')
AdS_U_4 = Manifold(4, 'AdS_U_4', latex_name=r'\widetilde{\mathrm{AdS}}_{3+1}', structure='Lorentzian')

X_AdS_3.<t,r,ph> = AdS_3.chart(r't:(-pi,pi) r:(0,+oo) ph:(0,2*pi):\varphi:periodic')
X_AdS_U_3.<t,r,ph> = AdS_U_3.chart(r't r:(0,+oo) ph:\varphi')

X_AdS_4.<t,r,th,ph> = AdS_4.chart(r't:(-pi,pi) r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')
X_AdS_U_4.<t,r,th,ph> = AdS_U_4.chart(r't r:(0,+oo) th:(0,pi):\theta ph:\varphi')

Le recouvrement universel est donné par la projection évidente πAdSn+1:AdS~n+1⟶AdSn+1\pi_{\mathrm{AdS}_{n+1}}:\widetilde{\mathrm{AdS}}_{n+1}\longrightarrow\mathrm{AdS}_{n+1}.

pi_AdS_3 = AdS_U_3.diff_map(AdS_3, [t,r,ph], name='pi_AdS_3',
                            latex_name=r'\pi_{\mathrm{AdS}_{2+1}}')
pi_AdS_3.display()

πAdS2+1:AdS~2+1⟶AdS2+1(t,r,φ)⟼(t,r,φ)=(t,r,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{AdS}_{2+1}}:& \widetilde{\mathrm{AdS}}_{2+1} & \longrightarrow & \mathrm{AdS}_{2+1} \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(t, r, {\varphi}\right) = \left(t, r, {\varphi}\right) \end{array}

pi_AdS_4 = AdS_U_4.diff_map(AdS_4, [t,r,th,ph], name='pi_AdS_4',
                            latex_name=r'\pi_{\mathrm{AdS}_{3+1}}')
pi_AdS_4.display()

πAdS3+1:AdS~3+1⟶AdS3+1(t,r,θ,φ)⟼(t,r,θ,φ)=(t,r,θ,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{AdS}_{3+1}}:& \widetilde{\mathrm{AdS}}_{3+1} & \longrightarrow & \mathrm{AdS}_{3+1} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(t, r, {\theta}, {\varphi}\right) = \left(t, r, {\theta}, {\varphi}\right) \end{array}

La variété abstraite AdSn+1\mathrm{AdS}_{n+1} se plonge dans R2+n\mathbb{R}^{2+n} selon :

ΦAdSn+1:(t,r,⋯ ,φ)↦(u,v,r,⋯ ,φ)=(ℓ2+r2cos⁡(tℓ),ℓ2+r2sin⁡(tℓ),r,⋯ ,φ)\Phi_{\mathrm{AdS}_{n+1}}:(t,r,\cdots,\varphi)\mapsto (u,v,r,\cdots,\varphi)=(\sqrt{\ell^2+r^2}\cos(\frac{t}{\ell}),\sqrt{\ell^2+r^2}\sin(\frac{t}{\ell}),r,\cdots,\varphi)

où R2+n≈R2×Rn\mathbb{R}^{2+n}\approx\mathbb{R}^2\times\mathbb{R}^n est muni de coordonnées sphériques sur Rn\mathbb{R}^n. 

Phi_AdS_3 = AdS_3.diff_map(R22, {(X_AdS_3, X_R22_Sph) :
                                 [sqrt(r^2+l^2)*cos(t/l), sqrt(r^2+l^2)*sin(t/l), r, ph]},
                           name='Phi_AdS_3', latex_name=r'\Phi_{\mathrm{AdS}_{2+1}}')
Phi_AdS_3.display()

ΦAdS2+1:AdS2+1⟶R2+2(t,r,φ)⟼(u,v,x,y)=(ℓ2+r2cos⁡(tℓ),ℓ2+r2sin⁡(tℓ),rcos⁡(φ),rsin⁡(φ))(t,r,φ)⟼(u,v,r,φ)=(ℓ2+r2cos⁡(tℓ),ℓ2+r2sin⁡(tℓ),r,φ)\displaystyle \begin{array}{llcl} \Phi_{\mathrm{AdS}_{2+1}}:& \mathrm{AdS}_{2+1} & \longrightarrow & \mathbb{R}^{2+2} \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(u, v, x, y\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r \cos\left({\varphi}\right), r \sin\left({\varphi}\right)\right) \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(u, v, r, {\varphi}\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r, {\varphi}\right) \end{array}

Phi_AdS_4 = AdS_4.diff_map(R23, {(X_AdS_4, X_R23_Sph) :
                                 [sqrt(r^2+l^2)*cos(t/l), sqrt(r^2+l^2)*sin(t/l), r,th, ph]},
                           name='Phi_AdS_4', latex_name=r'\Phi_{\mathrm{AdS}_{3+1}}')
Phi_AdS_4.display()

ΦAdS3+1:AdS3+1⟶R2+3(t,r,θ,φ)⟼(u,v,x,y,z)=(ℓ2+r2cos⁡(tℓ),ℓ2+r2sin⁡(tℓ),rcos⁡(φ)sin⁡(θ),rsin⁡(φ)sin⁡(θ),rcos⁡(θ))(t,r,θ,φ)⟼(u,v,r,θ,φ)=(ℓ2+r2cos⁡(tℓ),ℓ2+r2sin⁡(tℓ),r,θ,φ)\displaystyle \begin{array}{llcl} \Phi_{\mathrm{AdS}_{3+1}}:& \mathrm{AdS}_{3+1} & \longrightarrow & \mathbb{R}^{2+3} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(u, v, x, y, z\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r \cos\left({\varphi}\right) \sin\left({\theta}\right), r \sin\left({\varphi}\right) \sin\left({\theta}\right), r \cos\left({\theta}\right)\right) \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(u, v, r, {\theta}, {\varphi}\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r, {\theta}, {\varphi}\right) \end{array}

On vérifie que ΦAdSn+1\Phi_{\mathrm{AdS}_{n+1}} envoie AdSn+1\mathrm{AdS}_{n+1} dans l'ensemble des points vérifiant Q2+n(x)=−ℓ2Q_{2+n}(x)=-\ell^2.

(Q_22*Phi_AdS_3).display()

AdS2+1⟶R(t,r,φ)⟼t=−ℓ2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathrm{AdS}_{2+1} & \longrightarrow & \Bold{R} \\ & \left(t, r, {\varphi}\right) & \longmapsto & t = -{\ell}^{2} \end{array}

(Q_23*Phi_AdS_4).display()

AdS3+1⟶R(t,r,θ,φ)⟼t=−ℓ2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathrm{AdS}_{3+1} & \longrightarrow & \Bold{R} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & t = -{\ell}^{2} \end{array}

graph_AdS = X_AdS_3.plot(X_R22_Cart, mapping=Phi_AdS_3, ambient_coords=(x,u,v), fixed_coords={ph:0}, 
                    ranges={t:(-pi,pi), r:(0,2)}, number_values=9, 
                    color={t:'grey', r:'grey'}, thickness=1, parameters={l:1}, 
                    label_axes=False)

graph_AdS += X_AdS_3.plot(X_R22_Cart, mapping=Phi_AdS_3, ambient_coords=(x,u,v), fixed_coords={ph:pi}, 
                    ranges={t:(-pi,pi), r:(0,2)}, number_values=9, 
                    color={t:'grey', r:'grey'}, thickness=1, parameters={l:1}, 
                    label_axes=False)

Phi_AdS_3_u_0, Phi_AdS_3_u_pi = Phi_AdS_3.coord_functions()[0](t,r,0).subs({l:1}), Phi_AdS_3.coord_functions()[0](t,r,pi).subs({l:1})
Phi_AdS_3_v_0, Phi_AdS_3_v_pi = Phi_AdS_3.coord_functions()[1](t,r,0).subs({l:1}), Phi_AdS_3.coord_functions()[1](t,r,pi).subs({l:1})
Phi_AdS_3_x_0, Phi_AdS_3_x_pi = Phi_AdS_3.coord_functions()[2](t,r,0).subs({l:1}), Phi_AdS_3.coord_functions()[2](t,r,pi).subs({l:1})

graph_hyperboloid = parametric_plot3d([Phi_AdS_3_x_0, Phi_AdS_3_u_0, Phi_AdS_3_v_0],
                                      (t,-pi,pi), (r,0,2), color=(.8,.8,0.9))
graph_hyperboloid += parametric_plot3d([Phi_AdS_3_x_pi, Phi_AdS_3_u_pi, Phi_AdS_3_v_pi],
                                       (t,-pi,pi), (r,0,2), color=(.8,.8,0.9))

graph_AdS += graph_hyperboloid

show(graph_AdS, aspect_ratio=1, axes_labels=['x','u','v'])

La métrique gAdSn+1g_{\mathrm{AdS}_{n+1}} de AdSn+1\mathrm{AdS}_{n+1} est définie par tiré-en-arrière de la métrique plate η2+n\eta_{2+n} de R2+n\mathbb{R}^{2+n} :

gAdSn+1:=ΦAdSn+1∗η2+ng_{\mathrm{AdS}_{n+1}}:=\Phi_{\mathrm{AdS}_{n+1}}^*\eta_{2+n}
g_AdS_3 = AdS_3.metric()
g_AdS_3.set(Phi_AdS_3.pullback(eta_22))
g_AdS_3.display()

gAdS2+1=(−ℓ2+r2ℓ2)dt⊗dt+(ℓ2ℓ2+r2)dr⊗dr+r2dφ⊗dφ\displaystyle g_{\mathrm{AdS}_{2+1}} = \left( -\frac{{\ell}^{2} + r^{2}}{{\ell}^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{{\ell}^{2}}{{\ell}^{2} + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + r^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

g_AdS_4 = AdS_4.metric()
g_AdS_4.set(Phi_AdS_4.pullback(eta_23))
g_AdS_4.display()

gAdS3+1=(−ℓ2+r2ℓ2)dt⊗dt+(ℓ2ℓ2+r2)dr⊗dr+r2dθ⊗dθ+r2sin⁡(θ)2dφ⊗dφ\displaystyle g_{\mathrm{AdS}_{3+1}} = \left( -\frac{{\ell}^{2} + r^{2}}{{\ell}^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{{\ell}^{2}}{{\ell}^{2} + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + r^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + r^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

Modèles de Beltrami-Klein

Définitions

Pour l'espace hyperbolique Hn\mathbb{H}_n, on appelle modèle de Beltrami-Klein, ou modèle projectif, la représentation de Hn\mathbb{H}_n par projection sur une boule Bn\mathbb{B}_n. On donne une représentation similaire de AdSn+1\mathrm{AdS}_{n+1} par projection sur la sphère unité Sn+1\mathbb{S}_{n+1} de Rn+2\mathbb{R}^{n+2}.

Pour tout x=(u,v,x1,⋯ ,xn)∈AdSn+1x=(u,v,x_1,\cdots, x_{n})\in\mathrm{AdS}_{n+1}, on note p(x)p(x) la projection de xx sur Sn+1\mathbb{S}_{n+1}, i.e. :

p(u,v,x1,⋯ ,xn)=(u,v,x1,⋯ ,xn)u2+v2+x12+⋯+xn2.p(u,v,x_1,\cdots,x_n)=\frac{(u,v,x_1,\cdots,x_n)}{u^2+v^2+x_1^2+\cdots+x_n^2}.

Cette application fournit un plongement de AdSn+1\mathrm{AdS}_{n+1} sur l'ouvert AdSn+1\mathbb{AdS}_{n+1} de Sn+1\mathbb{S}_{n+1} des points vérifiant x12+⋯+xn2−u2−v2<0x_1^2+\cdots+x_n^2-u^2-v^2<0.

On munit Sn+1\mathbb{S}_{n+1} de coordonnées issues de la projection stéréographique selon le vecteur ene_n. Cela revient à munir Sn+1\mathbb{S}_{n+1} de coordonnées (U,V,X1,⋯ ,Xn−1)(U,V,X^1,\cdots,X^{n-1}), et de définir une injection dans R2+n\mathbb{R}^{2+n} par :

ΦSn+1:(U,V,X1,⋯ ,Xn−1)↦(2UR2+1,2VR2+1,2X1R2+1,⋯ ,2Xn−1R2+1,R2−1R2+1)\Phi_{\mathbb{S}_{n+1}}:(U,V,X^1,\cdots,X^{n-1})\mapsto(\frac{2U}{R^2+1},\frac{2V}{R^2+1}, \frac{2X^1}{R^2+1},\cdots,\frac{2X^{n-1}}{R^2+1},\frac{R^2-1}{R^2+1})

où R2:=U2+V2+(X1)2+⋯+(Xn−1)2R^2:=U^2+V^2+(X^1)^2+\cdots+(X^{n-1})^2.

S_3 = Manifold(3, 'S_3', latex_name=r'\mathbb{S}_{3}', structure='Lorentzian',
               metric_latex_name=r'g_{\mathbb{S}_{3}}')

X_S_3.<U,V,X> = S_3.chart()

Phi_S_3 = S_3.diff_map(R22, [2*U/(1+U^2+V^2+X^2), 2*V/(1+U^2+V^2+X^2), 2*X/(1+U^2+V^2+X^2),
                             (-1+U^2+V^2+X^2)/(1+U^2+V^2+X^2)],
                       name='Phi_S_3', latex_name=r'\Phi_{\mathbb{S}_3}')
Phi_S_3.display()

ΦS3:S3⟶R2+2(U,V,X)⟼(u,v,x,y)=(2 UU2+V2+X2+1,2 VU2+V2+X2+1,2 XU2+V2+X2+1,U2+V2+X2−1U2+V2+X2+1)\displaystyle \begin{array}{llcl} \Phi_{\mathbb{S}_3}:& \mathbb{S}_{3} & \longrightarrow & \mathbb{R}^{2+2} \\ & \left(U, V, X\right) & \longmapsto & \left(u, v, x, y\right) = \left(\frac{2 \, U}{U^{2} + V^{2} + X^{2} + 1}, \frac{2 \, V}{U^{2} + V^{2} + X^{2} + 1}, \frac{2 \, X}{U^{2} + V^{2} + X^{2} + 1}, \frac{U^{2} + V^{2} + X^{2} - 1}{U^{2} + V^{2} + X^{2} + 1}\right) \end{array}

S_4 = Manifold(4, 'S_4', latex_name=r'\mathbb{S}_{4}', structure='Lorentzian',
               metric_latex_name=r'g_{\mathbb{S}_{4}}')

X_S_4.<U,V,X,Y> = S_4.chart()

Phi_S_4 = S_4.diff_map(R23, [2*U/(1+U^2+V^2+X^2+Y^2), 2*V/(1+U^2+V^2+X^2+Y^2), 2*X/(1+U^2+V^2+X^2+Y^2),
                             2*Y/(1+U^2+V^2+X^2+Y^2), (-1+U^2+V^2+X^2+Y^2)/(1+U^2+V^2+X^2+Y^2)],
                       name='Phi_S_4', latex_name=r'\Phi_{\mathbb{S}_4}')
Phi_S_4.display()

ΦS4:S4⟶R2+3(U,V,X,Y)⟼(u,v,x,y,z)=(2 UU2+V2+X2+Y2+1,2 VU2+V2+X2+Y2+1,2 XU2+V2+X2+Y2+1,2 YU2+V2+X2+Y2+1,U2+V2+X2+Y2−1U2+V2+X2+Y2+1)\displaystyle \begin{array}{llcl} \Phi_{\mathbb{S}_4}:& \mathbb{S}_{4} & \longrightarrow & \mathbb{R}^{2+3} \\ & \left(U, V, X, Y\right) & \longmapsto & \left(u, v, x, y, z\right) = \left(\frac{2 \, U}{U^{2} + V^{2} + X^{2} + Y^{2} + 1}, \frac{2 \, V}{U^{2} + V^{2} + X^{2} + Y^{2} + 1}, \frac{2 \, X}{U^{2} + V^{2} + X^{2} + Y^{2} + 1}, \frac{2 \, Y}{U^{2} + V^{2} + X^{2} + Y^{2} + 1}, \frac{U^{2} + V^{2} + X^{2} + Y^{2} - 1}{U^{2} + V^{2} + X^{2} + Y^{2} + 1}\right) \end{array}

Ce plongement dans R2+n\mathbb{R}^{2+n} admet un inverse à gauche, dont l'expression est donnée par la formule usuelle de la projection stéréographique :

ΦSn+1−1:(u,v,x1,⋯ ,xn)↦(u1−xn,v1−xn,x11−xn,⋯ ,xn−11−xn)\Phi_{\mathrm{S}_{n+1}}^{-1}:(u,v,x^1,\cdots,x^n)\mapsto(\frac{u}{1-x^n},\frac{v}{1-x^n},\frac{x^1}{1-x^n},\cdots,\frac{x^{n-1}}{1-x^n})
Phi_S_3_inv = R22.diff_map(S_3, [u/(1-y), v/(1-y), x/(1-y)], name='Phi_S_3_inv',
                           latex_name=r'\Phi_{\mathbb{S}_3}^{-1}')
Phi_S_3_inv.display()

ΦS3−1:R2+2⟶S3(u,v,x,y)⟼(U,V,X)=(−uy−1,−vy−1,−xy−1)(u,v,r,φ)⟼(U,V,X)=(−ursin⁡(φ)−1,−vrsin⁡(φ)−1,−rcos⁡(φ)rsin⁡(φ)−1)\displaystyle \begin{array}{llcl} \Phi_{\mathbb{S}_3}^{-1}:& \mathbb{R}^{2+2} & \longrightarrow & \mathbb{S}_{3} \\ & \left(u, v, x, y\right) & \longmapsto & \left(U, V, X\right) = \left(-\frac{u}{y - 1}, -\frac{v}{y - 1}, -\frac{x}{y - 1}\right) \\ & \left(u, v, r, {\varphi}\right) & \longmapsto & \left(U, V, X\right) = \left(-\frac{u}{r \sin\left({\varphi}\right) - 1}, -\frac{v}{r \sin\left({\varphi}\right) - 1}, -\frac{r \cos\left({\varphi}\right)}{r \sin\left({\varphi}\right) - 1}\right) \end{array}

Phi_S_4_inv = R23.diff_map(S_4, [u/(1-z), v/(1-z), x/(1-z), y/(1-z)], name='Phi_S_4_inv',
                           latex_name=r'\Phi_{\mathbb{S}_4}^{-1}')
Phi_S_4_inv.display()

ΦS4−1:R2+3⟶S4(u,v,x,y,z)⟼(U,V,X,Y)=(−uz−1,−vz−1,−xz−1,−yz−1)(u,v,r,θ,φ)⟼(U,V,X,Y)=(−urcos⁡(θ)−1,−vrcos⁡(θ)−1,−rcos⁡(φ)sin⁡(θ)rcos⁡(θ)−1,−rsin⁡(φ)sin⁡(θ)rcos⁡(θ)−1)\displaystyle \begin{array}{llcl} \Phi_{\mathbb{S}_4}^{-1}:& \mathbb{R}^{2+3} & \longrightarrow & \mathbb{S}_{4} \\ & \left(u, v, x, y, z\right) & \longmapsto & \left(U, V, X, Y\right) = \left(-\frac{u}{z - 1}, -\frac{v}{z - 1}, -\frac{x}{z - 1}, -\frac{y}{z - 1}\right) \\ & \left(u, v, r, {\theta}, {\varphi}\right) & \longmapsto & \left(U, V, X, Y\right) = \left(-\frac{u}{r \cos\left({\theta}\right) - 1}, -\frac{v}{r \cos\left({\theta}\right) - 1}, -\frac{r \cos\left({\varphi}\right) \sin\left({\theta}\right)}{r \cos\left({\theta}\right) - 1}, -\frac{r \sin\left({\varphi}\right) \sin\left({\theta}\right)}{r \cos\left({\theta}\right) - 1}\right) \end{array}

On vérifie que ces fonctions fournissent bien des inverses à gauche :

(Phi_S_3_inv*Phi_S_3).display()

S3⟶S3(U,V,X)⟼(U,V,X)\displaystyle \begin{array}{llcl} & \mathbb{S}_{3} & \longrightarrow & \mathbb{S}_{3} \\ & \left(U, V, X\right) & \longmapsto & \left(U, V, X\right) \end{array}

Phi_S_3_inv*Phi_S_3 == S_3.identity_map()

True\displaystyle \mathrm{True}

(Phi_S_4_inv*Phi_S_4).display()

S4⟶S4(U,V,X,Y)⟼(U,V,X,Y)\displaystyle \begin{array}{llcl} & \mathbb{S}_{4} & \longrightarrow & \mathbb{S}_{4} \\ & \left(U, V, X, Y\right) & \longmapsto & \left(U, V, X, Y\right) \end{array}

Phi_S_4_inv*Phi_S_4 == S_4.identity_map()

True\displaystyle \mathrm{True}

Avec ce plongement de la sphère, la condition (x1)2+⋯(xn)2−u2−v2<0(x^1)^2+\cdots(x^n)^2-u^2-v^2<0 qui définit AdSn+1⊂Sn+1\mathbb{AdS}_{n+1}\subset\mathbb{S}_{n+1} s'écrit :

4∑i=1n−1(Xi)2+(U2+V2+∑i=1n−1(Xi)2−1)2−4U2−4V2<0,4\sum\limits_{i=1}^{n-1}(X^i)^2+(U^2+V^2+\sum\limits_{i=1}^{n-1}(X^i)^2-1)^2-4U^2-4V^2<0,

ou encore :

(1+U2+V2+∑i=1n−1(Xi)2)2<8(U2+V2).(1+U^2+V^2+\sum\limits_{i=1}^{n-1}(X^i)^2)^2<8(U^2+V^2).
AdS_Klein_3 = S_3.open_subset(name='AdS_Klein_3', latex_name=r'\mathbb{AdS}_{2+1}}',
                              coord_def={X_S_3 : (1+U^2+V^2+X^2)^2<8*(U^2+V^2)})

AdS_Klein_4 = S_4.open_subset(name='AdS_Klein_4', latex_name=r'\mathbb{AdS}_{3+1}}',
                              coord_def={X_S_4 : (1+U^2+V^2+X^2+Y^2)^2<8*(U^2+V^2)})

On peut maintenant définir un difféomorphisme pn+1p_{n+1} entre AdSn+1\mathrm{AdS}_{n+1} et AdSn+1\mathbb{AdS}_{n+1}, en projetant sur Sn+1\mathbb{S}_{n+1} l'application de normalisation p~:AdSn+1⟶R2+n\tilde{p}:\mathrm{AdS}_{n+1}\longrightarrow\mathbb{R}^{2+n} . Plus explicitement, pn+1=ΦSn+1∘p~n+1p_{n+1}=\Phi_{\mathbb{S}_{n+1}}\circ\tilde{p}_{n+1} où p~n+1\tilde{p}_{n+1} est donnée par :

p~n+1(u,v,x1,⋯ ,xn)=(u,v,x1,⋯ ,xn)u2+v2+x12+⋯+xn2.\tilde{p}_{n+1}(u,v,x_1,\cdots,x_n)=\frac{(u,v,x_1,\cdots,x_n)}{u^2+v^2+x_1^2+\cdots+x_n^2}.
p_tilde_3 = AdS_3.diff_map(R22,{(X_AdS_3, X_R22_Cart) : 
                                [sqrt(r^2+l^2)*cos(t/l)/sqrt(l^2+2*r^2),
                                 sqrt(r^2+l^2)*sin(t/l)/sqrt(l^2+2*r^2),
                                 r*cos(ph)/sqrt(l^2+2*r^2),
                                 r*sin(ph)/sqrt(l^2+2*r^2)]})

p_tilde_3.display()

AdS2+1⟶R2+2(t,r,φ)⟼(u,v,x,y)=(ℓ2+r2cos⁡(tℓ)ℓ2+2 r2,ℓ2+r2sin⁡(tℓ)ℓ2+2 r2,rcos⁡(φ)ℓ2+2 r2,rsin⁡(φ)ℓ2+2 r2)\displaystyle \begin{array}{llcl} & \mathrm{AdS}_{2+1} & \longrightarrow & \mathbb{R}^{2+2} \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(u, v, x, y\right) = \left(\frac{\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{\sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{r \cos\left({\varphi}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{r \sin\left({\varphi}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}\right) \end{array}

p_tilde_4 = AdS_4.diff_map(R23,{(X_AdS_4, X_R23_Cart) :
                                [sqrt(r^2+l^2)*cos(t/l)/sqrt(l^2+2*r^2),
                                 sqrt(r^2+l^2)*sin(t/l)/sqrt(l^2+2*r^2),
                                 r*cos(ph)*sin(th)/sqrt(l^2+2*r^2),
                                 r*sin(ph)*sin(th)/sqrt(l^2+2*r^2),
                                 r*cos(th)/sqrt(l^2+2*r^2)]})

p_tilde_4.display()

AdS3+1⟶R2+3(t,r,θ,φ)⟼(u,v,x,y,z)=(ℓ2+r2cos⁡(tℓ)ℓ2+2 r2,ℓ2+r2sin⁡(tℓ)ℓ2+2 r2,rcos⁡(φ)sin⁡(θ)ℓ2+2 r2,rsin⁡(φ)sin⁡(θ)ℓ2+2 r2,rcos⁡(θ)ℓ2+2 r2)\displaystyle \begin{array}{llcl} & \mathrm{AdS}_{3+1} & \longrightarrow & \mathbb{R}^{2+3} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(u, v, x, y, z\right) = \left(\frac{\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{\sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{r \cos\left({\varphi}\right) \sin\left({\theta}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{r \sin\left({\varphi}\right) \sin\left({\theta}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}, \frac{r \cos\left({\theta}\right)}{\sqrt{{\ell}^{2} + 2 \, r^{2}}}\right) \end{array}

On vérifie que ces applications envoient bien AdSn+1\mathrm{AdS}_{n+1} sur Sn+1\mathbb{S}_{n+1} :

(Q_4*p_tilde_3).display()

AdS2+1⟶R(t,r,φ)⟼t=1\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathrm{AdS}_{2+1} & \longrightarrow & \Bold{R} \\ & \left(t, r, {\varphi}\right) & \longmapsto & t = 1 \end{array}

(Q_5*p_tilde_4).display()

AdS3+1⟶R(t,r,θ,φ)⟼t=1\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathrm{AdS}_{3+1} & \longrightarrow & \Bold{R} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & t = 1 \end{array}

Cela autorise la définition pn+1=ΦSn+1∘p~n+1p_{n+1}=\Phi_{\mathbb{S}_{n+1}}\circ\tilde{p}_{n+1}.

p_3 = Phi_S_3_inv*p_tilde_3

p_4 = Phi_S_4_inv*p_tilde_4

Représentation graphique

On peut représenter graphiquement une section x=0x=0 du plongement de AdS2+1\mathrm{AdS}_{2+1} et AdS2+1\mathbb{AdS}_{2+1} dans R2+2\mathbb{R}^{2+2}. 

graph_AdS_Klein = graph_AdS

graph_sphere = X_S_3.plot(X_R22_Cart, mapping=Phi_S_3, ambient_coords=(y,u,v),
                          fixed_coords={X:0}, ranges={U:(-5,5), V:(-5,5)},
                          number_values=30, color={U:'grey', V:'grey'}, thickness=1,
                          label_axes=False)

Phi_S_3_u_0 = Phi_S_3.coord_functions()[0](U,V,0)
Phi_S_3_v_0 = Phi_S_3.coord_functions()[1](U,V,0)
Phi_S_3_y_0 = Phi_S_3.coord_functions()[3](U,V,0)

graph_sphere += parametric_plot3d([Phi_S_3_y_0, Phi_S_3_u_0, Phi_S_3_v_0],
                                  (U,-5,5), (V,-5,5), color=(.5,.5,0.9))

graph_AdS_Klein += graph_sphere

graph_image_Klein = X_AdS_3.plot(X_R22_Cart, mapping=p_tilde_3, ambient_coords=(y,u,v),
                                 fixed_coords={ph:pi/2}, ranges={t:(0,2*pi), r:(0,10)},
                                 number_values=10, color={t:'red', r:'red'}, thickness=1,
                                 parameters={l:1}, label_axes=False)

graph_image_Klein += X_AdS_3.plot(X_R22_Cart, mapping=p_tilde_3, ambient_coords=(y,u,v),
                                  fixed_coords={ph:-pi/2}, ranges={t:(0,2*pi), r:(0,10)},
                                  number_values=10, color={t:'red', r:'red'}, thickness=1,
                                  parameters={l:1}, label_axes=False)

p_tilde_3_u_p = p_tilde_3.coord_functions()[0](t,r,pi/2).subs({l:1})
p_tilde_3_v_p = p_tilde_3.coord_functions()[1](t,r,pi/2).subs({l:1})
p_tilde_3_y_p = p_tilde_3.coord_functions()[3](t,r,pi/2).subs({l:1})

p_tilde_3_u_m = p_tilde_3.coord_functions()[0](t,r,-pi/2).subs({l:1})
p_tilde_3_v_m = p_tilde_3.coord_functions()[1](t,r,-pi/2).subs({l:1})
p_tilde_3_y_m = p_tilde_3.coord_functions()[3](t,r,-pi/2).subs({l:1})

graph_image_Klein += parametric_plot3d([p_tilde_3_y_p, p_tilde_3_u_p, p_tilde_3_v_p],
                                       (t,-pi,pi), (r,0,10), plot_points=200, color=(.9,.5,0.5))
graph_image_Klein += parametric_plot3d([p_tilde_3_y_m, p_tilde_3_u_m, p_tilde_3_v_m],
                                       (t,-pi,pi), (r,0,10), plot_points=200, color=(.9,.5,0.5))

graph_AdS_Klein += graph_image_Klein
show(graph_AdS_Klein, aspect_ratio=1, axes_labels=['y','u','v'])