CoCalc -- Grafieken tekenen met SAGE.sagews

¹⁴⁵ views

In dit werkblad leggen we aan de hand van enkele eenvoudige voorbeelden uit hoe je SAGE kan gebruiken om snel mooie functiegrafieken te tekenen. Deze grafieken kan je gemakkelijk kopieren en plakken (in Word bv.) of rechtstreeks opslaan als .png-bestand. Voor meer gevorderde technieken raadpleeg je Help.

Zoals je kan zien bestaat een SAGE werkblad uit een opeenvolging van tekstvelden en cellen, rekenvelden waarin je opdrachten invoert die daarna door SAGE verwerkt worden. Onderaan het werkblad staat normaal altijd een (lege) cel. Je kan ook altijd nieuwe cellen tussenvoegen door tussen bestaande blokken te klikken op de invoegregel. (De invoegregel licht blauw op onder de muiswijzer.) Nieuwe tekstvelden voeg je op de zelfde manier in door <Shift>-klikken. Probeer het.

Een grafiek tekenen met SAGE is kinderspel. Hieronder zie je een voorbeeld. Typ gewoon een plot()-instructie in een cel, met tussen de haken de definitieformule van een functie. Klik daarna op de link evaluate onder de cel, of sluit af met de toetsencombinatie <Shift-Enter> en je bent klaar. Probeer het: klik in de cel hieronder en wijzig de formule in '5*x^2+x+1'. Merk op hoe de grafiek zich ogenblikkelijk aanpast.

plot(2*x^2+x+1)

Dingen waar je zeker moet op letten bij het invoeren van formules:

vermenigvuldiging wordt aangeduid met een '*',
voor machtsverheffing typ je een '^',
delen doe je met '/',
komma's in decimale getallen worden op zijn amerikaans, t.t.z. als punten, ingegeven en getoond (bv.: $\pi\approx3.14159$ ),
gebruik voldoende haakjes zodat berekeningen in de juiste volgorde gebeuren.

Merk op dat SAGE op eigen houtje beslist over kleur en afmetingen van de grafiek, en over het venster $[x_1,x_2]\times[y_1,y_2]$ waarin de grafiek getekend wordt. (Zo valt het op dat de assen op de figuur zich niet snijden in de oorsprong $O(0\! ,0)$.) Je kan al deze zaken echter naar believen wijzigen door extra gegevens (argumenten) mee te geven in de plot( )-instructie.

Hieronder laten we achtereenvolgens zien hoe je

de absolute afmetingen van figuur kan opgeven,
het venster kan aanpassen waarin de grafiek getekend wordt,
kleur en lijndikte van de grafiek kan aanpassen,
roosterlijnen kan laten tekenen,
meerdere grafieken tegelijk kan laten tekenen,
het tekenen van grafieken kan uitstellen en uitgestelde grafieken kan samenvoegen in één figuur,
hoe je een label (een bijschrift of titel) kan toevoegen aan een grafiek.

Van zodra je nog maar de puntjes (1-3) onder de knie hebt wordt SAGE al een nuttig en practisch werkinstrument.

1. Absolute afmetingen van een figuur opgeven.

Geef de plot( )-instructie het extra argument figsize mee.

# voorbeeld figsize
plot(2*x^2+x+1,figsize=3)

Vergelijk deze figuur met de eerste grafiek helemaal bovenaan dit werkblad.

De eerste lijn in de cel hierboven is een commentaarlijn. Elke lijn die met een '#'-teken begint wordt door SAGE gewoon genegeerd. Zo kan je titels, uitleg en commentaar opnemen in een invoercel.

Hieronder zie je hoe je beide afmetingen van een grafiek onafhankelijk van elkaar kan instellen: we tekenen een grafiek die drie keer breder is dan hoog.

# figsize (voorbeeld 2)
plot(2*x^2+x+1,figsize=(3,1))

2. Grafiekvenster aanpassen.

Geef in de plot()-instructie de extra argumenten xmin, xmax, ymin en ymax mee. Argumenten die je achterwege laat krijgen door SAGE een standaardwaarde toegekend.

# xmin, xmax, ymin, ymax (vb. 1)
plot(2*x^2+x+1,xmin=-3,xmax=2,ymin=-1,ymax=9,figsize=3)

# xmin, xmax, ymin, ymax (vb. 2 - zonder xmax en ymax)
plot(2*x^2+x+1,xmin=-3,ymin=2,figsize=3)

Standaard gaat het interval [xmin,xmax] van -1 tot 1. De grenzen ymin en ymax worden zo goed en zo kwaad als het gaat aangepast aan het bereik van de grafiek. In feite is het geen goed idee om xmin en/of xmax weg te laten. Je krijgt ook vreemde resultaten als xmin>xmax of ymin>ymax.

# voorbeeld met xmin>xmax: er wordt geen grafiek getekend.
plot(2*x^2+x+1,xmin=2,xmax=-2,figsize=3)

# voorbeeld met ymin>ymax: de y-as wordt 'omgekeerd' getekend.
plot(2*x^2+x+1,ymin=5,ymax=-5,figsize=3)

Een handige en kortere schrijfwijze gebruikt de constructie $(x,a,b)$ om aan te geven dat de grafiek moet getekend worden in het interval $a\leq x \leq b$ . Deze constructie wordt nog in een heel aantal andere SAGE-instructies gebruikt.

# voorbeeld met de constructie (x,a,b).
plot(x^2,(x,-2,3),figsize=(4,3))

3. Kleur en lijndikte van een grafiek aanpassen.

Geef in de plot()-instructie de extra argumenten color en thickness mee. Om de waarde van color in te stellen kan je een kleur bij naam noemen of de hue()-functie gebruiken met, tussen de haken, een kleurcode tussen 0 en 1. Enkele gemakkelijk te onthouden namen zijn red, blue, green, yellow, cyan, pink en black.

# color en thickness (vb. 1 - met een benoemde kleur)
plot(2*x^2+x+1,xmin=-3,xmax=3,figsize=3,color='red',thickness=2)

# color en thickness (vb. 2 - met een kleurcode en de hue()-functie)
plot(2*x^2+x+1,xmin=-3,xmax=3,figsize=3,color=hue(0.4),thickness=0.5)

4. Roosterlijnen tekenen.

Geef in de plot()-instructie het extra argument gridlines de waarde 'True'. Veranderlijken zoals 'gridlines' kunnen enkel de waarden 'True' en 'False' krijgen. Dergelijke veranderlijken worden logische of Booleaanse (ook wel Boolse) veranderlijken genoemd.

# gridlines (voorbeeld)
plot(2*x^2+x+1,xmin=-3,xmax=3,figsize=3,gridlines=True)

5. Meerdere grafieken tegelijk tekenen.

Om grafieken van meerdere functies tegelijk te tekenen kan je deze functies opnemen in een LIJST, door ze - gescheiden door komma's - tussen vierkante haken te plaatsen. Een plot( )-instructie met een lijst als argument zal alle functies in die lijst apart in grafiek zetten.

# meerdere functies tegelijk tekenen (voorbeeld)
# we tekenen een parabool en een raaklijn aan die parabool
plot([x^2,2*x-1],(x,-1,3),figsize=3)

Je kan heel lange lijsten maken door ze te programmeren, in plaats van elk element afzonderlijk in te typen. We tekenen bijvoorbeeld 10 rechten, met vergelijking $y=mx+q$ , elk met een verschillende richtingscoëfficiënt $m$ , om de invloed van de richtingscoëfficiënt op de helling van de rechte te illustreren.

# maak een lijst met 11 verschillende rechten...
L=[m*x+1 for m in (0..10)]

# ... en teken al deze rechten in één enkele figuur
plot(L,(x,-3,3),ymin=-5,ymax=5,figsize=(4,4))

In de definitie van de lijst L hierboven gebruiken we de constructie (0..10) die zelf een lijst oplevert van gehele waarden tussen 0 en 10, grenzen inbegrepen. De figuur bevat dus alles samen 11 grafieken. Een dergelijke constructie wordt een bereik genoemd.

Op de zelfde manier kunnen we ook de constante term $q$ variëren, of $m$ en $q$ tegelijk.

# definiëer een lijst van 11 rechten met een verschillende constante term.
L=[x+q for q in (-5..5)]

# en teken ze in de zelfde figuur.
plot(L,(x,-3,3),ymin=-4,ymax=4,figsize=(4,4))

# 20 rechten y=mx+q, waarbij zowel m als q variëren
L=[m*x+1-m^2 for m in (-4,-3.6,..,4)]

# teken ze in de zelfde figuur
plot(L,(x,-6,6),ymin=-3,ymax=9,figsize=(4,4))

Let op het bereik voor de waarde $m$ : (-4,3.6,..4) begint bij $m=-4$ en bevat alle waarden kleiner dan of gelijk aan 4, in stappen van $+0.4$ .

6. Uitgestelde grafieken.

Een nadeel van de methode onder (5.) is dat alle grafieken dezelfde opmaak (kleur, lijndikte,...) krijgen. Als dat niet wenselijk is moet je elke grafiek in een afzonderlijke, uitgestelde figuur onderbrengen, die je nadien samenvoegt (met een ' $+$ ') en vervolgens laat tekenen met show( ).

# alternatieve werkwijze om een parabool samen met een raaklijn te tekenen 

# de parabool blijft standaard blauw, maar wordt iets dikker getekend
p=plot(x^2,(x,-3,3),thickness=2)

# de raaklijn wordt rood, met standaard dikte
q=plot(2*x-1,(x,-3,3),color='red')

# beide figuren worden samengevoegd en getekend op het scherm
(p+q).show(ymin=-3,figsize=(4,3))

Om veel verschillende grafieken samen te tekenen kan je (zoals in (5.) ) elke grafiek weer in een geprogrammeerde lijst stoppen. Om alle grafieken in zo een lijst samen te voegen gebruik je dan het sleutelwoord sum( ) in plaats van een ' $+$ '-teken. In het voorbeeld tekenen we een familie parabolen waarvan we de kleur variëren tot steeds lichtere tinten rood.

# definieer een familie van 20 parabolen, in steeds lichtere tinten rood
# zuiver rood correspondeert met t=0, zuiver wit met t=20
# de 'blend()'-functie berekent een mengkleur met gegeven verhoudingen.
R=Color('red'); W=Color('white')
L=[plot(t*x^2,(x,-3,3),color=R.blend(W,t/20)) for t in (1..20)]

# en teken ze allemaal samen in 1 figuur:
sum(L).show(ymin=-2,ymax=12,figsize=(4,3))

7. Labels toevoegen aan een grafiek.

De basisinstructie is text(<letterreeks> , <positie in figuur>) .

# alleen maar een stukje tekst...
text('abc',(1,1))

Meestal echter zal je tekst en grafieken samen willen voegen. Dit gebeurt op exact dezelfde manier als het bijeenvoegen van verschillende grafieken. Je kent het resultaat van de text( )-instructie dus toe aan een variabele, en voegt die samen met grafieken of andere tekst m.b.v. een ' $+$ '-teken. Zoals in elk degelijk wiskundig geöriënteerd programma kan je ook hier TeX-formules invoeren. Het is echter aangeraden om de letterreeks die je in de figuur wil opnemen te laten voorafgaan door een 'r'-symbool, om problemen met speciale tekens te voorkomen.

# teken een grafiek...
p=plot(sqrt(x),(x,0,5))

# ... en voeg er een stukje tekst bij
q=text(r'de functie $y=\sqrt{x}$', (.5,1))

# ... en toon beide samen
(p+q).show(xmin=-1,xmax=5,ymin=-1,figsize=(4,3))

Je kan de alignering, kleur en lettertype en -grootte van een tekst aanpassen m.b.v. extra argumenten voor de text( )-instructie.

# teken een grafiek...
p=plot(sqrt(x),(x,0,5))

# ... en voeg er een stukje tekst bij
#
q=text(r'de functie $y=\sqrt{x}$', (.5,1),horizontal_alignment='left',color='green',fontsize=24)

# toon tenslotte beide samen
(p+q).show(xmin=-1,xmax=5,ymin=-1,figsize=(4,3))