Sagemath.ipynb

Kernel: SageMath (stable)

Linear Algebra with Sagemath

See the following for a more thorough and likely better tutorial:

• http://linear.ups.edu/html/fcla.html (Rob Beezer's book on Linear Algebra)

• http://www.gregorybard.com/Sage.html (Greg Bard's book on Sagemath for undergraduates)

This worksheet is just more specialized for our 308 class

What's with the QQ?

In math, there are different number systems. We call them rings https://en.wikipedia.org/wiki/Ring_(mathematics). Linear algebra over different rings give you different answers. In this class, we'll use QQ for exact answer and RR for inexact ones.

What is Sage?

A computer algebra system built on top of Python.

Echelon Forms

Problem 1 http://kevinlui.org/m308exams/au17_midterm1sol.pdf

A = matrix(QQ,[
           [1, 2, -1, 3],
           [0, 1, -1, 2],
           [0, 0, 1, 1]
           ])

A

[ 1  2 -1  3]
[ 0  1 -1  2]
[ 0  0  1  1]

show(A)

B = A.rref()

show(B)

Solving Linear System

### Problem 1 <http://kevinlui.org/m308exams/au17_midterm1sol.pdf>

A = matrix(QQ,[
           [1, 2, -1, 3],
           [0, 1, -1, 2],
           [0, 0, 1, 1]
           ])

b = vector(QQ, [1, 1, 0])

show(A)

show(b)

A.solve_right(b)

(-1, 1, 0, 0)

A.right_kernel()

Vector space of degree 4 and dimension 1 over Rational Field
Basis matrix:
[   1 -3/2 -1/2  1/2]

The general solution is then $x=(-1,1,0,0)+s_1(1,-3/2,-1/2,1/2)$.

Use RDF - real double field - for inexact computations

A = random_matrix(RDF, 5); show(A)

b = random_vector(RDF, 5); show(b)

A.solve_right(b)

(0.7454769517982468, -2.224701702449103, 1.8640870570327306, 0.8131141695930252, -0.7342450326911023)

A \ b

(0.7454769517982468, -2.224701702449103, 1.8640870570327306, 0.8131141695930252, -0.7342450326911023)

Here's how to check linearly independence/span

V = QQ^3 # this is the 3-dimensional rational field

v1 = vector(QQ, [1,2,3])
v2 = vector(QQ, [2,-1,3])
v3 = 2*v1+v2

V.linear_dependence([v1, v2, v3])

[
(1, 1/2, -1/2)
]

1*v1+1/2*v2-1/2*v3

(0, 0, 0)

V.span([v1, v2, v3])

Vector space of degree 3 and dimension 2 over Rational Field
Basis matrix:
[  1   0 9/5]
[  0   1 3/5]

V.span([v1, v2, v3]) == V

False