Tutorial Sage: Vetores

³⁵⁵ views
License: GPL3

Vetores

Vetores no Sage são representados por objetos do tipo vector. Por exemplo, para criar um vetor com coordenadas (-1.5, 3.2, 4.6) e atribuí-lo à variável v, usamos o seguinte comando:

v = vector([-1.5, 3.2, 4.6])

Para imprimir na tela uma variável, simplesmente digitamos o nome da variável ou usamos o comando print:

(-1.50000000000000, 3.20000000000000, 4.60000000000000)

print(v)

(-1.50000000000000, 3.20000000000000, 4.60000000000000)

Para imprimir na tela uma variável em formato LaTeX, usamos o comando show:

show(v)

\displaystyle \left(-1.50000000000000,\,3.20000000000000,\,4.60000000000000\right)

Número de coordenadas de um vetor

Para obter o número de coordenadas do vetor v, usamos o método length de v:

v.length()

3

Coordenadas de um vetor

No Sage, as coordenadas de vetores do $\mathbb{R}^n$ são indexadas de 0 a n-1. Por exemplo, se v é um vetor do $\mathbb{R}^3$ , então as coordenadas de v são indexadas de 0 a 2, ou seja, $v = (v_0, v_1, v_2)$ .

Para obter o valor da coordenada j do vetor v, usamos o comando v[j]:

v = vector([5, 6, 7])

v[0]

5

v[2]

7

Podemos também modificar o valor de uma coordenada com o seguinte comando:

v[0] = 10
v

(10, 6, 7)

Copiando vetores

Para criar uma cópia de um vetor, usamos o comando copy:

w = copy(v)

Podemos comparar dois vetores usando o operador ==:

w == v

True

O seguinte comando modifica o valor da terceira coordenada de w (lembre que as coordenadas são indexadas a partir de 0):

w[2] = 10

Agora os vetores v e w são diferentes:

w == v

False

De fato

(10, 6, 10)

(10, 6, 7)

Vetor zero

O comando zero_vector(3) fornece o vetor zero do $\mathbb{R}^3$ :

zero_vector(3)

(0, 0, 0)

Podemos atribuí-lo à variável zero, por exemplo:

zero = zero_vector(3)
print(zero)

(0, 0, 0)

Vetores aleatórios

Muitas vezes é útil tomar um vetor qualquer. O comando random_vector(3) fornece um vetor do $\mathbb{R}^3$ em que as coordenadas foram escolhidas aleatóriamente:

random_vector(3)

(-2, -1, -1)

Por definição, esse comando fornece um vetor cujas coordenadas são números inteiros. Se quisermos obter vetores cujas coordenadas são números do tipo float (grosso, números reais), usamos o comando

random_vector(RR, 3)

(-0.765230441237253, -0.845791783980390, -0.651697419467054)

Podemos também selecionar um vetor cujas coordenadas são números racionais:

random_vector(QQ, 3)

(-1, 1, 1/9)

Para calcular a soma de v e w usamos o comando v + w:

v = vector([1, 2, 3])
w = vector([5, 5, 5])
v + w

(6, 7, 8)

Analogamente, podemos calcular v - w:

v - w

(-4, -3, -2)

Multiplicação de vetor por escalar

Multiplicamos um escalar por um vetor usando o operador *. O comando 2*v calcula 2 vezes o vetor v, por exemplo:

v = vector([-1, 0, 3])

2*v

(-2, 0, 6)

Combinações lineares

Podemos atribuir vetores e escalares a variáveis:

u = vector([2, 0, 7])
v = vector([-3, 5, 1])
a = 2
b = -3

Então calculamos uma combinação linear de u e v:

w = a*u + b*v
w

(13, -15, 11)

Gráficos de vetores

Consideremos dois vetores no plano:

u = vector([5, 1])
v = vector([1, 3])

Para criar o gráfico de um vetor com ponto inicial na origem, usamos o comando plot:

plot(u)

Para representar vários vetores em um mesmo gráfico, primeiro "somamos" os gráficos de cada um deles e armazenamos em uma variável. Por exemplo, somamos os gráficos dos vetores u, v e u + v e armazenamos na variável p:

p1 = plot(u, color='blue')
p2 = plot(v, color='red')
p3 = plot(u + v, color='green')
p = p1 + p2 + p3

Em seguida, exibimos o gráfico p com o comando show(p):

show(p, axes_labels=['X', 'Y'])