Contact
CoCalc Logo Icon
StoreFeaturesDocsShareSupportNewsAboutSign UpSign In
| Download

Espaces-temps anti-de Sitter et cylindres d'Einstein en dimension arbitraire.

Path: AdS.ipynb
Views: 51
Visibility: Unlisted (only visible to those who know the link)
Image: ubuntu2204
Kernel: SageMath 10.1
%display latex Parallelism().set(nproc=8)

This notebook was written under the supervision of Éric Gourgoulhon (LUTH) as part of my physics internship in July 2023.

Author : Nicolas Seroux

Espace-temps anti-de Sitter et cylindre d'Einstein

Nous donnons ici quelques propriétés géométriques des espaces-temps anti-de Sitter AdSn+1\mathrm{AdS}_{n+1} et des espaces-temps d'Einstein Einn+1\mathrm{Ein}_{n+1}. On essaiera d'énoncer la théorie dans le cas général n2n\geq2, et on illustrera cette théorie par les calculs explicites dans les cas n=2n=2 et n=3n=3.

Cylindre d'Einstein

Pour, pour n2n\geq2, on appelle espace-temps d'Einstein universel en dimension n+1n+1 la variété Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} définie comme un produit R×Sn\mathbb{R}\times\mathbb{S}_n muni de la métrique :

gEin~n+1=dτ+dΩn2,g_{\widetilde{\mathrm{Ein}}_{n+1}} = -\mathrm{d}\tau+\mathrm{d}\Omega_n^2,

dΩn2\mathrm{d}\Omega_n^2 est la métrique usuelle sur Sn\mathbb{S}_n.

L'exemple classique dans le cas n=3n=3 est le cylindre d'Einstein Ein~3+1R×S3\widetilde{\mathrm{Ein}}_{3+1}\approx\mathbb{R}\times\mathbb{S}_3, dont la métrique est donnée dans des coordonnées naturelles (τ,χ,θ,φ)(\tau,\chi,\theta,\varphi) par :

gEin~3+1=dτ2+dχ2+sin2χ(dθ2+sin2θdφ2).g_{\widetilde{\mathrm{Ein}}_{3+1}} = -\mathrm{d}\tau^2+\mathrm{d}\chi^2 + \sin^2\chi\left(\mathrm{d}\theta^2+\sin^2\theta\, \mathrm{d}\varphi^2\right).

Pour n=2n=2, on choisit de manière analogue des coordonnées (τ,θ,φ)(\tau, \theta,\varphi) pour lesquelles :

gEin~2+1=dτ2+dθ2+sin2θdφ2.g_{\widetilde{\mathrm{Ein}}_{2+1}} = -\mathrm{d}\tau^2+\mathrm{d}\theta^2+\sin^2\theta \,\mathrm{d}\varphi^2.

Définition de la variété d'espace-temps et des coordonnées adaptées :

Ein_U_3 = Manifold(3, 'Ein_U_3', latex_name=r'\widetilde{\mathrm{Ein}}_{2+1}', structure='Lorentzian', metric_latex_name=r'g_{\widetilde{\mathrm{Ein}}_{2+1}}') X_Ein_U_3.<tau,th,ph> = Ein_U_3.chart(r'tau:\tau th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')
Ein_U_4 = Manifold(4, 'Ein_U_4', latex_name=r'\widetilde{\mathrm{Ein}}_{3+1}', structure='Lorentzian', metric_latex_name=r'g_{\widetilde{\mathrm{Ein}}_{3+1}}') X_Ein_U_4.<tau,chi,th,ph> = Ein_U_4.chart(r'tau:\tau chi:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic')

Définition de la métrique :

g_Ein_U_3 = Ein_U_3.metric() g_Ein_U_3[0,0] = -1 g_Ein_U_3[1,1] = 1 g_Ein_U_3[2,2] = sin(th)^2 g_Ein_U_3.display()

gEin~2+1=dτdτ+dθdθ+sin(θ)2dφdφ\displaystyle g_{\widetilde{\mathrm{Ein}}_{2+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

g_Ein_U_4 = Ein_U_4.metric() g_Ein_U_4[0,0] = -1 g_Ein_U_4[1,1] = 1 g_Ein_U_4[2,2] = sin(chi)^2 g_Ein_U_4[3,3] = sin(chi)^2*sin(th)^2 g_Ein_U_4.display()

gEin~3+1=dτdτ+dχdχ+sin(χ)2dθdθ+sin(χ)2sin(θ)2dφdφ\displaystyle g_{\widetilde{\mathrm{Ein}}_{3+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}


On peut désormais calculer les tenseurs d'Einstein associés aux métriques gEin~2+1g_{\widetilde{\mathrm{Ein}}_{2+1}} et gEin~3+1g_{\widetilde{\mathrm{Ein}}_{3+1}}. Pour n=2n=2 :

Ric_Ein_U_3 = g_Ein_U_3.ricci() R_Ein_U_3 = g_Ein_U_3.ricci_scalar() G_Ein_U_3 = Ric_Ein_U_3 - 1/2*R_Ein_U_3*g_Ein_U_3 G_Ein_U_3.set_name('G', latex_name=r'G_{\mathrm{Ein}_{2+1}}') G_Ein_U_3.display()

GEin2+1=dτdτ\displaystyle G_{\mathrm{Ein}_{2+1}} = \mathrm{d} {\tau}\otimes \mathrm{d} {\tau}

On voit donc que le cylindre d'Einstein en dimension 2+12+1 est une solution des équations d'Einstein en présence d'un fluide parfait sans pression de densité 18π\frac{1}{8\pi} suivant des orbites de τ\partial_\tau, dont le tenseur énergie-impulsion est donné par :

T=18πdτdτ.T=\frac{1}{8\pi}\,\mathrm{d}\tau\otimes\mathrm{d}\tau.

Pour n=3n=3 :

Ric_Ein_U_4 = g_Ein_U_4.ricci() R_Ein_U_4 = g_Ein_U_4.ricci_scalar() G_Ein_U_4 = Ric_Ein_U_4-1/2*R_Ein_U_4*g_Ein_U_4 G_Ein_U_4.set_name('G', latex_name=r'G_{\mathrm{Ein}_{3+1}}') G_Ein_U_4.display()

GEin3+1=3dτdτdχdχsin(χ)2dθdθsin(χ)2sin(θ)2dφdφ\displaystyle G_{\mathrm{Ein}_{3+1}} = 3 \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} -\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} -\sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} -\sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

On voit donc que :

GEin3+1=2dτdτgEin3+1G_{\mathrm{Ein}_{3+1}}=2\,\mathrm{d}\tau\otimes\mathrm{d}\tau-g_{\mathrm{Ein}_{3+1}}

ce qui montre que le cylindre d'Einstein en dimension 3+13+1 est une solution des équations d'Einstein avec constante cosmologique Λ=1\Lambda=1 en présence d'un fluide parfait sans pression de densité ρ=14π\rho=\frac{1}{4\pi} suivant des orbites de τ\partial_\tau, dont le tenseur énergie-impulsion est donné par :

T=14πdτdτ.T=\frac{1}{4\pi}\,\mathrm{d}\tau\otimes\mathrm{d}\tau.

On peut également voir le cylindre d'Einstein en dimension 3+13+1 comme une solution des équations d'Einstein avec une constante cosmologique Λ\Lambda quelconque et un fluide parfait de densité ρ=3Λ8π\rho=\frac{3-\Lambda}{8\pi} et de pression p=Λ18πp=\frac{\Lambda-1}{8\pi} sont le tenseur énergie impulsion est donné par :

T=(ρ+p)dτdτ+pgEin~3+1=14πdτdτ+Λ18πgEin~3+1.T=(\rho+p)\,\mathrm{d}\tau\otimes\mathrm{d}\tau+p\,g_{\widetilde{\mathrm{Ein}}_{3+1}}=\frac{1}{4\pi}\mathrm{d\tau}\otimes\mathrm{d}\tau+\frac{\Lambda-1}{8\pi}g_{\widetilde{\mathrm{Ein}}_{3+1}}.

En particulier, l'espace-temps d'Einstein en dimension 3+13+1 a une courbure scalaire constante :

R_Ein_U_4.display()

r(gEin~3+1):Ein~3+1R(τ,χ,θ,φ)6\displaystyle \begin{array}{llcl} \mathrm{r}\left(g_{\widetilde{\mathrm{Ein}}_{3+1}}\right):& \widetilde{\mathrm{Ein}}_{3+1} & \longrightarrow & \mathbb{R} \\ & \left({\tau}, {\chi}, {\theta}, {\varphi}\right) & \longmapsto & 6 \end{array}

En général, pour n2n\geq2, on a :

RicEinn+1=(n1)gEinn+1+(n1)dτdτ,\mathrm{Ric}_{\mathrm{Ein}_{n+1}}=(n-1)g_{\mathrm{Ein}_{n+1}}+(n-1)\,\mathrm{d}\tau\otimes\mathrm{d}\tau,

ce qui implique que la courbure scalaire est donnée par REinn+1=(n1)(n+1)(n1)=n(n1)R_{\mathrm{Ein}_{n+1}}=(n-1)(n+1)-(n-1)=n(n-1), et donc : GEinn+1=(n1)n22gEinn+1+(n1)dτdτ, G_{\mathrm{Ein}_{n+1}}=-(n-1)\frac{n-2}{2}g_{\mathrm{Ein}_{n+1}}+(n-1)\,\mathrm{d}\tau\otimes\mathrm{d}\tau, ce qui signifie que le cylindre d'Einstein de dimension n+1n+1 est une solution des équations d'Einstein avec constante cosmologique Λ\Lambda et un fluide parfait de densité ρ\rho et de pression pp avec : p=18π(Λ(n1)(n2)2),p=\frac{1}{8\pi}\left(\Lambda-\frac{(n-1)(n-2)}{2}\right), ρ=18π(n(n1)2Λ).\rho=\frac{1}{8\pi}\left(\frac{n(n-1)}{2}-\Lambda\right). En particulier, si l'on impose une condition d'énergie forte, qui se traduit par ρ0\rho\geq0, p+ρ0p+\rho\geq0, on obtient une borne sur la constante cosmologique : Λn(n1)2.\Lambda\leq\frac{n(n-1)}{2}.

Alternativement, on peut supposer que l'espace-temps d'Einstein est solution des équations d'Einstein pour une matière sans pression - hypothèse raisonnable pour une situation cosmologique - ce qui fixe alors la valeur de la constante cosmologique Λ\Lambda et de la densité ρ\rho :

Λ=(n1)(n2)2,\Lambda=\frac{(n-1)(n-2)}{2},ρ=n18π.\rho=\frac{n-1}{8\pi}.

Pour tout n2n\geq2, Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} est simplement connexe. L'espace-temps d'Einstein universel est en fait le recouvrement universel de l'espace-temps d'EinsteinEinn+1S1×Sn\mathrm{Ein}_{n+1}\approx\mathbb{S}_1\times\mathbb{S}_n. La forme de la métrique de Einn+1\mathrm{Ein}_{n+1} est similaire à celle de Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} :

Ein_3 = Manifold(3, 'Ein_3', latex_name=r'\mathrm{Ein}_{2+1}', structure='Lorentzian', metric_latex_name=r'g_{\mathrm{Ein}_{2+1}}') X_Ein_3.<tau,th,ph> = Ein_3.chart(r'tau:(0,2*pi):\tau:periodic th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic') g_Ein_3 = Ein_3.metric() g_Ein_3[0,0] = -1 g_Ein_3[1,1] = 1 g_Ein_3[2,2] = sin(th)^2 g_Ein_3.display()

gEin2+1=dτdτ+dθdθ+sin(θ)2dφdφ\displaystyle g_{\mathrm{Ein}_{2+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

Ein_4 = Manifold(4, 'Ein_4', latex_name=r'\mathrm{Ein}_{3+1}', structure='Lorentzian', metric_latex_name=r'g_{\mathrm{Ein}_{3+1}}') X_Ein_4.<tau,chi,th,ph> = Ein_4.chart(r'tau:(0,2*pi):\tau:periodic chi:(0,pi):\chi th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic') g_Ein_4 = Ein_4.metric() g_Ein_4[0,0] = -1 g_Ein_4[1,1] = 1 g_Ein_4[2,2] = sin(chi)^2 g_Ein_4[3,3] = sin(chi)^2*sin(th)^2 g_Ein_4.display()

gEin3+1=dτdτ+dχdχ+sin(χ)2dθdθ+sin(χ)2sin(θ)2dφdφ\displaystyle g_{\mathrm{Ein}_{3+1}} = -\mathrm{d} {\tau}\otimes \mathrm{d} {\tau}+\mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \sin\left({\chi}\right)^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}

On dispose d'une projection naturelle πEinn+1:Ein~n+1Einn+1\pi_{\mathrm{Ein}_{n+1}}:\widetilde{\mathrm{Ein}}_{n+1}\longrightarrow\mathrm{Ein}_{n+1}, qui est de plus une isométrie. On aurait également pu partir de Einn+1\mathrm{Ein}_{n+1} et définir la métrique sur le recouvrement universel Ein~n+1\widetilde{\mathrm{Ein}}_{n+1} comme un tiré-en-arrière par πEinn+1\pi_{\mathrm{Ein}_{n+1}}.

pi_Ein_3 = Ein_U_3.diff_map(Ein_3, [tau, th, ph], name='pi_Ein_3', latex_name=r'\pi_{\mathrm{Ein}_{2+1}}') pi_Ein_3.display()

πEin2+1:Ein~2+1Ein2+1(τ,θ,φ)(τ,θ,φ)=(τ,θ,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{Ein}_{2+1}}:& \widetilde{\mathrm{Ein}}_{2+1} & \longrightarrow & \mathrm{Ein}_{2+1} \\ & \left({\tau}, {\theta}, {\varphi}\right) & \longmapsto & \left({\tau}, {\theta}, {\varphi}\right) = \left({\tau}, {\theta}, {\varphi}\right) \end{array}

pi_Ein_4 = Ein_U_4.diff_map(Ein_4, [tau, chi, th, ph], name='pi_Ein_4', latex_name=r'\pi_{\mathrm{Ein}_{3+1}}') pi_Ein_4.display()

πEin3+1:Ein~3+1Ein3+1(τ,χ,θ,φ)(τ,χ,θ,φ)=(τ,χ,θ,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{Ein}_{3+1}}:& \widetilde{\mathrm{Ein}}_{3+1} & \longrightarrow & \mathrm{Ein}_{3+1} \\ & \left({\tau}, {\chi}, {\theta}, {\varphi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\varphi}\right) = \left({\tau}, {\chi}, {\theta}, {\varphi}\right) \end{array}

Espace-temps anti-de Sitter

Espace pseudo-minkowskien R2+n\mathbb{R}^{2+n}

On définit l'espace-temps pseudo-minkowskien R2+n\mathbb{R}^{2+n} en munissant Rn+2\mathbb{R}^{n+2} de coordonnées globales (u,v,x1,,xn)(u,v,x^1, \cdots,x^n) et d'une métrique pseudo-riemannienne plate.

R22 = Manifold(4, 'R22', r'\mathbb{R}^{2+2}', structure='pseudo-Riemannian', signature=0, metric_name='eta_22', metric_latex_name=r'\eta_{2+2}') X_R22_Cart.<u,v,x,y> = R22.chart() X_R22_Sph.<u,v,r,ph> = R22.chart(r'u v r:(0,+oo) ph:(0,2*pi):\varphi:periodic') trans_R22_Sph_to_Cart = X_R22_Sph.transition_map(X_R22_Cart, [u, v, r*cos(ph), r*sin(ph)], restrictions2=(x^2+y^2!=0))
R23 = Manifold(5, 'R23', r'\mathbb{R}^{2+3}', structure='pseudo-Riemannian', signature=1, metric_name='eta_23', metric_latex_name=r'\eta_{2+3}') X_R23_Cart.<u,v,x,y,z> = R23.chart() X_R23_Sph.<u,v,r,th,ph> = R23.chart(r'u v r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic') trans_R23_Sph_to_Cart = X_R23_Sph.transition_map(X_R23_Cart, [u, v, r*cos(ph)*sin(th), r*sin(ph)*sin(th), r*cos(th)], restrictions2=(x^2+y^2+z^2!=0))

La forme de la métrique mime la métrique de Minkowski, à ceci près qu'on ajoute une seconde direction temporelle :

η2+n=dududvdv+dx1dx1++dxndxn.\eta_{2+n}=-\mathrm{d}u\otimes\mathrm{d}u-\mathrm{d}v\otimes\mathrm{d}v+\mathrm{d}x^1\otimes\mathrm{d}x^1+\cdots+\mathrm{d}x^n\otimes\mathrm{d}x^n.
eta_22 = R22.metric() eta_22[0,0], eta_22[1,1], eta_22[2,2], eta_22[3,3] = -1, -1, 1, 1 eta_22.display()

η2+2=dududvdv+dxdx+dydy\displaystyle \eta_{2+2} = -\mathrm{d} u\otimes \mathrm{d} u-\mathrm{d} v\otimes \mathrm{d} v+\mathrm{d} x\otimes \mathrm{d} x+\mathrm{d} y\otimes \mathrm{d} y

eta_23 = R23.metric() eta_23[0,0], eta_23[1,1], eta_23[2,2], eta_23[3,3], eta_23[4,4] = -1, -1, 1, 1, 1 eta_23.display()

η2+3=dududvdv+dxdx+dydy+dzdz\displaystyle \eta_{2+3} = -\mathrm{d} u\otimes \mathrm{d} u-\mathrm{d} v\otimes \mathrm{d} v+\mathrm{d} x\otimes \mathrm{d} x+\mathrm{d} y\otimes \mathrm{d} y+\mathrm{d} z\otimes \mathrm{d} z

Cette métrique permet de définir une forme quadratique Q2+nQ_{2+n} sur R2+n\mathbb{R}^{2+n} dont l'expression est naturellement :

Q2+n(u,v,x1,,xn)=u2v2+i=1n(xi)2Q_{2+n}(u,v,x^1, \cdots,x^n)=-u^2-v^2+\sum\limits_{i=1}^n(x^i)^2
Q_22 = R22.diff_map(manifolds.RealLine(), [x^2+y^2-u^2-v^2], name='Q_22', latex_name=r'Q_{2+2}') Q_22.display()

Q2+2:R2+2R(u,v,x,y)t=u2v2+x2+y2(u,v,r,φ)t=r2u2v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{2+2}:& \mathbb{R}^{2+2} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y\right) & \longmapsto & t = -u^{2} - v^{2} + x^{2} + y^{2} \\ & \left(u, v, r, {\varphi}\right) & \longmapsto & t = r^{2} - u^{2} - v^{2} \end{array}

Q_23 = R23.diff_map(manifolds.RealLine(), [x^2+y^2+z^2-u^2-v^2], name='Q_23', latex_name=r'Q_{2+3}') Q_23.display()

Q2+3:R2+3R(u,v,x,y,z)t=u2v2+x2+y2+z2(u,v,r,θ,φ)t=r2u2v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{2+3}:& \mathbb{R}^{2+3} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y, z\right) & \longmapsto & t = -u^{2} - v^{2} + x^{2} + y^{2} + z^{2} \\ & \left(u, v, r, {\theta}, {\varphi}\right) & \longmapsto & t = r^{2} - u^{2} - v^{2} \end{array}

On introduit aussi des formes quadratiques pour la norme usuelle de Rn+2\mathbb{R}^{n+2} :

Q_4 = R22.diff_map(manifolds.RealLine(), [x^2+y^2+u^2+v^2], name='Q_4', latex_name=r'Q_{4}') Q_4.display()

Q4:R2+2R(u,v,x,y)t=u2+v2+x2+y2(u,v,r,φ)t=r2+u2+v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{4}:& \mathbb{R}^{2+2} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y\right) & \longmapsto & t = u^{2} + v^{2} + x^{2} + y^{2} \\ & \left(u, v, r, {\varphi}\right) & \longmapsto & t = r^{2} + u^{2} + v^{2} \end{array}

Q_5 = R23.diff_map(manifolds.RealLine(), [x^2+y^2+z^2+u^2+v^2], name='Q_5', latex_name=r'Q_{5}') Q_5.display()

Q5:R2+3R(u,v,x,y,z)t=u2+v2+x2+y2+z2(u,v,r,θ,φ)t=r2+u2+v2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} Q_{5}:& \mathbb{R}^{2+3} & \longrightarrow & \Bold{R} \\ & \left(u, v, x, y, z\right) & \longmapsto & t = u^{2} + v^{2} + x^{2} + y^{2} + z^{2} \\ & \left(u, v, r, {\theta}, {\varphi}\right) & \longmapsto & t = r^{2} + u^{2} + v^{2} \end{array}

Espace-temps anti-de Sitter

L'espace-temps anti-de Sitter AdSn+1\mathrm{AdS}_{n+1} est usuellement défini comme une sous-variété de R2+n\mathbb{R}^{2+n}. Plus précisément, AdSn+1\mathrm{AdS}_{n+1} est l'ensemble des points xR2+nx\in\mathbb{R}^{2+n} tels que Q2+n(x)=2Q_{2+n}(x)=-\ell^2, où \ell est un paramètre qu'on peut supposer positif :

l = var('l', latex_name=r'\ell') assume(l>0)

Dans tout les calculs et illustrations, on prendra =1\ell=1.

On choisit plutôt de définir AdSn+1\mathrm{AdS}_{n+1} comme une variété lorentzienne abstraite difféomorphe à S1×Rn\mathbb{S}_1\times\mathbb{R}^n que l'on munit de coordonnées sphériques sur le facteur Rn\mathbb{R}^n. On a donc des coordonnées (t,r,,θ,φ)(t,r,\cdots,\theta,\varphi). On voit donc que AdSn+1S1×Rn\mathrm{AdS}_{n+1}\approx\mathbb{S}_1\times\mathbb{R}^n n'est pas simplement connexe, et on introduit aussi son revêtement universel AdS~n+1Rn+1\widetilde{\mathrm{AdS}}_{n+1}\approx\mathbb{R}^{n+1}.

AdS_3 = Manifold(3, 'AdS_3', latex_name=r'\mathrm{AdS}_{2+1}', structure='Lorentzian', metric_latex_name=r'g_{\mathrm{AdS}_{2+1}}') AdS_U_3 = Manifold(3, 'AdS_U_3', latex_name=r'\widetilde{\mathrm{AdS}}_{2+1}', structure='Lorentzian')
AdS_4 = Manifold(4, 'AdS_4', latex_name=r'\mathrm{AdS}_{3+1}', structure='Lorentzian', metric_latex_name=r'g_{\mathrm{AdS}_{3+1}}') AdS_U_4 = Manifold(4, 'AdS_U_4', latex_name=r'\widetilde{\mathrm{AdS}}_{3+1}', structure='Lorentzian')
X_AdS_3.<t,r,ph> = AdS_3.chart(r't:(-pi,pi) r:(0,+oo) ph:(0,2*pi):\varphi:periodic') X_AdS_U_3.<t,r,ph> = AdS_U_3.chart(r't r:(0,+oo) ph:\varphi')
X_AdS_4.<t,r,th,ph> = AdS_4.chart(r't:(-pi,pi) r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic') X_AdS_U_4.<t,r,th,ph> = AdS_U_4.chart(r't r:(0,+oo) th:(0,pi):\theta ph:\varphi')

Le recouvrement universel est donné par la projection évidente πAdSn+1:AdS~n+1AdSn+1\pi_{\mathrm{AdS}_{n+1}}:\widetilde{\mathrm{AdS}}_{n+1}\longrightarrow\mathrm{AdS}_{n+1}.

pi_AdS_3 = AdS_U_3.diff_map(AdS_3, [t,r,ph], name='pi_AdS_3', latex_name=r'\pi_{\mathrm{AdS}_{2+1}}') pi_AdS_3.display()

πAdS2+1:AdS~2+1AdS2+1(t,r,φ)(t,r,φ)=(t,r,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{AdS}_{2+1}}:& \widetilde{\mathrm{AdS}}_{2+1} & \longrightarrow & \mathrm{AdS}_{2+1} \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(t, r, {\varphi}\right) = \left(t, r, {\varphi}\right) \end{array}

pi_AdS_4 = AdS_U_4.diff_map(AdS_4, [t,r,th,ph], name='pi_AdS_4', latex_name=r'\pi_{\mathrm{AdS}_{3+1}}') pi_AdS_4.display()

πAdS3+1:AdS~3+1AdS3+1(t,r,θ,φ)(t,r,θ,φ)=(t,r,θ,φ)\displaystyle \begin{array}{llcl} \pi_{\mathrm{AdS}_{3+1}}:& \widetilde{\mathrm{AdS}}_{3+1} & \longrightarrow & \mathrm{AdS}_{3+1} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(t, r, {\theta}, {\varphi}\right) = \left(t, r, {\theta}, {\varphi}\right) \end{array}

La variété abstraite AdSn+1\mathrm{AdS}_{n+1} se plonge dans R2+n\mathbb{R}^{2+n} selon :

ΦAdSn+1:(t,r,,φ)(u,v,r,,φ)=(2+r2cos(t),2+r2sin(t),r,,φ)\Phi_{\mathrm{AdS}_{n+1}}:(t,r,\cdots,\varphi)\mapsto (u,v,r,\cdots,\varphi)=(\sqrt{\ell^2+r^2}\cos(\frac{t}{\ell}),\sqrt{\ell^2+r^2}\sin(\frac{t}{\ell}),r,\cdots,\varphi)

R2+nR2×Rn\mathbb{R}^{2+n}\approx\mathbb{R}^2\times\mathbb{R}^n est muni de coordonnées sphériques sur Rn\mathbb{R}^n.

Phi_AdS_3 = AdS_3.diff_map(R22, {(X_AdS_3, X_R22_Sph) : [sqrt(r^2+l^2)*cos(t/l), sqrt(r^2+l^2)*sin(t/l), r, ph]}, name='Phi_AdS_3', latex_name=r'\Phi_{\mathrm{AdS}_{2+1}}') Phi_AdS_3.display()

ΦAdS2+1:AdS2+1R2+2(t,r,φ)(u,v,x,y)=(2+r2cos(t),2+r2sin(t),rcos(φ),rsin(φ))(t,r,φ)(u,v,r,φ)=(2+r2cos(t),2+r2sin(t),r,φ)\displaystyle \begin{array}{llcl} \Phi_{\mathrm{AdS}_{2+1}}:& \mathrm{AdS}_{2+1} & \longrightarrow & \mathbb{R}^{2+2} \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(u, v, x, y\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r \cos\left({\varphi}\right), r \sin\left({\varphi}\right)\right) \\ & \left(t, r, {\varphi}\right) & \longmapsto & \left(u, v, r, {\varphi}\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r, {\varphi}\right) \end{array}

Phi_AdS_4 = AdS_4.diff_map(R23, {(X_AdS_4, X_R23_Sph) : [sqrt(r^2+l^2)*cos(t/l), sqrt(r^2+l^2)*sin(t/l), r,th, ph]}, name='Phi_AdS_4', latex_name=r'\Phi_{\mathrm{AdS}_{3+1}}') Phi_AdS_4.display()

ΦAdS3+1:AdS3+1R2+3(t,r,θ,φ)(u,v,x,y,z)=(2+r2cos(t),2+r2sin(t),rcos(φ)sin(θ),rsin(φ)sin(θ),rcos(θ))(t,r,θ,φ)(u,v,r,θ,φ)=(2+r2cos(t),2+r2sin(t),r,θ,φ)\displaystyle \begin{array}{llcl} \Phi_{\mathrm{AdS}_{3+1}}:& \mathrm{AdS}_{3+1} & \longrightarrow & \mathbb{R}^{2+3} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(u, v, x, y, z\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r \cos\left({\varphi}\right) \sin\left({\theta}\right), r \sin\left({\varphi}\right) \sin\left({\theta}\right), r \cos\left({\theta}\right)\right) \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(u, v, r, {\theta}, {\varphi}\right) = \left(\sqrt{{\ell}^{2} + r^{2}} \cos\left(\frac{t}{{\ell}}\right), \sqrt{{\ell}^{2} + r^{2}} \sin\left(\frac{t}{{\ell}}\right), r, {\theta}, {\varphi}\right) \end{array}

On vérifie que ΦAdSn+1\Phi_{\mathrm{AdS}_{n+1}} envoie AdSn+1\mathrm{AdS}_{n+1} dans l'ensemble des points vérifiant Q2+n(x)=2Q_{2+n}(x)=-\ell^2.

(Q_22*Phi_AdS_3).display()

AdS2+1R(t,r,φ)t=2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathrm{AdS}_{2+1} & \longrightarrow & \Bold{R} \\ & \left(t, r, {\varphi}\right) & \longmapsto & t = -{\ell}^{2} \end{array}

(Q_23*Phi_AdS_4).display()

AdS3+1R(t,r,θ,φ)t=2\displaystyle \renewcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathrm{AdS}_{3+1} & \longrightarrow & \Bold{R} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & t = -{\ell}^{2} \end{array}

graph_AdS = X_AdS_3.plot(X_R22_Cart, mapping=Phi_AdS_3, ambient_coords=(x,u,v), fixed_coords={ph:0}, ranges={t:(-pi,pi), r:(0,2)}, number_values=9, color={t:'grey', r:'grey'}, thickness=1, parameters={l:1}, label_axes=False) graph_AdS += X_AdS_3.plot(X_R22_Cart, mapping=Phi_AdS_3, ambient_coords=(x,u,v), fixed_coords={ph:pi}, ranges={t:(-pi,pi), r:(0,2)}, number_values=9, color={t:'grey', r:'grey'}, thickness=1, parameters={l:1}, label_axes=False) Phi_AdS_3_u_0, Phi_AdS_3_u_pi = Phi_AdS_3.coord_functions()[0](t,r,0).subs({l:1}), Phi_AdS_3.coord_functions()[0](t,r,pi).subs({l:1}) Phi_AdS_3_v_0, Phi_AdS_3_v_pi = Phi_AdS_3.coord_functions()[1](t,r,0).subs({l:1}), Phi_AdS_3.coord_functions()[1](t,r,pi).subs({l:1}) Phi_AdS_3_x_0, Phi_AdS_3_x_pi = Phi_AdS_3.coord_functions()[2](t,r,0).subs({l:1}), Phi_AdS_3.coord_functions()[2](t,r,pi).subs({l:1}) graph_hyperboloid = parametric_plot3d([Phi_AdS_3_x_0, Phi_AdS_3_u_0, Phi_AdS_3_v_0], (t,-pi,pi), (r,0,2), color=(.8,.8,0.9)) graph_hyperboloid += parametric_plot3d([Phi_AdS_3_x_pi, Phi_AdS_3_u_pi, Phi_AdS_3_v_pi], (t,-pi,pi), (r,0,2), color=(.8,.8,0.9)) graph_AdS += graph_hyperboloid show(graph_AdS, aspect_ratio=1, axes_labels=['x','u','v'])