Etude de la solution de Reissner-Nordström, et intégration numérique de géodésiques.

Project: Relativité générale - Stage maths/physique, été 2023

Views: ⁸⁷

Visibility: Unlisted (only visible to those who know the link)

Image: ubuntu2204

Kernel: SageMath 10.1

In [1]:

%display latex

This notebook was written under the supervision of Éric Gourgoulhon (LUTH) as part of my physics internship in July 2023.

Author : Nicolas Seroux

Solution de Reissner-Nordström

Définition de la variété d'espace-temps et de la métrique de Reissner-Nordström

On définit la métrique de Reissner-Nordström sur une variété $\mathscr{M}$ difféomorphe à $\mathbb{R}\times\mathbb{R}^*_+\times\mathbb{S}_2$ que l'on munit des coordonnées de Schwarzschild $(t,r,\theta,\varphi)$ adaptées à la symétrie sphérique :

In [2]:

M = Manifold(4, 'M', latex_name=r'\mathscr{M}', structure='Lorentzian')

In [3]:

X.<t,r,th,ph> = M.chart(r"t r:(0,+oo) th:(0,pi):\theta ph:(0,2*pi):\varphi:periodic")

La métrique $g$ de Reissner-Nordström est définie en fonction des paramètres $m$ et $Q$ représentant respectivement la masse et la charge totale du trou noir. On supposera de plus que $|Q|<m$ .

In [4]:

m = var('m')
assume(m>=0)

Q = var('Q')
assume(abs(Q)<m)

On introduit également le polynôme $\Delta=r^2-2mr+Q^2$ qui simplifie l'expression de la métrique.

In [5]:

Del = r^2-2*m*r+Q^2

La métrique de Reissner-Nordström a une forme analogue à celle de la métrique de Schwarzschild :

In [6]:

g = M.metric()

g[0,0] = -Del/r^2
g[1,1] = r^2/Del
g[2,2] = r^2
g[3,3] = r^2*sin(th)^2

g.display()

$\displaystyle g = \left( -\frac{Q^{2} - 2 \, m r + r^{2}}{r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{r^{2}}{Q^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + r^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + r^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}$

Equations d'Einstein

Tenseurs de courbure

On peut désormais calculer les tenseurs de Riemann et de Ricci liés à $g$ :

In [7]:

Riem = g.riemann()
Rc = g.ricci()
R = g.ricci_scalar()

L'espace-temps de Reissner-Nordstrom n'est pas Ricci-plat à cause du champ électromagnétique :

In [8]:

Rc.display()

$\displaystyle \mathrm{Ric}\left(g\right) = \left( \frac{Q^{4} - 2 \, Q^{2} m r + Q^{2} r^{2}}{r^{6}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{Q^{2}}{Q^{2} r^{2} - 2 \, m r^{3} + r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} r + \frac{Q^{2}}{r^{2}} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{Q^{2} \sin\left({\theta}\right)^{2}}{r^{2}} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}$

On peut également calculer le tenseur d'Einstein associé :

In [9]:

G = Rc - R*g/2
G.set_name('G', latex_name=r'G')
G.display()

$\displaystyle G = \left( \frac{Q^{4} - 2 \, Q^{2} m r + Q^{2} r^{2}}{r^{6}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{Q^{2}}{Q^{2} r^{2} - 2 \, m r^{3} + r^{4}} \right) \mathrm{d} r\otimes \mathrm{d} r + \frac{Q^{2}}{r^{2}} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{Q^{2} \sin\left({\theta}\right)^{2}}{r^{2}} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}$

En outre, ce alcul du scalaire de Kretschman montre qu'il y a une singularité de courbure en $r=0$ :

In [10]:

K = Riem.down(g)['_{abcd}']*Riem.up(g)['^{abcd}']
K.expr()

$\displaystyle \frac{8 \, {\left(7 \, Q^{4} - 12 \, Q^{2} m r + 6 \, m^{2} r^{2}\right)}}{r^{8}}$

Tenseur énergie-impulsion

On commence par exprimer le champ électromagnétique dans le co-repère associé aux coordonnées de Schwarzschild. On suppose que le potentiel électromagnétique $A$ à une forme simple où la symétrie sphérique est manifeste, et qui se réduit à l'expression usuelle du potentiel dans un espace-temps plat :

In [11]:

A = M.diff_form(1, name='A')

A[M.default_frame(), 0] = -Q/r

A.display()

$\displaystyle A = -\frac{Q}{r} \mathrm{d} t$

Le champ électromagnétique est défini comme la différentielle extérieure du potentiel $A$ :

In [12]:

F = A.exterior_derivative()
F.set_name('F')
F.display()

$\displaystyle F = -\frac{Q}{r^{2}} \mathrm{d} t\wedge \mathrm{d} r$

Le tenseur énergie-impulsion $T$ est défini à partir du champ $F$ par :

T_{\mu\nu}=\frac{1}{4\pi}F_{\alpha\mu}F^\alpha_\nu-\frac{1}{4}F_{\alpha\beta}F^{\alpha\beta}g_{\mu\nu}.

In [13]:

Fuu = F.up(g)
F2 = F['_ab']*Fuu['^ab']


Fud = F.up(g,0)
T = 1/(4*pi)*( F['_k.']*Fud['^k_.'] - 1/4*F2 * g )
T.set_name('T',latex_name=r'T')
T.display()

$\displaystyle T = \left( \frac{Q^{4} - 2 \, Q^{2} m r + Q^{2} r^{2}}{8 \, \pi r^{6}} \right) \mathrm{d} t\otimes \mathrm{d} t -\frac{Q^{2}}{8 \, {\left(\pi Q^{2} r^{2} - 2 \, \pi m r^{3} + \pi r^{4}\right)}} \mathrm{d} r\otimes \mathrm{d} r + \frac{Q^{2}}{8 \, \pi r^{2}} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{Q^{2} \sin\left({\theta}\right)^{2}}{8 \, \pi r^{2}} \mathrm{d} {\varphi}\otimes \mathrm{d} {\varphi}$

En utilisant les calculs précédents, il est facile de vérifier que la métrique de Reissner-Nordström est une solution des équations d'Einstein :

In [14]:

G == 8*pi*T

$\displaystyle \mathrm{True}$

Géodésiques dans l'espace-temps de Reissner-Nordström

On introduit un espace euclidien $\mathbb{E}^3$ dans lequel on projettera les géodésiques.

In [15]:

E3.<x,y,z> = EuclideanSpace()
X3 = E3.cartesian_coordinates()
to_E3 = M.diff_map(E3, {(X, X3): [r*sin(th)*cos(ph), r*sin(th)*sin(ph), r*cos(th)]})
to_E3.display()

$\displaystyle \begin{array}{llcl} & \mathscr{M} & \longrightarrow & \mathbb{E}^{3} \\ & \left(t, r, {\theta}, {\varphi}\right) & \longmapsto & \left(x, y, z\right) = \left(r \cos\left({\varphi}\right) \sin\left({\theta}\right), r \sin\left({\varphi}\right) \sin\left({\theta}\right), r \cos\left({\theta}\right)\right) \end{array}$

Une géodésique est caractérisée par un point $p_0$ de $\mathscr{M}$ et un vecteur $v_0\in\mathrm{T}_{p_0}\mathscr{M}$ .

In [16]:

p0 = M((0,8*m,pi/2,0), name='p_0')
v0 = M.tangent_space(p0)((1.4,0,0,0.06/m), name='v_0')
v0.display()

$\displaystyle v_0 = 1.40000000000000 \frac{\partial}{\partial t } + \frac{0.0600000000000000}{m} \frac{\partial}{\partial {\varphi} }$

On introduit un paramètre affine $s$ avant d'intégrer numériquement l'équation des géodsiques :

In [17]:

s = var('s')
geod = M.integrated_geodesic(g, (s, 0, 500), v0)
sol = geod.solve(parameters_values={m: 1, Q:1/2}) 
interp = geod.interpolate()

La projection des coordonnées de Schwarzschild dans $\mathbb{E}^3$ permet d'obtenir une visualisation des géodésiques :

In [18]:

graph = geod.plot_integrated(chart=X3, mapping=to_E3, plot_points=500, thickness=2, label_axes=False)
graph += p0.plot(chart=X3, mapping=to_E3, size=4, parameters={m: 1, Q:1/2})
graph += sphere(size=2, color='grey')
show(graph)

Le caractère répulsif du centre de symétrie $r=0$ est manifeste si l'on trace une géodésique de même condition initiale dans l'espace-temps de Schwarzschild, i.e. pour $Q=0$ .

In [19]:

s = var('s')

geod_sch = M.integrated_geodesic(g, (s, 0, 90), v0)
sol_sch = geod_sch.solve(parameters_values={m: 1, Q:0}) 
interp_sch = geod_sch.interpolate()

graph_sch = geod_sch.plot_integrated(chart=X3, mapping=to_E3, plot_points=500, 
                                     thickness=2, label_axes=False)           # the geodesic
graph_sch += p0.plot(chart=X3, mapping=to_E3, size=4, parameters={m: 1, Q:0}) # the starting point
graph_sch += sphere(size=2, color='grey')                                 # the event horizon
show(graph_sch)