Contact Us!
CoCalc Logo Icon
StoreFeaturesDocsShareSupportNewsAboutSign UpSign In

Real-time collaboration for Jupyter Notebooks, Linux Terminals, LaTeX, VS Code, R IDE, and more,
all in one place. Commercial Alternative to JupyterHub.

| Download
Views: 39
Image: ubuntu2204
Tweet
Share
Share
Kernel: SageMath 10.3

Stokes' Theorem

The curl vector

Green's theorem (in a plane) ∮CF⃗⋅dr⃗=∬R(∂N∂x−∂M∂y)dxdy\oint_C\vec F\cdot d\vec r=\iint_R\left({\partial N\over \partial x}-{\partial M\over\partial y}\right)dxdy It measures the rotation rate of F⃗\vec F around an axis parallel to k⃗\vec k.

How to extend it to a general surface?

When viewed looking down, the vector points in the direction for which the rotation is counterclockwise.

The curl vector for the vector field F⃗=Mi⃗+Nj⃗+Pk⃗\vec F=M\vec i+N\vec j+P\vec k is curl F⃗=(∂P∂y−∂N∂z)i⃗+(∂M∂z−∂P∂x)j⃗+(∂N∂x−∂M∂y)k⃗\mbox{curl }\vec F=\left({\partial P\over \partial y}-{\partial N\over \partial z}\right)\vec i +\left({\partial M\over \partial z}-{\partial P\over \partial x}\right)\vec j+\left({\partial N\over \partial x}-{\partial M\over \partial y}\right)\vec k

Definition (pronounced 'del') ∇=i⃗∂∂x+j⃗∂∂y+k⃗∂∂z\nabla =\vec i {\partial \over \partial x}+\vec j {\partial \over \partial y}+\vec k {\partial \over \partial z} Then the curl of F⃗\vec F is curl F⃗=∇×F⃗=∣i⃗j⃗k⃗∂∂x∂∂y∂∂zMNP∣\mbox{curl }\vec F=\nabla \times \vec F=\begin{vmatrix} \vec i & \vec j & \vec k\\ {\partial \over \partial x} & {\partial\over\partial y}&{\partial\over\partial z}\\ M & N & P \end{vmatrix}

Example: Find the curl of F⃗=(x2−z)i⃗+xezj⃗+xyk⃗\vec F=(x^2-z)\vec i+xe^z\vec j+xy\vec k

Solution:

curl F⃗=∇×F⃗=∣i⃗j⃗k⃗∂∂x∂∂y∂∂zx2−zxezxy∣=(x−xez)i⃗+(−1−y)j⃗+(ez)k⃗\begin{align*} \mbox{curl }\vec F=\nabla \times \vec F=\begin{vmatrix} \vec i & \vec j & \vec k\\ {\partial \over \partial x} & {\partial\over\partial y}&{\partial\over\partial z}\\ x^2-z & xe^z & xy \end{vmatrix}=(x-xe^z)\vec i+(-1-y)\vec j+(e^z)\vec k \end{align*}
reset()
var('x, y, z')
F(x,y,z) = vector((x^2-z, x*e^z, x*y))
show('The curl of F is', F.curl((x,y,z)))

The curl of F is(x,y,z) ↦ (−xez+x, −y−1, ez)\displaystyle \verb|The|\verb| |\verb|curl|\verb| |\verb|of|\verb| |\verb|F|\verb| |\verb|is| \left( x, y, z \right) \ {\mapsto} \ \left(-x e^{z} + x,\,-y - 1,\,e^{z}\right)

Stokes' theorem

Theorem (Theorem 6 - Stokes' Theorem)

Let SS be a piecewise smooth oriented surface having a piecewise smooth boundary curve CC. Let F⃗=Mi⃗+Nj⃗+Pk⃗\vec F = M \vec i + N \vec j + P \vec k be a vector field whose components have continuous first partial derivatives on an open region containing SS. Then the circulation of F⃗\vec F around CC in the direction counterclockwise with respect to the surface's unit normal vector n⃗\vec n equals the integral of the curl vector field ∇×F⃗\nabla \times \vec F over SS: ∮CF⃗⋅dr⃗⏟counterclockwise=∬S∇×F⃗⋅n⃗dσ⏟curl integral\underbrace{\oint_C\vec F\cdot d\vec r}_{\mbox{counterclockwise}}=\underbrace{\iint_S\nabla \times \vec F\cdot \vec n d\sigma}_{\mbox{curl integral}}

  • Surface independent ∬S1∇×F⃗⋅n⃗1dσ=∬S2∇×F⃗⋅n⃗2dσ.\iint_{S_1}\nabla \times \vec F\cdot \vec n_1d\sigma = \iint_{S_2}\nabla \times \vec F\cdot \vec n_2d\sigma.

  • Analogous to a path independent for F⃗:=∇f\vec{F}:=\nabla f.

  • Green's theorem is a special case of Stokes' theorem. Let CC be a curve in the xyxy-plan, oriented counterclockwise, and RR is the region in the xyxy-plane bounded by CC. Then we have ∮CF⃗⋅dr⃗=∬R(∂N∂x−∂M∂y)dxdy=∬S∇×F⃗⋅k⃗dσ\oint_C\vec F\cdot d\vec r=\iint_R\left({\partial N\over \partial x}-{\partial M\over\partial y}\right)dxdy=\iint_S\nabla \times \vec F\cdot \vec k d\sigma

Stokes' theorem for surfaces with holes

Stokes’ Theorem holds for an oriented surface SS that has one or more holes. The surface integral over SS of the normal component of ∇×F⃗\nabla \times \vec F equals the sum of the line integrals around all the boundary curves of the tangential component of F⃗\vec F, where the curves are to be traced in the direction induced by the orientation of SS. For such surfaces the theorem is unchanged, but CC is considered as a union of simple closed curves.

Example: Verify Stokes' theorem: the hemisphere S:x2+y2+z2=9S: x^2 + y^2 + z^2 = 9, z≥0z\geq 0, its bounding circle C:x2+y2=9, z=0C: x^2 + y^2 = 9,~z = 0, and the field F⃗=yi⃗−xj⃗\vec F = y\vec i - x\vec j.

Solution: We calculate the counterclockwise circulation around C (as viewed from above):

r⃗(θ)=3cos⁡θi⃗+3sin⁡θj⃗,0≤θ≤2π\vec r(\theta)=3\cos \theta\vec i+3\sin \theta \vec j,\quad 0\leq \theta\leq 2\piF⃗⋅dr⃗=−9sin⁡2dθ−9cos⁡2dθ=−9dθ\vec F \cdot d \vec r = -9\sin^2 d \theta -9\cos^2 d \theta = -9 d \theta∮CF⃗⋅dr=∫02π−9dθ=−18π\oint_C \vec F \cdot dr = \int_0^{2\pi} -9 d\theta = -18 \pi

For the curl integral of F⃗\vec F, we have:

∇×F⃗=(0−0)i⃗+(0−0)j⃗+(−1−1)k⃗=−2k⃗\nabla \times \vec F = (0-0)\vec i + (0-0)\vec j + (-1-1)\vec k = -2\vec kn⃗=xi⃗+yj⃗+zk⃗3\vec n = {x\vec i + y\vec j + z\vec k \over 3}dσ=3zdAd\sigma ={3 \over z} dA

Thus

∬S(∇×F⃗)⋅n⃗dσ=∬x2+y2≤9−2dA=−18π\iint_S (\nabla \times \vec F) \cdot \vec n d \sigma = \iint_{x^2+y^2 \leq 9} -2 dA = -18 \pi
reset()

var('x, y, z, t')

r = vector((3*cos(t), 3*sin(t), 0))
show('r(t) =', r, 'for 0 <= t <= 2pi')

F(x,y,z) = vector((y, -x, 0))
Ft = F(r[0], r[1], r[2]) # Note that the index starts at 0.
show('F(t) =', Ft)

res = integral(Ft.dot_product(diff(r,t)), t, 0, 2*pi)
print('The line integral over C is', res.full_simplify())

h(x,y,z) =  x^2+y^2+z^2-9 # Express z as a function of x and y

vn = h.diff()
#vn = vn/vn.norm()  # normalize it to a unit vector

Fcurl = F.curl((x,y,z))


assume(x^2+y^2<9)
hz(x,y) = sqrt(9-x^2-y^2)

show(h.diff().norm()(z=hz(x,y)))

show('The surface integral is ', (Fcurl.dot_product(vn)(z=hz(x,y))/vn[2](z=hz(x,y))).integral(y, -sqrt(9-x^2), sqrt(9-x^2), algorithm='giac').integral(x, -3, 3, algorithm='giac'))

r(t) =(3 cos⁡(t), 3 sin⁡(t), 0)for 0 <= t <= 2pi\displaystyle \verb|r(t)|\verb| |\verb|=| \left(3 \, \cos\left(t\right),\,3 \, \sin\left(t\right),\,0\right) \verb|for|\verb| |\verb|0|\verb| |\verb|<=|\verb| |\verb|t|\verb| |\verb|<=|\verb| |\verb|2pi|

F(t) =(3 sin⁡(t), −3 cos⁡(t), 0)\displaystyle \verb|F(t)|\verb| |\verb|=| \left(3 \, \sin\left(t\right),\,-3 \, \cos\left(t\right),\,0\right)

The line integral over C is -18*pi

2 ∣x∣2+∣y∣2+∣−x2−y2+9∣\displaystyle 2 \, \sqrt{{\left| x \right|}^{2} + {\left| y \right|}^{2} + {\left| -x^{2} - y^{2} + 9 \right|}}

The surface integral is−18 π\displaystyle \verb|The|\verb| |\verb|surface|\verb| |\verb|integral|\verb| |\verb|is| -18 \, \pi

Example: Find the circulation of F⃗=(x2−y)i⃗+4zj⃗+x2k⃗\vec F = (x^2 - y)\vec i + 4z \vec j + x^2\vec k around the curve CC in which the plane z=2z = 2 meets the cone z=x2+y2z = \sqrt{x^2 + y^2}, counterclockwise as viewed from above.

Solution:

r⃗(r,θ)=rcos⁡θi⃗+rsin⁡θj⃗+rk⃗,r⃗r×r⃗θ=−rcos⁡θi⃗−rsin⁡θj⃗+rk⃗n⃗=−12cos⁡θi⃗−12sin⁡θj⃗+12k⃗∇×F⃗=−4i⃗−2xj⃗+k⃗=−4i⃗−2rcos⁡θj⃗+k⃗\begin{align*} \vec r(r,\theta)=&r\cos\theta\vec i+r\sin\theta\vec j+r\vec k,\\ \vec r_r\times \vec r_\theta =&-r\cos\theta\vec i-r\sin\theta\vec j+r\vec k \\ \vec{n} =& -{1\over\sqrt{2}}\cos\theta\vec i-{1\over\sqrt{2}}\sin\theta\vec j+{1\over\sqrt{2}}\vec k\\ \nabla \times \vec F =& -4\vec i -2x\vec j + \vec k\\ =&-4\vec i-2r\cos\theta\vec j +\vec k \end{align*}r⃗(θ)=2cos⁡θi⃗+2sin⁡θj⃗+2k⃗\vec r(\theta)=2\cos\theta\vec i+2\sin\theta\vec j+2\vec k∫02π(4cos⁡2θ−2sin⁡θ)(−2sin⁡θ)+8⋅2cos⁡θdθ=4π\begin{align*} \int_0^{2\pi} (4\cos^2\theta-2\sin\theta)(-2\sin\theta)+8\cdot 2\cos\theta d\theta=4\pi \end{align*}
reset()

var('x, y, z, t')

r = vector((2*cos(t), 2*sin(t), 2))
show('r(t) =', r, 'for 0 <= t <= 2pi')

F(x,y,z) = vector((x^2-y, 4*z, x^2))
Ft = F(r[0], r[1], r[2]) # Note that the index starts at 0.
show('F(t) =', Ft)

res = integral(Ft.dot_product(diff(r,t)), t, 0, 2*pi)
print('The line integral over C is', res.full_simplify())


Fcurl = F.curl((x,y,z))

h(x,y,z) =  sqrt(x^2+y^2)-z # Express z as a function of x and y

vn = h.diff()
#vn = vn/vn.norm()  # normalize it to a unit vector

hz(x,y) =  sqrt(x^2+y^2) # Express z as a function of x and y


show('The surface integral is ', (Fcurl.dot_product(vn)(z=hz(x,y))/vn[2](z=hz(x,y))).integral(y, -sqrt(4-x^2), sqrt(4-x^2)).integral(x, -2, 2))

r(t) =(2 cos⁡(t), 2 sin⁡(t), 2)for 0 <= t <= 2pi\displaystyle \verb|r(t)|\verb| |\verb|=| \left(2 \, \cos\left(t\right),\,2 \, \sin\left(t\right),\,2\right) \verb|for|\verb| |\verb|0|\verb| |\verb|<=|\verb| |\verb|t|\verb| |\verb|<=|\verb| |\verb|2pi|

F(t) =(4 cos⁡(t)2−2 sin⁡(t), 8, 4 cos⁡(t)2)\displaystyle \verb|F(t)|\verb| |\verb|=| \left(4 \, \cos\left(t\right)^{2} - 2 \, \sin\left(t\right),\,8,\,4 \, \cos\left(t\right)^{2}\right)

The line integral over C is 4*pi

The surface integral is4 π\displaystyle \verb|The|\verb| |\verb|surface|\verb| |\verb|integral|\verb| |\verb|is| 4 \, \pi

Example: Verify Stokes' theorem for SS using the vector field F⃗=yi⃗−xj⃗+x2k⃗\vec F = y\vec i - x\vec j + x^2\vec k, where SS is formed by the part of the hyperbolic paraboloid z=y2−x2z = y^2 - x^2 lying inside the cylinder of radius one around the zz-axis.

Solution:

Find a parametrization for the surface SS formed by the part of the hyperbolic paraboloid z=y2−x2z = y^2 - x^2 lying inside the cylinder of radius one around the zz-axis.

r⃗(r,θ)=rcos⁡θi⃗+rsin⁡θj⃗+r2(sin⁡2θ−cos⁡2θ)k⃗, 0≤θ≤2π, 0≤r≤1\begin{align*} \vec r(r,\theta)=&r\cos \theta\vec i+r\sin \theta\vec j+r^2(\sin^2\theta-\cos^2\theta)\vec k,\\ &~0\leq \theta\leq 2\pi,~0\leq r\leq 1 \end{align*}∇×F⃗=−2xi⃗−2k⃗=−2rcos⁡θj⃗−2k⃗r⃗r×r⃗θ=2r2cos⁡θi⃗−2r2sin⁡θj⃗+rk⃗∫02π∫01(4r3sin⁡θcos⁡θ−2r)drdθ=−2π\begin{align*} \nabla \times \vec F=&-2x\vec i -2\vec k=-2r\cos\theta \vec j-2\vec k\\ \vec r_r\times \vec r_\theta = & 2r^2\cos\theta\vec i-2r^2\sin\theta \vec j+r\vec k\\ \int_0^{2\pi}\int_0^1&(4r^3\sin\theta\cos\theta -2r)drd\theta=-2\pi \end{align*}

Find a parametrization for the boundary curve CC of the surface SS.

r⃗(t)=cos⁡ti⃗+sin⁡tj⃗+(sin⁡2t−cos⁡2t)k⃗, 0≤t≤2π\begin{align*} \vec r(t)=&\cos t\vec i+\sin t\vec j+(\sin^2t-\cos^2t)\vec k,\\ &~0\leq t\leq 2\pi \end{align*}∮CF⃗⋅dr⃗=∫02π(4sin⁡tcos⁡3t−1)dt=−2π.\begin{align*} \oint_C\vec F\cdot d\vec r=&\int_0^{2\pi}(4\sin t\cos^3t-1)dt=-2\pi. \end{align*}
reset()

var('x, y, z, t')

r = vector((cos(t), sin(t), sin(t)^2-cos(t)^2))
show('r(t) =', r, 'for 0 <= t <= 2pi')

F(x,y,z) = vector((y, -x, x^2))
Ft = F(r[0], r[1], r[2]) # Note that the index starts at 0.
show('F(t) =', Ft)

res = integral(Ft.dot_product(diff(r,t)), t, 0, 2*pi)
print('The line integral over C is', res.full_simplify())


Fcurl = F.curl((x,y,z))

h(x,y,z) =  y^2-x^2-z # Express z as a function of x and y

vn = h.diff()
#vn = vn/vn.norm()  # normalize it to a unit vector

hz(x,y) =  y^2-x^2 # Express z as a function of x and y


show('The surface integral is ', (Fcurl.dot_product(vn)(z=hz(x,y))/vn[2](z=hz(x,y))).integral(y, -sqrt(1-x^2), sqrt(1-x^2)).integral(x, -1, 1))

r(t) =(cos⁡(t), sin⁡(t), −cos⁡(t)2+sin⁡(t)2)for 0 <= t <= 2pi\displaystyle \verb|r(t)|\verb| |\verb|=| \left(\cos\left(t\right),\,\sin\left(t\right),\,-\cos\left(t\right)^{2} + \sin\left(t\right)^{2}\right) \verb|for|\verb| |\verb|0|\verb| |\verb|<=|\verb| |\verb|t|\verb| |\verb|<=|\verb| |\verb|2pi|

F(t) =(sin⁡(t), −cos⁡(t), cos⁡(t)2)\displaystyle \verb|F(t)|\verb| |\verb|=| \left(\sin\left(t\right),\,-\cos\left(t\right),\,\cos\left(t\right)^{2}\right)

The line integral over C is -2*pi

The surface integral is−2 π\displaystyle \verb|The|\verb| |\verb|surface|\verb| |\verb|integral|\verb| |\verb|is| -2 \, \pi

Example: Calculate the circulation of the vector field F⃗=(x2+z)i⃗+(y2+2x)j⃗+(z2−y)k⃗\vec F=(x^2+z)\vec i+(y^2+2x)\vec j+(z^2-y)\vec kalong the curve of intersection of the sphere x2+y2+z2=1x^2+y^2+z^2=1 with the cone z=x2+y2z = \sqrt{x^2 + y^2} traversed in the counterclockwise direction around the zz-axis when viewed from above.

Solution:

∇×F⃗=−i⃗+j⃗+2k⃗,n⃗=k⃗∮CF⃗⋅dr⃗=∬S∇×F⃗⋅n⃗dσ=∬S2dσ=π\begin{align*} \nabla \times \vec F=&-\vec i+\vec j+2\vec k,\quad \vec n=\vec k\\ \oint_C\vec F\cdot d\vec r=&\iint_S\nabla\times\vec F\cdot\vec n d\sigma\\ =&\iint_S2d\sigma=\pi \end{align*}
reset()

var('x, y, z, t')

r = vector((cos(t)/sqrt(2), sin(t)/sqrt(2), 1/sqrt(2)))
show('r(t) =', r, 'for 0 <= t <= 2pi')

F(x,y,z) = vector((x^2+z, y^2+2*x, z^2-y))
Ft = F(r[0], r[1], r[2]) # Note that the index starts at 0.
show('F(t) =', Ft)

res = integral(Ft.dot_product(diff(r,t)), t, 0, 2*pi)
print('The line integral over C is', res.full_simplify())


Fcurl = F.curl((x,y,z))

h(x,y,z) =  x^2+y^2+z^2-1 # Express z as a function of x and y

vn = h.diff()
#vn = vn/vn.norm()  # normalize it to a unit vector

hz(x,y) =  sqrt(1-x^2-y^2) # Express z as a function of x and y

show('The surface integral is ', (Fcurl.dot_product(vn)(z=hz(x,y))/vn[2](z=hz(x,y))).integral(y, -sqrt(1/2-x^2), sqrt(1/2-x^2), algorithm='giac').integral(x, -1/sqrt(2), 1/sqrt(2),algorithm='giac'))

r(t) =(12 2cos⁡(t), 12 2sin⁡(t), 12 2)for 0 <= t <= 2pi\displaystyle \verb|r(t)|\verb| |\verb|=| \left(\frac{1}{2} \, \sqrt{2} \cos\left(t\right),\,\frac{1}{2} \, \sqrt{2} \sin\left(t\right),\,\frac{1}{2} \, \sqrt{2}\right) \verb|for|\verb| |\verb|0|\verb| |\verb|<=|\verb| |\verb|t|\verb| |\verb|<=|\verb| |\verb|2pi|

F(t) =(12 cos⁡(t)2+12 2, 12 sin⁡(t)2+2cos⁡(t), −12 2sin⁡(t)+12)\displaystyle \verb|F(t)|\verb| |\verb|=| \left(\frac{1}{2} \, \cos\left(t\right)^{2} + \frac{1}{2} \, \sqrt{2},\,\frac{1}{2} \, \sin\left(t\right)^{2} + \sqrt{2} \cos\left(t\right),\,-\frac{1}{2} \, \sqrt{2} \sin\left(t\right) + \frac{1}{2}\right)

The line integral over C is pi

The surface integral isπ\displaystyle \verb|The|\verb| |\verb|surface|\verb| |\verb|integral|\verb| |\verb|is| \pi

Find ∇×F⃗\nabla \times \vec F and relate it to the circulation density 1πρ2∮CF⃗⋅dr⃗{1\over \pi\rho^2}\oint_C \vec F\cdot d\vec r, where CC is a circle of radius ρ\rho in the xy−xy-plane.

Assume that a fluid of constant density rotates around the zz-axis with velocity F⃗=w(−yi⃗+xj⃗)\vec F = w(-y\vec i + x\vec j), where ww is the angular velocity of the rotation.

From the computation, we have ∇×F⃗=2wk⃗ \nabla \times \vec F = 2w \vec k

For circle CC of radius ρ\rho ∮CF⃗⋅dr⃗=∬S∇×F⃗⋅n⃗dσ=(2w)(πρ2)\begin{align*} %\nabla \times \vec F =& 2w\vec k\\ \oint_C\vec F\cdot d\vec r=& \iint_S\nabla\times \vec F\cdot \vec n d\sigma=(2w)(\pi\rho^2) \end{align*} Thus (∇×F⃗)⋅k⃗=2w=1πρ2∮CF⃗⋅dr (\nabla \times \vec F) \cdot \vec k = 2w = {1 \over \pi \rho^2} \oint_C \vec F \cdot dr

Paddle wheel interpretation of ∇×F⃗\nabla \times \vec F

We fix a point QQ in the region RR and a direction u⃗\vec u. Take CC as a circle of radius ρ\rho, with center at QQ, whose plane is normal to u⃗\vec u.

If ∇×F⃗\nabla \times \vec F is continuous at QQ, the average value of the u⃗\vec u-component of ∇×F⃗\nabla\times \vec F over the circular disk SS bounded by CC approaches the u⃗\vec u-component of ∇×F⃗\nabla\times \vec F at QQ as the radius ρ→0\rho\rightarrow 0: (∇×F⃗⋅u⃗)Q=lim⁡ρ→01πρ2∬S∇×F⃗⋅u⃗dσ=lim⁡ρ→01πρ2∮CF⃗⋅dr⃗.\begin{align*} (\nabla \times \vec F\cdot\vec u)_Q=&\lim_{\rho\rightarrow0}{1\over\pi\rho^2}\iint_S\nabla \times \vec F\cdot \vec u d\sigma=\lim_{\rho\rightarrow0}{1\over\pi\rho^2}\oint_C \vec F\cdot d\vec r. \end{align*}

circulation density: the circulation around CC divided by the area of the disk lim⁡ρ→01πρ2∮CF⃗⋅dr⃗\lim_{\rho\rightarrow0}{1\over\pi\rho^2}\oint_C \vec F\cdot d\vec r

Example: Use Stokes' theorem to evaluate ∮CF⃗⋅dr⃗\oint_C \vec F\cdot d\vec r with F⃗=xzi⃗+xyj⃗+3xzk⃗\vec F = xz\vec i + xy\vec j + 3xz\vec k, where CC is the boundary of the portion of the plane 2x+y+z=22x + y + z = 2 in the first octant, traversed counterclockwise as viewed from above.

Solution: Since the surface is a triangle, and we need to compute three integrals to find the line integral. However, we can use the Stokes' theorem to compute the surface integral instead. n⃗=16(2i⃗+j⃗+k⃗)∇×F⃗=(x−3z)j⃗+yk⃗∮CF⃗⋅dr⃗=∬S∇×F⋅n⃗dσ=∫01∫02−2x(7x+4y−6)dydx=−1\begin{align*} \vec n=&{1\over\sqrt{6}}(2\vec i+\vec j+\vec k)\\ \nabla\times \vec F=& (x-3z)\vec j+y\vec k\\ \oint_C\vec F\cdot d\vec r=&\iint_S\nabla\times F\cdot \vec n d\sigma \\ =&\int_0^1\int_0^{2-2x}(7x+4y-6)dydx\\ =&-1 \end{align*}

reset()

var('x, y, z, length, theta')

vn = vector((2,1,1))
vn = vn/vn.norm()  # normalize it to a unit vector

F = vector((x*z, x*y, 3*x*z))
Fcurl = F.curl((x,y,z))

h(x,y) =  2-2*x-y # Express z as a function of x and y

show('The surface integral is ', (Fcurl.dot_product(vn)(z=h(x,y))*sqrt(h.diff(x)^2+h.diff(y)^2+1)).integral(y, 0, 2-2*x).integral(x, 0, 1))

The surface integral is−1\displaystyle \verb|The|\verb| |\verb|surface|\verb| |\verb|integral|\verb| |\verb|is| -1

Example: Find the flux of ∇×F⃗\nabla \times\vec F across SS in the direction n⃗\vec n for F⃗=yi⃗−xzj⃗+xz2k⃗\vec F = y\vec i - xz\vec j + xz^2\vec k. The surface SS is the elliptical paraboloid z=x2+4y2z = x^2 + 4y^2 lying beneath the plane z=1z = 1. We define the orientation of SS by taking the inner normal vector n⃗\vec n to the surface, which is the normal having a positive k⃗\vec k-component.

Solution: By the Stokes' theorem, we can find the line integral instead. We need to find a parametrization for the loop. r⃗(t)=cos⁡ti⃗+12sin⁡tj⃗+k⃗, 0≤t≤2πr⃗′(t)=−sin⁡ti⃗+12cos⁡tj⃗F⃗(r⃗(t))=12sin⁡ti⃗−cos⁡tj⃗+cos⁡tk⃗∬S(∇×F⃗)⋅n⃗dA=∮CF⃗⋅dr⃗=∫02π−12dt=−π\begin{align*} \vec r(t)=&\cos t\vec i+{1\over 2}\sin t\vec j+\vec k,~0\leq t\leq 2\pi\\ \vec r'(t)=&-\sin t\vec i+{1\over 2}\cos t\vec j\\ \vec F(\vec r(t))=&{1\over2}\sin t\vec i-\cos t\vec j+\cos t\vec k\\ \iint_S(\nabla\times \vec F)\cdot\vec n &dA=\oint_C\vec F\cdot d\vec r \\ =& \int_0^{2\pi}{-1\over 2}dt=-\pi \end{align*}

reset()

var('x, y, z, t')

r = vector((cos(t), sin(t)/2, 1))
show('r(t) =', r, 'for 0 <= t <= 2pi')

F(t) = vector((r[1], -r[0]*r[2], r[0]*r[2]^2)) # Note that the index starts at 0.
show('F(t) =', F(t))

res = integral(F(t).dot_product(diff(r,t)), t, 0, 2*pi)
print('The line integral over C is', res.full_simplify())

r(t) =(cos⁡(t), 12 sin⁡(t), 1)for 0 <= t <= 2pi\displaystyle \verb|r(t)|\verb| |\verb|=| \left(\cos\left(t\right),\,\frac{1}{2} \, \sin\left(t\right),\,1\right) \verb|for|\verb| |\verb|0|\verb| |\verb|<=|\verb| |\verb|t|\verb| |\verb|<=|\verb| |\verb|2pi|

F(t) =(12 sin⁡(t), −cos⁡(t), cos⁡(t))\displaystyle \verb|F(t)|\verb| |\verb|=| \left(\frac{1}{2} \, \sin\left(t\right),\,-\cos\left(t\right),\,\cos\left(t\right)\right)

The line integral over C is -pi

An important identity

∇×∇f=0⃗\nabla \times \nabla f=\vec{0}

Theorem If ∇×F=0⃗\nabla\times F=\vec{0} at every point of a simply connected open region DD in space, then on any piecewise smooth closed path CC in DD, ∮CF⃗⋅dr⃗=∬S(∇×F⃗)⋅n⃗dσ=∬S0⃗⋅n⃗dσ=0.\oint_C\vec F \cdot d\vec r=\iint_S(\nabla\times\vec F) \cdot\vec n d\sigma=\iint_S\vec{0} \cdot\vec n d\sigma=0.

Summary