Ask
CoCalc Logo Icon
StoreFeaturesDocsShareSupport News Sign UpSign In
Views: 40
Visibility: Unlisted (only visible to those who know the link)
Image: ubuntu2004
Embed | Download | Raw |
Kernel: SageMath 9.2

Volumes of Revolution - A Methodical Approach

var('x y') # usually we're rotating a portion of a function, so the piecewise feature is useful f = piecewise([([0, 1], x^2)]) g = piecewise([([0, 1], sqrt(x))])
p1 = plot(f, 0, 1, gridlines=True) t1 = text("I", (0.8, 0.2), fontsize='large', fontweight='bold') p2 = plot(g, 0, 1) t2 = text("II", (0.2, 0.8), fontsize='large', fontweight='bold') t3 = text("III", (0.4, 0.4), fontsize='large', fontweight='bold') (p1 + t1 + p2 + t2 + t3).show()

This notebook will demonstrate many permutations of rotating the above regions about various axes using disk, washer and shell methods. Depending on the goal, we will integrate either with respect to x- or with respect to y.

Rotate regions I, II, and III about the x axis.

Region 1 is bounded by the curve y=x2y = x^2 above, the x axis below, and the line x=1x=1. Here is the surface of the volume created.

revolution_plot3d(f, (x,0,1), parallel_axis='x', show_curve=True, opacity=0.7).show(aspect_ratio=(1,1,1))

Using the disk method, with the disk perpendicular to the x-axis,

V=A  dxV = \int A \; dxA=πr2A = \pi r^2r=f(x)r = f(x)V=π01(f(x))2  dxV = \pi \int_{0}^{1} (f(x))^2 \; dx
pi * integrate(f^2, x, 0, 1)

Region 2 is bounded by the curve y=xy = \sqrt{x} below, the y axis, and the line y=1y=1 above. Here is the surface of the volume created.

l = 1 sur1 = revolution_plot3d(l, (x,0,1), parallel_axis='x', opacity=0.5, rgbcolor=(1,0.5,0)) sur2 = revolution_plot3d(g, (x,0,1), parallel_axis='x', show_curve=True, mesh=True, opacity=0.5, rgbcolor=(0,1,0)) (sur1 + sur2).show()

Rotating region II about the x axis requires use of the washer method, i.e. one disk subtracted from another.

A=π(ro2ri2)A = \pi (r_o^2 - r_i^2)ro=1, and ri=xr_o = 1 \text{, and } r_i = \sqrt{x}V=π0112(x)2  dxV = \pi \int_{0}^{1} 1^2 - (\sqrt{x})^2 \; dx
# The volume of region II rotated about the x axis pi * integrate(1 - x, x, 0, 1)

Region 3 is bounded above by the curve y=xy = \sqrt{x} and below by the curve y=x2y = x^2. Here the surface of the volume created.

aor = line([(0,0,0), (1,0,0)], thickness=3, color='green') sur1 = revolution_plot3d(f, (x,0,1), parallel_axis='x', show_curve=True, opacity=0.5, color='red') sur2 = revolution_plot3d(g, (x,0,1), parallel_axis='x', show_curve=True, opacity=0.5, color='blue') (aor + sur1 + sur2).show(aspect_ratio=(1,1,1))

Link to Geogebra construction of the same shape: Region III rotated about x.

Using the washer method, with the washer / disk perpendicular to the x-axis,

V=A  dxV = \int A \; dxA=πro2πri2A = \pi r_o^2 - \pi r_i^2ro=g(x) and ri=f(x)r_o = g(x) \text{ and } r_i = f(x)V=π01(g(x))2(f(x))2  dxV = \pi \int_{0}^{1} (g(x))^2 - (f(x))^2 \; dx
# The volume of region III rotated about the x-axis. pi * integral(x - x^2, x, 0, 1)

Rotate regions I, II, and III about the y axis.

Region I, bounded by y=x2y=x^2, the x axis, and the line x=1x=1, rotated about the y axis, looks like this:

# SageMath surface plots assume the form z=f(x, y), so the independent variable is z. Hence the parallel axis. aor = line([(0,0,0), (0,0,1)], thickness=2, color='red') surf1 = revolution_plot3d(f, (x,0,1), parallel_axis='z', show_curve=True, opacity=0.7) (aor + surf1).show(aspect_ratio=(1,1,1))

Using the shell method, the area of each shell is

A=2πrhA = 2 \pi r h

where

r=x and h=f(x)=x2r = x \text{ and } h = f(x) = x^2

So

V=2π01xf(x)  dxV = 2 \pi \int_{0}^{1} x f(x) \; dx
2 * pi * integral(x * x^2, x, 0, 1)

Region II, bounded by y=xy = \sqrt{x}, the y axis, and the line y=1y=1, rotated about the y axis.

aor = line([(0,0,0), (0,0,1)], thickness=2, color='red') surf1 = revolution_plot3d(g, (x,0,1), parallel_axis='z', show_curve=True, opacity=0.7) (aor + surf1).show(aspect_ratio=(1,1,1))

Using the shell method again,

r=x and h=1xr = x \text{ and } h = 1 - \sqrt{x}V=2π01x(1g(x))  dxV = 2 \pi \int_{0}^{1} x (1 - g(x)) \; dx
2 * pi * integral(x*(1-sqrt(x)), x, 0, 1)

Region III, rotated about y.

aor = line([(0,0,0), (0,0,1)], thickness=2, color='black') sur1 = revolution_plot3d(f, (x,0,1), show_curve=True, opacity=0.4, color='blue', parallel_axis='z') sur2 = revolution_plot3d(g, (x,0,1), show_curve=True, opacity=0.8, color='red', parallel_axis='z') (aor + sur1 + sur2).show(aspect_ratio=(1,1,1))
r=x and h=xx2r = x \text{ and } h = \sqrt{x} - x^2V=2π01x(xx2)  dxV = 2 \pi \int_{0}^{1} x (\sqrt{x} - x^2) \; dx
2 * pi * integral(x*(sqrt(x) - x^2), x, 0, 1)

The next group will be the same regions and rotations, but replacing the shell method with the disk or washer and integrating with respect to y. When integrating with respect to y we'll need to use the inverse functions.

f(x)=x2f1(y)=yf(x) = x^2 \Rightarrow f^{-1}(y) = \sqrt{y}g(x)=xg1(y)=y2g(x) = \sqrt{x} \Rightarrow g^{-1}(y) = y^2

Rotating region I around y, we get a washer with

ro=1 and ri=yr_o = 1 \text{ and } r_i = \sqrt{y}V=π0112(y)2  dyV = \pi \int_{0}^{1} 1^2 - (\sqrt{y})^2 \; dy
pi * integral(1 - y, y, 0, 1)

Rotating region II about y and integrating with respect to y yields a simple disk with r=y2r = y^2

V=π01(y2)2  dyV = \pi \int_{0}^{1} (y^2)^2 \; dy
pi * integral(y^4, y, 0, 1)

And, rotating region III about y and integrating with respect to y gives a washer with

ro=y and ri=y2r_o = \sqrt{y} \text{ and } r_i = y^2

and

V=π01(y)2(y2)2  dyV = \pi \int_{0}^{1} (\sqrt{y})^2 - (y^2)^2 \; dy
pi * integral(y - y^4, y, 0, 1)

Rotate regions I, II, and III about y=1

Rotating region I about y=1 using the washer method, we have

ro=1 and ri=1x2r_o = 1 \text{ and } r_i = 1-x^2V=π01ro2ri2  dxV = \pi \int_{0}^{1} r_o^2 - r_i^2 \; dxV=π0112(1x2)2  dxV = \pi \int_{0}^{1} 1^2 - (1-x^2)^2 \; dx
pi * integral(1 - (1-x^2)^2, x, 0, 1)

Rotating region II about y=1 is a simple disk method with r=1xr = 1 - \sqrt{x}.

pi * integral((1 - sqrt(x))^2, x, 0, 1)

For region III about y=1 we have a washer with

ro=1x2 and ri=1xr_o = 1-x^2 \text{ and } r_i = 1 - \sqrt{x}V=π01(1x2)2(1x)2  dxV = \pi \int_{0}^{1} (1 - x^2)^2 - (1 - \sqrt{x})^2 \; dx
aor = line([(1,0,1), (0,0,1)], thickness=3, color='blue') sur1 = revolution_plot3d(f, (x,0,1), parallel_axis='x', axis=(0,1), show_curve=True, opacity=0.7, mesh=True, color='purple') sur2 = revolution_plot3d(g, (x,0,1), parallel_axis='x', axis=(0,1), show_curve=True, opacity=0.7, mesh=True, color='yellow') (aor + sur1 + sur2).show(aspect_ratio=(1,1,1))
pi * integral((1-x^2)^2 - (1-sqrt(x))^2, x, 0, 1)

Rotate regions I, II, and III about x=1

Rotating region I about x=1 and using the shell method yields

A=2πrhA = 2 \pi r hr=1x and h=x2r = 1 - x \text{ and } h = x^2V=2π01(1x)x2  dxV = 2 \pi \int_{0}^{1} (1-x) x^2 \; dx
2 * pi * integral((1-x)*x^2, x, 0, 1)

Rotating region II about x=1, also using shells.

A=2πrhA = 2 \pi r hr=1x, and h=1xr = 1 - x, \text{ and } h = 1 - \sqrt{x}V=2π01(1x)(1x)  dxV = 2 \pi \int_{0}^{1} (1 - x) (1 - \sqrt{x}) \; dx
2 * pi * integral((1 - x)*(1 - sqrt(x)), x, 0, 1)

Region III rotated about x=1.

# this is the volume enclosed by y = x^2 and y = sqrt(x) rotated about x=1 aor = line([(1,0,0), (1,0,1)], thickness=3, color='green') surf1 = revolution_plot3d(f, (x,0,1), parallel_axis='z', axis=(1, 0), show_curve=True, opacity=0.7, color='red') surf2 = revolution_plot3d(g, (x,0,1), parallel_axis='z', axis=(1, 0), show_curve=True, opacity=0.7, color='blue') (aor + surf1 + surf2).show(aspect_ratio=(1,1,1))

Rotating region III about x=1 using shells.

r=1x, and h=xx2r = 1 - x, \text{ and } h = \sqrt{x} - x^2V=2π01(1x)(xx2)  dxV = 2 \pi \int_{0}^{1} (1 - x) (\sqrt{x} - x^2) \; dx
2 * pi * integral((1 - x)*(sqrt(x) - x^2), x, 0, 1)